eiffel-iup/library/iup_widget_maxmin_size.e

deferred class IUP_WIDGET_MAXMIN_SIZE
-- Commands to handle the attributes related with max/min size.

inherit
	IUP_WIDGET_INTERNALS
	
feature {ANY}

	set_maxsize (width: INTEGER; height: INTEGER)
		-- Specifies the element maximum size in pixels during the layout 
		-- process.
		require
			non_negative: width >= 0
							  height >= 0
							  is_valid_maxsize(width, height)
		local
			size: STRING
		do
			size := width.out
			size.append_string("x")
			size.append_string(height.out)

			iup_open.set_attribute(Current, "MAXSIZE", size)
		end

	get_maxsize: TUPLE[INTEGER, INTEGER]
		-- Return the maximum size of the element.
		local
			size: STRING
		do
			size := iup_open.get_attribute(Current, "MAXSIZE")
			Result := components_of_size(size)			
		end

	set_minsize (width: INTEGER; height: INTEGER)
		-- Specifies the element minimum size in pixels during the layout process.
		require
			non_negative: width >= 0
							  height >= 0
							  is_valid_minsize(width, height)
		local
			size: STRING
		do
			size := width.out
			size.append_string("x")
			size.append_string(height.out)

			iup_open.set_attribute(Current, "MINSIZE", size)
		end

	get_minsize: TUPLE[INTEGER, INTEGER]
		-- Return the minimum size of the element.
		local
			size: STRING
		do
			size := iup_open.get_attribute(Current, "MINSIZE")
			Result := components_of_size(size)			
		end

	is_valid_maxsize (w, h: INTEGER): BOOLEAN
		local
			mins: TUPLE[INTEGER, INTEGER]
			w1, h1: INTEGER
		do
			mins := get_minsize

			w1 := mins.integer_32_item(1)
			h1 := mins.integer_32_item(2)

			if w1 <= w and then
				h1 <= h then
				Result := True
			else
				Result := False
			end
		end

	is_valid_minsize (w, h: INTEGER): BOOLEAN
		local
			maxs: TUPLE[INTEGER, INTEGER]
			w1, h1: INTEGER
		do
			maxs := get_maxsize

			w1 := maxs.integer_32_item(1)
			h1 := maxs.integer_32_item(2)

			if w1 >= w and then
				h1 >= h then
				Result := True
			else
				Result := False
			end
		end

end

-- The MIT License (MIT)

-- Copyright (c) 2016, 2019 by German A. Arias

-- Permission is hereby granted, free of charge, to any person obtaining a copy
-- of this software and associated documentation files (the "Software"), to deal
-- in the Software without restriction, including without limitation the rights
-- to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
-- copies of the Software, and to permit persons to whom the Software is
-- furnished to do so, subject to the following conditions:
--
-- The above copyright notice and this permission notice shall be included in 
-- all copies or substantial portions of the Software.
--
-- THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
-- IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
-- FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
-- AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
-- LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
-- OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
-- SOFTWARE.