godot/platform/android/java/scripts/publish-module.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'

group = ossrhGroupId
version = PUBLISH_VERSION

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                // The coordinates of the library, being set from variables that
                // we'll set up later
                groupId ossrhGroupId
                artifactId PUBLISH_ARTIFACT_ID
                version PUBLISH_VERSION

                // Two artifacts, the `aar` (or `jar`) and the sources
                if (project.plugins.findPlugin("com.android.library")) {
                    from components.release
                } else {
                    from components.java
                }

                // Mostly self-explanatory metadata
                pom {
                    name = PUBLISH_ARTIFACT_ID
                    description = 'Godot Engine Android Library'
                    url = 'https://godotengine.org/'
                    licenses {
                        license {
                            name = 'MIT License'
                            url = 'https://github.com/godotengine/godot/blob/master/LICENSE.txt'
                        }
                    }
                    developers {
                        developer {
                            id = 'm4gr3d'
                            name = 'Fredia Huya-Kouadio'
                            email = 'fhuyakou@gmail.com'
                        }
                        developer {
                            id = 'reduz'
                            name = 'Juan Linietsky'
                            email = 'reduzio@gmail.com'
                        }
                        developer {
                            id = 'akien-mga'
                            name = 'Rémi Verschelde'
                            email = 'rverschelde@gmail.com'
                        }
                        // Add all other devs here...
                    }

                    // Version control info - if you're using GitHub, follow the
                    // format as seen here
                    scm {
                        connection = 'scm:git:github.com/godotengine/godot.git'
                        developerConnection = 'scm:git:ssh://github.com/godotengine/godot.git'
                        url = 'https://github.com/godotengine/godot/tree/master'
                    }
                }
            }
        }
    }
}

signing {
    useInMemoryPgpKeys(
        rootProject.ext["signing.keyId"],
        rootProject.ext["signing.key"],
        rootProject.ext["signing.password"],
    )
    sign publishing.publications
}