123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293 |
- dnl AC_VALIDATE_CACHE_SYSTEM_TYPE[(cmd)]
- dnl if the cache file is inconsistent with the current host,
- dnl target and build system types, execute CMD or print a default
- dnl error message.
- AC_DEFUN(AC_VALIDATE_CACHE_SYSTEM_TYPE, [
- AC_REQUIRE([AC_CANONICAL_SYSTEM])
- AC_MSG_CHECKING([config.cache system type])
- if { test x"${ac_cv_host_system_type+set}" = x"set" &&
- test x"$ac_cv_host_system_type" != x"$host"; } ||
- { test x"${ac_cv_build_system_type+set}" = x"set" &&
- test x"$ac_cv_build_system_type" != x"$build"; } ||
- { test x"${ac_cv_target_system_type+set}" = x"set" &&
- test x"$ac_cv_target_system_type" != x"$target"; }; then
- AC_MSG_RESULT([different])
- ifelse($#, 1, [$1],
- [AC_MSG_ERROR(["you must remove config.cache and restart configure"])])
- else
- AC_MSG_RESULT([same])
- fi
- ac_cv_host_system_type="$host"
- ac_cv_build_system_type="$build"
- ac_cv_target_system_type="$target"
- ])
- dnl Check for socklen_t: historically on BSD it is an int, and in
- dnl POSIX 1g it is a type of its own, but some platforms use different
- dnl types for the argument to getsockopt, getpeername, etc. So we
- dnl have to test to find something that will work.
- dnl This is no good, because passing the wrong pointer on C compilers is
- dnl likely to only generate a warning, not an error. We don't call this at
- dnl the moment.
- AC_DEFUN([TYPE_SOCKLEN_T],
- [
- AC_CHECK_TYPE([socklen_t], ,[
- AC_MSG_CHECKING([for socklen_t equivalent])
- AC_CACHE_VAL([rsync_cv_socklen_t_equiv],
- [
- # Systems have either "struct sockaddr *" or
- # "void *" as the second argument to getpeername
- rsync_cv_socklen_t_equiv=
- for arg2 in "struct sockaddr" void; do
- for t in int size_t unsigned long "unsigned long"; do
- AC_TRY_COMPILE([
- #include <sys/types.h>
- #include <sys/socket.h>
- int getpeername (int, $arg2 *, $t *);
- ],[
- $t len;
- getpeername(0,0,&len);
- ],[
- rsync_cv_socklen_t_equiv="$t"
- break
- ])
- done
- done
- if test "x$rsync_cv_socklen_t_equiv" = x; then
- AC_MSG_ERROR([Cannot find a type to use in place of socklen_t])
- fi
- ])
- AC_MSG_RESULT($rsync_cv_socklen_t_equiv)
- AC_DEFINE_UNQUOTED(socklen_t, $rsync_cv_socklen_t_equiv,
- [type to use in place of socklen_t if not defined])],
- [#include <sys/types.h>
- #include <sys/socket.h>])
- ])
- dnl AC_HAVE_TYPE(TYPE,INCLUDES)
- AC_DEFUN([AC_HAVE_TYPE], [
- AC_REQUIRE([AC_HEADER_STDC])
- cv=`echo "$1" | sed 'y%./+- %__p__%'`
- AC_MSG_CHECKING(for $1)
- AC_CACHE_VAL([ac_cv_type_$cv],
- AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
- AC_INCLUDES_DEFAULT
- $2]],
- [[$1 foo;]])],
- [eval "ac_cv_type_$cv=yes"],
- [eval "ac_cv_type_$cv=no"]))dnl
- ac_foo=`eval echo \\$ac_cv_type_$cv`
- AC_MSG_RESULT($ac_foo)
- if test "$ac_foo" = yes; then
- ac_tr_hdr=HAVE_`echo $1 | sed 'y%abcdefghijklmnopqrstuvwxyz./- %ABCDEFGHIJKLMNOPQRSTUVWXYZ____%'`
- if false; then
- AC_CHECK_TYPES($1)
- fi
- AC_DEFINE_UNQUOTED($ac_tr_hdr, 1, [Define if you have type `$1'])
- fi
- ])
|