abslibre/libre/freecad/PKGBUILD

# Maintainer (arch): Alexander F. Rødseth <xyproto@archlinux.org>
# Contributor: loqs <bugs-archlinux@entropy-collector.net>
# Contributor: Gabriel Souza Franco <gabrielfrancosouza@gmail.com>
# Contributor: Florian Pritz
# Contributor: Jonas Heinrich <onny@project-insanity.org>
# Contributor: Jordi De Groof <jordi.degroof@gmail.com>
# Contributor: mickele
# Contributor: manwithgrenade
# Contributor: bricem13
# Contributor: gborzi
# Contributor: Adrian Insaurralde


# parabola changes and rationale:
#   - build without webengine
#   - disable downloader
#   - build from versioned source-ball, not VCS
#   - pin to strongly-coupled dependency versions

# FIXME: this package fails to build with libretools, without the -N flag
#        -> could NOT find MPI (missing: MPI_C_FOUND MPI_CXX_FOUND)


pkgname=freecad
_upstream_name=FreeCAD
pkgver=0.20.2
pkgrel=4
pkgrel+=.parabola1
pkgdesc='Feature based parametric 3D CAD modeler'
arch=(x86_64)
arch+=(armv7h) # 'med-openmpi' is unavailable for i686
url='https://freecadweb.org/'
license=(LGPL)
depends=(boost-libs coin fmt glew jsoncpp libspnav med-openmpi netcdf
         opencascade openmpi pugixml pyside2 pyside2-tools python-gitpython
         python-markdown python-matplotlib python-pip python-pivy python-ply
         python-yaml qt5-svg qt5-tools qt5-webengine qt5-x11extras
         qt5-xmlpatterns xerces-c)
depends=( ${depends[*]/python-pip/} )
depends=( ${depends[*]/qt5-webengine/qt5-webkit} )
makedepends=(boost cgns cmake eigen git libharu liblas ninja openvdb openvr
             ospray pdal postgresql-libs python-mpi4py python-shiboken2
             qt5-webengine shiboken2 swig utf8cpp)
makedepends=( ${makedepends[*]/qt5-webengine/} )                        # redundant entry
makedepends=( ${makedepends[*]/git/} )                                  # build from source-ball
[[ "${CARCH}" == x86_64 ]] || makedepends=( ${makedepends[*]/ospray/} ) # unavailable for i686 and armv7h
optdepends=('graphviz: dependency graph support'
            'openscad: OpenSCAD support')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/refs/tags/${pkgver}.tar.gz)
sha256sums=(46922f3a477e742e1a89cd5346692d63aebb2b67af887b3e463e094a4ae055da)


_version_constraint() # (dep_pkgname [precision])
{
  local dep_pkgname=$1
  local full_version=$(pacman -S --print-format='%v' ${dep_pkgname} | tail -n 1)
  local n_dots=$(tmp=${full_version%-*} ; tmp=${tmp//[^\.]} ; echo "${#tmp}" ;)
  local def_precision=$(( n_dots + 1 ))
  local precision=$( [[ "$2" =~ ^[1-${def_precision}]$ ]] && echo $2 || echo ${def_precision} )
  local pkgver_rx='[^-\.\ ]+'
  local subver_rx='\.'${pkgver_rx}
  local pkgrel_rx='[^-\ ]+'
  local capture_rx=${pkgver_rx}
  for (( n_dots=1 ; n_dots < precision ; n_dots++ )) ; do capture_rx+=${subver_rx} ; done ;

  if   [[ "${full_version}" =~ ^(${capture_rx})(${subver_rx})*-${pkgrel_rx}$ ]]
  then local version=${BASH_REMATCH[1]}
       local subver_inc=$(( ${version##*.} + 1 ))
       local version_inc=$( [[ "${version}" =~ \. ]] && echo ${version%.*}.${subver_inc} || \
                                                        echo ${subver_inc}                  )
       local constraint_string="${dep_pkgname}>=${version} ${dep_pkgname}<${version_inc}"

       echo "applied version constraint: ${constraint_string}" >&2
       echo -n "${constraint_string}"
  else echo "ERROR: _version_constraint() error parsing: dep_pkgname='${dep_pkgname}' full_version='${full_version}'" >&2
       exit 1
  fi
}


build() {
  cmake \
    -B build \
    -D BUILD_ENABLE_CXX_STD=C++17 \
    -D BUILD_FLAT_MESH=ON \
    -D BUILD_QT5=ON \
    -D BUILD_ADDONMGR=OFF \
    -D CMAKE_BUILD_TYPE=Release \
    -D CMAKE_C_FLAGS="$CFLAGS -ffat-lto-objects -fPIC -w" \
    -D CMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects -fPIC -w" \
    -D CMAKE_INSTALL_BINDIR=/usr/lib/freecad/bin \
    -D CMAKE_INSTALL_DATADIR=/usr/share/freecad \
    -D CMAKE_INSTALL_DATAROOTDIR=/usr/share \
    -D CMAKE_INSTALL_DOCDIR=/usr/share/freecad/doc \
    -D CMAKE_INSTALL_LIBDIR=/usr/lib/freecad/lib \
    -D CMAKE_INSTALL_PREFIX=/usr/lib/freecad \
    -D FREECAD_USE_EXTERNAL_PIVY=ON \
    -D FREECAD_USE_OCC_VARIANT='Official Version' \
    -D FREECAD_USE_QT_FILEDIALOG=ON \
    -D PYTHON_EXECUTABLE=/usr/bin/python \
    -D INSTALL_TO_SITEPACKAGES=ON \
    -G Ninja \
    -S ${_upstream_name}-${pkgver} \
    -W no-dev
  ninja -C build
}

package() {
  # pin to strongly-coupled dependency versions
  depends=( ${depends[*]/boost-libs/} )
  depends+=( $(_version_constraint boost-libs 3) )

  DESTDIR="$pkgdir" ninja -C build install

  cd "${srcdir}"/${_upstream_name}-${pkgver}

  # thumbnailer
  install -Dm755 src/Tools/$pkgname-thumbnailer -t "$pkgdir/usr/bin/"

  # symlinks
  install -d "$pkgdir/usr/bin"
  ln -sf /usr/lib/freecad/bin/FreeCAD "$pkgdir/usr/bin/freecad"
  ln -sf /usr/lib/freecad/bin/FreeCAD "$pkgdir/usr/bin/FreeCAD"
  ln -sf /usr/lib/freecad/bin/FreeCADCmd "$pkgdir/usr/bin/freecadcmd"
  ln -sf /usr/lib/freecad/bin/FreeCADCmd "$pkgdir/usr/bin/FreeCADCmd"
}