abslibre/nonprism/kio/PKGBUILD

# Maintainer (arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: grizzlyuser <grizzlyuser@protonmail.com>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
#  - replace non-privacy search engines
#  - pin to strongly-coupled dependency versions


pkgname=kio
pkgver=5.103.0
pkgrel=1
pkgrel+=.parabola1
_pkgver_i686=5.100.0
_pkgrel_i686=1.1.parabola1
[[ "${CARCH}" == i686 ]] && eval "pkgver=\$_pkgver_${CARCH}" # our different arches do not
[[ "${CARCH}" == i686 ]] && eval "pkgrel=\$_pkgrel_${CARCH}" # always roll at the same speed
pkgdesc='Resource and network access abstraction'
pkgdesc+=', with privacy-respecting search engines only'
arch=(x86_64)
arch+=(armv7h i686)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(solid kjobwidgets kbookmarks libxslt kwallet ktextwidgets kded)
depends=( ${depends[*]/kded/kded=$pkgver} ) # pin version to other k-things
makedepends=(extra-cmake-modules kdoctools doxygen qt5-tools qt5-doc)
optdepends=('kio-extras: extra protocols support (sftp, fish and more)' 'kdoctools: for the help kioslave'
            'kio-fuse: to mount remote filesystems via FUSE')
groups=(kf5)
source=(https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz{,.sig})
source+=(duckduckgo_html.desktop
         duckduckgo_lite.desktop
         gnupg-keys.desktop
         internet-archive.desktop
         parabola-packages.desktop
         parabola-wiki.desktop
         searx.desktop
         yacy.desktop)
sha256sums=('0b4837365aa489cc4007badb21f49e7d7729b758020cf2a0717ab12fbf97f447'
            'SKIP')
sha256sums+=('31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
             '40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d'
             '57ded4375e1ddfe747bc55e3c52f4f39d1688f583c6af77da3479f544d262b71'
             '5e57f0978b3429dfd2e97f215ab58394dd4c19c5b7e1b6bea9733eae92253e1a'
             '7960cfc6b5a4030898cdd9d4699732fd7c1995983a0762ed1121aa2589beedc3'
             '45af1a8588246c64c2e306237ef605406c5289c2ff53b5f459315c40c8e5099b'
             '0264268855ac59872fe6bde4ce5c7d5f4a9b4d6936f3c2f870fc9a34de323c54'
             '0a494a6bd652533b2ac1ea6a139e8b7295da29f840e5d0d7b2aa7e18886887ef')
_sha256sum_i686='088788d32eb38016d92c2fdfe29f337332089efa1f0d3a810cf807c2646d7cb6' # upstream source-ball
[[ "${CARCH/i686/}" ]] || eval "sha256sums[0]=\$_sha256sum_${CARCH}"               # upstream source-ball
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>
options=(debug)


prepare() {
  cd "${srcdir}"/${pkgname}-${pkgver}/

  # replace default search engines
  local searchengines_dir=src/urifilters/ikws/searchproviders
  find ${searchengines_dir}/         \
       -name *.desktop               \
       -not -name duckduckgo.desktop \
       -not -name fsd.desktop        \
       -not -name wikipedia.desktop  \
       -not -name wiktionary.desktop \
       -exec rm -f {} \;
  cp -v "${srcdir}"/*.desktop ${searchengines_dir}/
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}