abslibre/nonprism/redshift/PKGBUILD

# Maintainer (arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Geoffrey Teale <tealeg@stop-squark>
# Contributor: Mark, Huo Mian <markhuomian[at]gmail[dot]com>
# Contributor: Biginoz <biginoz a free dot fr>
# Contributor: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=redshift
pkgver=1.12
pkgrel=2.nonprism1
pkgdesc='Adjusts the color temperature of your screen according to your surroundings, without geoclue2 support'
arch=('i686' 'x86_64' 'armv7h')
url='http://jonls.dk/redshift/'
license=('GPL3')
depends=('libdrm' 'libxcb' 'libxxf86vm')
optdepends=('python-gobject: for redshift-gtk'
            'python-xdg: for redshift-gtk'
            'gtk3: for redshift-gtk')
makedepends=('intltool' 'python')
source=("https://github.com/jonls/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('d2f8c5300e3ce2a84fe6584d2f1483aa9eadc668ab1951b2c2b8a03ece3a22ba')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr --enable-drm --enable-randr --enable-vidmode \
    --with-systemduserunitdir=/usr/lib/systemd/user
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
}