abslibre/libre/libretools/PKGBUILD

# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: bill-auger <bill-auger@programmer.net>

# Upstream information

pkgbase=libretools
pkgname=(libretools librelib gitget)
pkgdesc="Programs for Parabola development"
url="https://git.parabola.nu/packages/libretools.git/"
license=(GPL-2.0-only GPL-3.0-or-later)

pkgver=20240707
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
        test-rubygems.rb)
sha256sums=('b3e22601e85a28de2693b6a2894079127bba3dbf69a837d978e125e0ca989243'
            'SKIP'
            '649abdfe296768077ae62b3534d73fda67b0ade94983823c7d4a539b986b828b')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9'  # Luke Shumaker
              '6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78'  # David P.
              'BFA8008A8265677063B11BF47171986E4B745536'  # Andreas Grapentin
              '3954A7AB837D0EA9CFA9798925DB7D9B5A8D4B40') # bill-auger

# Package information

pkgrel=2
arch=('any')
makedepends=(ruby-ronn-ng)
_pacman_constraints=('pacman>=7.0' 'pacman<7.1')
checkdepends=(
  bats-assert
  bats-file
  git
  "${_pacman_constraints[@]}"
  expac
  openssh
  rsync
  tokyocabinet
)

# Build instructions

build() {
  if ! ./test-rubygems.rb
  then echo "\`rubygems\` seems to be broken again - man pages will not be built"
       sed -i 's|^enable_manpages = .*|enable_manpages =|' $pkgbase-$pkgver/config.mk
  fi

  cd "$srcdir/$pkgbase-$pkgver"
  make
}

check() {
  cd "$srcdir/$pkgbase-$pkgver"
  SUDO_USER= make check BATS_FLAGS='--filter-tags !network,!sudo,!btrfs,!locale-es'
}

package_librelib() {
  pkgdesc="The shell library portion of libretools"
  license=(GPL-2.0-only)
  conflicts=('xbs')
  optdepends=(
    'libretools: for libreblacklist/blacklist.sh'
    'wget: for libreblacklist/blacklist.sh'
  )

  cd "$srcdir/$pkgbase-$pkgver"
  make install-librelib DESTDIR="$pkgdir"
}

package_gitget() {
  pkgdesc="A simple to use downloader for git URLs"
  license=(GPL-2.0-only)
  depends=("librelib=$pkgver" git)

  cd "$srcdir/$pkgbase-$pkgver"
  make install-gitget DESTDIR="$pkgdir"
}

package_libretools() {
  backup=(etc/libretools.conf
          etc/libretools.d/chroot.conf
          etc/libretools.d/libredbdiff.conf
          etc/libretools.d/librefetch.conf)
  conflicts=(devtools)
  depends=(
    "librelib=$pkgver"
    "gitget=$pkgver"     # `createworkdir`
    "${_pacman_constraints[@]}"
    arch-install-scripts # `mkarchroot` uses `pacstrap`
    binutils             # `libremakepkg`->`makepkg` uses `strip`
    expac                # `libredbdiff`
    fakeroot             # `libremakepkg`->`makepkg` uses `fakeroot`
    make                 # `librefetch`
    openssh              # `librerelease`
    #pacutils             # `librechroot` uses `pacsift` # TODO: not yet, it doesn't
    rsync                # `librerelease` and `makechrootpkg.sh`
    'systemd-tools>=234' # `systemd-nspawn` # TODO: merge 'nonsystemd' branch
    tokyocabinet         # `toru`
    #namcap               # `libremakepkg` # FIXME: Namcap is currently disabled in libremakepkg :-(
    subversion           # `diff-unfree`
    wget                 # `aur`, optdepend for librelib:`blacklist`
  )
  optdepends=(
    'qemu-user-static-binfmt: To build ARM packages from x86'
  )

  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
}