relax-ng-textbook/src/reference-manual/compact.xsl

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:rng="http://relaxng.org/ns/structure/1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:d="http://dyomedea.com/ns/id" version="1.0" exclude-result-prefixes="rng d">
	<xsl:variable name="meta" select="document('../reference-manual/elements-meta.xml')"/>
	<xsl:variable name="schema" select="document('../reference-manual/compact-summary.rng')"/>
	<xsl:variable name="spaces" select="'                                '"/>
	<xsl:strip-space elements="*"/>
	<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

	<xsl:template match="*|@*|processing-instruction()">
		<xsl:copy>
			<xsl:apply-templates select="@*"/>
			<xsl:apply-templates select="*|text()"/>
		</xsl:copy>
	</xsl:template>

	<xsl:template match="get-reference">
		<xsl:apply-templates select="$schema//*[@d:id]" mode="production"/>
	</xsl:template>
	
	<xsl:template match="get-ebnf">
		<programlisting>
			<xsl:apply-templates select="$schema/*" mode="synopsis"/>
		</programlisting>
	</xsl:template>
	
	<xsl:template match="*[rng:ref/@name='datatypeName' and normalize-space(.) = '{}']" mode="name">
		<xsl:text>datatypeName param exceptPattern</xsl:text>
	</xsl:template>
	
	<xsl:template match="*[*[1][self::rng:ref] and *[2][self::rng:oneOrMore]]" mode="name">
		<xsl:value-of select="concat(rng:ref/@name, ' ', rng:oneOrMore/rng:value, ' ', rng:oneOrMore/rng:ref/@name)"/>
	</xsl:template>
	
	<xsl:template match="*" mode="production" name="production">
		<!--<xsl:comment><xsl:value-of select="@d:id"/></xsl:comment>-->
		<xsl:variable name="current-meta" select="$meta//refentry[@id=current()/@d:id]"/>
		<xsl:param name="title" select="$current-meta/compact"/>
		<xsl:param name="id" select="concat('ch16-', @d:id)"/>
		<refentry id="{$id}">
			<refmeta>
				<refentrytitle>
					<xsl:value-of select="$title"/>
				</refentrytitle>
			</refmeta>
			<refnamediv>
				<indexterm id="IXT-{generate-id()}">
					<primary>
						<xsl:value-of select="$title"/>
					</primary>
				</indexterm>
				<refname>
					<xsl:value-of select="$title"/>
				</refname>
				<xsl:apply-templates select="$current-meta/purpose" mode="meta"/>
			</refnamediv>
			<refsect1>
				<title>Class:</title>
				<para>
					<xsl:value-of select="ancestor::rng:define/@name"/>
				</para>
			</refsect1>
			<refsynopsisdiv>
				<synopsis>
					<xsl:text>&#xa;</xsl:text>
					<xsl:apply-templates select="." mode="synopsis">
						<xsl:with-param name="indent" select="0"/>
					</xsl:apply-templates>
					<xsl:text>&#xa;</xsl:text>
				</synopsis>
			</refsynopsisdiv>
			<refsect1>
				<title>May be included in:</title>
				<para>
					<xsl:apply-templates select="." mode="parent1"/>
				</para>
			</refsect1>
			<xsl:apply-templates select="$current-meta/name" mode="meta"/>
			<xsl:apply-templates select="$current-meta/compact-description" mode="meta"/>
			<xsl:apply-templates select="$current-meta/restrictions" mode="meta"/>
			<xsl:apply-templates select="$current-meta/compact-example" mode="meta"/>
		</refentry>
		
	</xsl:template>

	<xsl:template match="restrictions" mode="meta">
		<refsect1>
			<title>Restrictions:</title>
			<xsl:choose>
				<xsl:when test="para">
					<xsl:apply-templates mode="meta"/>
				</xsl:when>
				<xsl:otherwise>
					<para>
						<xsl:apply-templates mode="meta"/>
					</para>
				</xsl:otherwise>
			</xsl:choose>
		</refsect1>
	</xsl:template>

	<xsl:template match="rng:define" mode="parent1">
		<xsl:apply-templates select="//rng:ref[@name=current()/@name]" mode="parent2"/>
	</xsl:template>
	
	<xsl:template match="*" mode="parent1">
		<xsl:call-template name="searchParent"/>
	</xsl:template>
	
	<xsl:template match="*[@d:id]" mode="parent2" name="gotParent">
		<xsl:param name="depth" select="0"/>
		<literal>
			<xsl:value-of select="$meta//refentry[@id=current()/@d:id]/compact"/>
		</literal>
		<xsl:text>, </xsl:text>
	</xsl:template>

	<xsl:template match="*" mode="parent2" name="searchParent">
		<xsl:param name="depth" select="0"/>
		<xsl:apply-templates select="parent::*" mode="parent2">
			<xsl:with-param name="depth" select="$depth"/>
		</xsl:apply-templates>
	</xsl:template>
	
	<xsl:template match="rng:define" mode="parent2" priority="1">
		<xsl:param name="depth" select="0"/>
		<xsl:if test="$depth &lt; 2">
			<xsl:apply-templates select="//rng:ref[@name=current()/@name]" mode="parent2">
				<xsl:with-param name="depth" select="$depth+1"/>
			</xsl:apply-templates>
		</xsl:if>
	</xsl:template>
	
	<xsl:template match="name" mode="meta">
		<refsect1>
			<title>XML syntax equivalent:</title>
			<para>
				<xsl:apply-templates mode="meta"/>
			</para>
		</refsect1>
	</xsl:template>
	
	<xsl:template match="purpose" mode="meta">
		<refpurpose>
			<xsl:apply-templates mode="meta"/>
		</refpurpose>
	</xsl:template>
	
	<xsl:template match="compact-example" mode="meta">
		<refsect1>
			<title>Example:</title>
			<programlisting>
				<xsl:apply-templates mode="meta"/>
			</programlisting>
		</refsect1>
	</xsl:template>
	
	<xsl:template match="compact-description" mode="meta">
		<refsect1>
			<title>Description:</title>
			<xsl:apply-templates mode="meta"/>
		</refsect1>
	</xsl:template>
	
	<xsl:template match="*|@*" mode="meta">
		<xsl:copy>
			<xsl:apply-templates select="@*" mode="meta"/>
			<xsl:apply-templates mode="meta"/>
		</xsl:copy>
	</xsl:template>
	
	<xsl:template match="this|thisElement|thisParent" mode="meta">
		<literal><xsl:value-of select="ancestor::refentry/compact"/></literal>
	</xsl:template>
	
	<xsl:template match="this[@path]" mode="meta">
		<xsl:apply-templates select="ancestor::refentry/*[name()=current()/@path]/node()" mode="meta"/>
	</xsl:template>
	
	<xsl:template match="thisName" mode="meta">
		<literal><xsl:value-of select="ancestor::refentry/name"/></literal>
	</xsl:template>
	
	<xsl:template match="varlistentry//this" mode="meta">
		<xsl:copy-of select="ancestor::varlistentry/term/literal"/>
	</xsl:template>

	<xsl:template match="*" mode="synopsis">
		<xsl:comment>
			<xsl:value-of select="name()"/>
		</xsl:comment>
	</xsl:template>
	
	<xsl:template match="rng:grammar|rng:group|rng:choice|rng:oneOrMore|rng:zeroOrMore" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:apply-templates mode="synopsis"/>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:choice[count(*) > 1 and (not(parent::rng:define) or preceding-sibling::* or following-sibling::*)]|rng:oneOrMore[count(*) > 1]|rng:zeroOrMore[count(*) > 1]" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:text>(</xsl:text>
		<xsl:apply-templates mode="synopsis"/>
		<xsl:text>)</xsl:text>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:define" mode="synopsis">
		<xsl:text>&#xa;</xsl:text>
		<xsl:value-of select="@name"/>
		<xsl:value-of select="substring($spaces, 1, 20 - string-length(@name))"/>
		<xsl:text>::= </xsl:text>
		<xsl:apply-templates mode="synopsis"/>
	</xsl:template>
	
	<xsl:template match="rng:optional" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:text>[</xsl:text>
		<xsl:apply-templates mode="synopsis"/>
		<xsl:text>]</xsl:text>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:ref" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<emphasis>
			<xsl:value-of select="@name"/>
		</emphasis>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:data" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:if test="*">(</xsl:if>
		<emphasis>
			<xsl:value-of select="@type"/>
		</emphasis>
		<xsl:apply-templates mode="synopsis"/>
		<xsl:if test="*">)</xsl:if>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:except" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:text> - </xsl:text>
		<xsl:if test="count(*) > 1">(</xsl:if>
		<xsl:apply-templates mode="synopsis"/>
		<xsl:if test="count(*) > 1">)</xsl:if>
		<xsl:apply-templates select="." mode="suffix"/>
	</xsl:template>
	
	<xsl:template match="rng:value" mode="synopsis">
		<xsl:param name="indent" select="1"/>
		<xsl:apply-templates select="." mode="prefix">
			<xsl:with-param name="indent" select="$indent"/>
		</xsl:apply-templates>
		<xsl:text>"</xsl:text>
		<xsl:value-of select="."/>
		<xsl:apply-templates select="." mode="suffix"/>
		<xsl:text>"</xsl:text>
	</xsl:template>

	<xsl:template match="*" mode="prefix"/>
	<xsl:template match="*[preceding-sibling::* and not(parent::rng:choice)]" mode="prefix">
		<xsl:text> </xsl:text>
	</xsl:template>
	<xsl:template match="*[preceding-sibling::* and parent::rng:choice]" mode="prefix">
		<xsl:param name="indent" select="1"/>
		<xsl:if test="$indent = 1">
			<xsl:if test="parent::rng:choice[parent::rng:define and not(preceding-sibling::*|following-sibling::*)]">
				<xsl:text>&#xa;</xsl:text>
				<xsl:value-of select="substring($spaces, 1, 24)"/>
			</xsl:if>
			<xsl:text>|</xsl:text>
		</xsl:if>
	</xsl:template>
	
	<xsl:template match="*" mode="suffix"/>
	<xsl:template match="rng:zeroOrMore" mode="suffix">
		<xsl:text>*</xsl:text>
	</xsl:template>
	<xsl:template match="rng:oneOrMore" mode="suffix">
		<xsl:text>+</xsl:text>
	</xsl:template>

</xsl:stylesheet>