iap_sample_drm_case/QTComponent_based/TryAndBuyExample/TryAndBuyExample.pro

# Add more folders to ship with the application, here
folder_01.source = qml
folder_01.target = .
DEPLOYMENTFOLDERS = folder_01

# Additional import path used to resolve QML modules in Creator's code model
QML_IMPORT_PATH =

CONFIG += mobility qt-components
MOBILITY += serviceframework

# The .cpp file which was generated for your project. Feel free to hack it.
SOURCES += main.cpp \
    purchasableitem.cpp \
    purchasableitemBase.cpp \
    drmfile.cpp \
    symbian_drm/drmfile_p.cpp \
    productlistmodel.cpp \
    filterproxymodel.cpp

# Please do not modify the following two lines. Required for deployment.
include(qmlapplicationviewer/qmlapplicationviewer.pri)
qtcAddDeployment()

HEADERS += \
    purchasableitem.h \
    purchasableitemBase.h \
    drmfile.h \
    symbian_drm/drmfile_p.h \
    productlistmodel.h \
    filterproxymodel.h


symbian{
# Smart Installer package's UID
# This UID is from the protected range and therefore the package will
# fail to install if self-signed. By default qmake uses the unprotected
# range value if unprotected UID is defined for the application and
# 0x2002CCCF value if protected UID is given to the application
#symbian:DEPLOYMENT.installer_header = 0x2002CCCF
    TARGET.UID3 = 0x2005F2FB

    # IAP supporting
    LIBS += -liapclientapi  -lusrt2_2
    # DRM protection support
    LIBS += -lcaf -lcafutils -lapmime -lefsrv

    # capabilities required for IAP API
    TARGET.CAPABILITY += NetworkServices

    iap_dependency.pkg_prerules = "; Has dependency on IAP component" \
                                  "(0x200345C8), 0, 2, 2, {\"IAP\"}"


    # IAP API files to include in package
    addIapFiles.sources = ./items2sell/IAP_VARIANTID.txt #./items2sell/TEST_MODE.txt
    addIapFiles.path = ./

    DEPLOYMENT += iap_dependency addIapFiles

    # DRM protected purchasable items
    addDrm588547.source = items2sell/product_588547/resources
    addDrm588547.target = drm/data/resourceid_588547
    DEPLOYMENTFOLDERS += addDrm588547

    addDrm588549.source = items2sell/product_588549/resources
    addDrm588549.target = drm/data/resourceid_588549
    DEPLOYMENTFOLDERS += addDrm588549

    addDrm588550.source = items2sell/product_588550/resources
    addDrm588550.target = drm/data/resourceid_588550
    DEPLOYMENTFOLDERS += addDrm588550

    addDrm588551.source = items2sell/product_588551/resources
    addDrm588551.target = drm/data/resourceid_588551
    DEPLOYMENTFOLDERS += addDrm588551

    # execute function from qmlapplicationviewer/qmlapplicationviewer.pri
    qtcAddDeployment()
}