idiv32.S 2.1 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586
  1. /*
  2. * Copyright (C) 2000 Hewlett-Packard Co
  3. * Copyright (C) 2000 David Mosberger-Tang <davidm@hpl.hp.com>
  4. *
  5. * 32-bit integer division.
  6. *
  7. * This code is based on the application note entitled "Divide, Square Root
  8. * and Remainder Algorithms for the IA-64 Architecture". This document
  9. * is available as Intel document number 248725-002 or via the web at
  10. * http://developer.intel.com/software/opensource/numerics/
  11. *
  12. * For more details on the theory behind these algorithms, see "IA-64
  13. * and Elementary Functions" by Peter Markstein; HP Professional Books
  14. * (http://www.goodreads.com/book/show/2019887.Ia_64_and_Elementary_Functions)
  15. */
  16. #include <asm/asmmacro.h>
  17. #include <asm/export.h>
  18. #ifdef MODULO
  19. # define OP mod
  20. #else
  21. # define OP div
  22. #endif
  23. #ifdef UNSIGNED
  24. # define SGN u
  25. # define EXTEND zxt4
  26. # define INT_TO_FP(a,b) fcvt.xuf.s1 a=b
  27. # define FP_TO_INT(a,b) fcvt.fxu.trunc.s1 a=b
  28. #else
  29. # define SGN
  30. # define EXTEND sxt4
  31. # define INT_TO_FP(a,b) fcvt.xf a=b
  32. # define FP_TO_INT(a,b) fcvt.fx.trunc.s1 a=b
  33. #endif
  34. #define PASTE1(a,b) a##b
  35. #define PASTE(a,b) PASTE1(a,b)
  36. #define NAME PASTE(PASTE(__,SGN),PASTE(OP,si3))
  37. GLOBAL_ENTRY(NAME)
  38. .regstk 2,0,0,0
  39. // Transfer inputs to FP registers.
  40. mov r2 = 0xffdd // r2 = -34 + 65535 (fp reg format bias)
  41. EXTEND in0 = in0 // in0 = a
  42. EXTEND in1 = in1 // in1 = b
  43. ;;
  44. setf.sig f8 = in0
  45. setf.sig f9 = in1
  46. #ifdef MODULO
  47. sub in1 = r0, in1 // in1 = -b
  48. #endif
  49. ;;
  50. // Convert the inputs to FP, to avoid FP software-assist faults.
  51. INT_TO_FP(f8, f8)
  52. INT_TO_FP(f9, f9)
  53. ;;
  54. setf.exp f7 = r2 // f7 = 2^-34
  55. frcpa.s1 f6, p6 = f8, f9 // y0 = frcpa(b)
  56. ;;
  57. (p6) fmpy.s1 f8 = f8, f6 // q0 = a*y0
  58. (p6) fnma.s1 f6 = f9, f6, f1 // e0 = -b*y0 + 1
  59. ;;
  60. #ifdef MODULO
  61. setf.sig f9 = in1 // f9 = -b
  62. #endif
  63. (p6) fma.s1 f8 = f6, f8, f8 // q1 = e0*q0 + q0
  64. (p6) fma.s1 f6 = f6, f6, f7 // e1 = e0*e0 + 2^-34
  65. ;;
  66. #ifdef MODULO
  67. setf.sig f7 = in0
  68. #endif
  69. (p6) fma.s1 f6 = f6, f8, f8 // q2 = e1*q1 + q1
  70. ;;
  71. FP_TO_INT(f6, f6) // q = trunc(q2)
  72. ;;
  73. #ifdef MODULO
  74. xma.l f6 = f6, f9, f7 // r = q*(-b) + a
  75. ;;
  76. #endif
  77. getf.sig r8 = f6 // transfer result to result register
  78. br.ret.sptk.many rp
  79. END(NAME)
  80. EXPORT_SYMBOL(NAME)