joy-in-the-morning/configure.ac

# Joy -- implementation of the Joy programming language
# Copyright © 2016, 2020 Eric Bavier <bavier@member.fsf.org>
#
# Joy is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 3 of the License, or (at your
# option) any later version.
#
# Joy is distributed in the hope that it will be useful, but WITHOUT
# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
# License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Joy.  If not, see <http://www.gnu.org/licenses/>.

AC_PREREQ(2.68)
AC_INIT([Joy], [1.0.1], [bavier@member.fsf.org], [joy],
  [http://notabug.org/bavier/joy-in-the-morning])
AC_CONFIG_AUX_DIR([build-aux])

dnl Use -Wno-portability for custom silent rules
AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
 color-tests parallel-tests -Woverride -Wno-portability])

# Enable silent rules by default.
AM_SILENT_RULES([yes])

AC_CONFIG_TESTDIR([tests],[scripts])

AC_CANONICAL_HOST

dnl Search for 'guile' and 'guild'.  This macro defines
dnl 'GUILE_EFFECTIVE_VERSION'.
GUILE_PKG([3.0 2.2 2.0])
GUILE_PROGS
if test "x$GUILD" = "x"; then
   AC_MSG_ERROR(['guild' binary not found; please check your guile installation.])
fi
dnl Installation directories for .scm and .go files.
guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
AC_SUBST([guilemoduledir])
AC_SUBST([guileobjectdir])

AC_CHECK_PROGS([GREP], [grep egrep])

AM_MISSING_PROG([HELP2MAN], help2man])

AC_CONFIG_FILES([Makefile
                 joy/config.scm
		 tests/atlocal])
AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])

AM_PATH_LISPDIR
dnl for byte-compiling joy-mode.el?
AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])

AC_OUTPUT