qt_openal_soft/Qt/OpenAL-Soft.pro

#-------------------------------------------------
#
# Project created by QtCreator 2011-05-14T13:58:16
#
#-------------------------------------------------

QT += multimedia
QT -= gui

TARGET = openal_soft
TEMPLATE = lib
DEFINES += _QT

CONFIG(debug, debug|release) {
    TARGET_CONFIG = debug
    DEFINES += _DEBUG
} else {
    TARGET_CONFIG = release
}

win32 {
    TARGET_PLATFORM = win32
    DEFINES += _WIN32
    LIBS += -Wl,-s -lwinmm
}

simulator {
    TARGET_PLATFORM = simulator
    DEFINES += _SIMULATOR
    LIBS += -Wl,-s -lwinmm
}

symbian: {
    DEFINES += _SYMBIAN
}

DEFINES += OPENALSOFT_LIBRARY \
    AL_BUILD_LIBRARY \
    AL_ALEXT_PROTOTYPES \
    _QT

SOURCES += \
    ../Alc/bs2b.c \
    ../Alc/ALu.c \
    ../Alc/alcThread.c \
    ../Alc/alcRing.c \
    ../Alc/alcReverb.c \
    ../Alc/alcModulator.c \
    ../Alc/alcEcho.c \
    ../Alc/alcConfig.c \
    ../Alc/ALc.c \
    ../OpenAL32/alThunk.c \
    ../OpenAL32/alState.c \
    ../OpenAL32/alSource.c \
    ../OpenAL32/alListener.c \
    ../OpenAL32/alFilter.c \
    ../OpenAL32/alExtension.c \
    ../OpenAL32/alError.c \
    ../OpenAL32/alEffect.c \
    ../OpenAL32/alDatabuffer.c \
    ../OpenAL32/alBuffer.c \
    ../OpenAL32/alAuxEffectSlot.c \
    ../Alc/null.c \
    ../Alc/qt.c \
    qAudioOutputWrapper.cpp \
    qThreadWrapper.cpp \
    qDebugWrapper.cpp \
    qAudioOutputEvent.cpp

HEADERS += config.h \
    qAudioOutputWrapper.h \
    qThreadWrapper.h \
    qDebugWrapper.h \
    ../OpenAL32/Include/bs2b.h \
    ../OpenAL32/Include/alu.h \
    ../OpenAL32/Include/alThunk.h \
    ../OpenAL32/Include/alState.h \
    ../OpenAL32/Include/alSource.h \
    ../OpenAL32/Include/alMain.h \
    ../OpenAL32/Include/alListener.h \
    ../OpenAL32/Include/alFilter.h \
    ../OpenAL32/Include/alError.h \
    ../OpenAL32/Include/alEffect.h \
    ../OpenAL32/Include/alDatabuffer.h \
    ../OpenAL32/Include/alBuffer.h \
    ../OpenAL32/Include/alAuxEffectSlot.h \
    ../include/AL/efx-creative.h \
    ../include/AL/efx.h \
    ../include/AL/alext.h \
    ../include/AL/alc.h \
    ../include/AL/al.h \
    qAudioOutputEvent.h

INCLUDEPATH += ../include \
    ../OpenAL32/Include \
    ./ \

QMAKE_CXXFLAGS.GCCE -= -fvisibility-inlines-hidden

symbian {
    #Symbian specific definitions
    MMP_RULES += EXPORTUNFROZEN
    TARGET.UID3 = 0xE99C2071
    TARGET.CAPABILITY += NetworkServices
    TARGET.EPOCALLOWDLLDATA = 1
    addFiles.sources = openal_soft.dll
    addFiles.path = !:/sys/bin
    DEPLOYMENT += addFiles
}

unix:!symbian {
    maemo5 {
        target.path = /opt/usr/lib
    } else {
        target.path = /usr/local/lib
    }
    INSTALLS += target
}

symbian {
    # Symbian libs files can only be copied to epoc32 udeb & urel folder
    message(Note: Symbian target files must be manually copied from corresponding udeb folder.)
    message(Note: Make sure custom build steps are added to project setting.)
} else {
    DESTDIR = $$PWD/../bin/$$TARGET_PLATFORM/$$TARGET_CONFIG/
}