abslibre/libre/mate-sensors-applet/PKGBUILD

# Maintainer (arch): Brad Fanella <cesura@archlinux.org>
# Contributor: Martin Wimpress <code@flexion.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=mate-sensors-applet
pkgver=1.24.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A MATE Panel applet to display readings from hardware sensors, including CPU temperature, fan speeds and voltage readings"
pkgdesc+=", without nonfree libxnvctrl support"
url="https://mate-desktop.org"
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('GPL')
depends=('libatasmart' 'libnotify' 'lm_sensors' 'mate-panel' 'gettext')
makedepends=('docbook-xsl' 'itstool')
groups=('mate-extra')
conflicts=('mate-sensors-applet-gtk3')
replaces=('mate-sensors-applet-gtk3')
source=("https://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('5a604dd7ede7f5889817d936486b83b720ad500f097154635623ad3ee47ff2c7')

build() {
	cd "${pkgname}-${pkgver}"
    	./configure \
        	--prefix=/usr \
        	--libexecdir=/usr/lib/${pkgname}

    	#https://bugzilla.gnome.org/show_bug.cgi?id=656231
    	sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  	make
}

package() {
    	cd "${pkgname}-${pkgver}"
    	make DESTDIR="${pkgdir}" install
}