abslibre/libre/libxfce4ui/PKGBUILD

# Maintainer (Arch): Evangelos Foutras <evangelos@foutrelis.com>
# Contributor (Arch): Xavier Devlamynck <magicrhesus@ouranos.be>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>


# parabola changes and rationale
# - rebranded "about" modal


pkgname=libxfce4ui
pkgver=4.16.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Commonly used Xfce widgets among Xfce applications"
pkgdesc+=" (Parabola rebranded)"
arch=('x86_64')
arch+=('armv7h' 'i686')
url="https://www.xfce.org/"
license=('GPL2')
depends=('libxfce4util' 'gtk3' 'xfconf' 'libsm' 'startup-notification'
         'libgtop' 'libepoxy' 'hicolor-icon-theme')
makedepends=('intltool' 'gobject-introspection' 'vala')
source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
sha256sums=('8b06c9e94f4be88a9d87c47592411b6cbc32073e7af9cbd64c7b2924ec90ceaa')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libexecdir=/usr/lib \
    --localstatedir=/var \
    --disable-static \
    --disable-debug \
    --with-vendor-info='Parabola GNU/Linux-libre'
  make
}

package() {
  # pin to tightly-coupled dependency versions
  depends+=( "xfce4-session=${pkgver}" )

  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}