abslibre/libre-testing/pacman/PKGBUILD

# Maintainer (Arch): Dan McGee <dan@archlinux.org>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Nicolás Reynolds <fauno@kiwwwi.com.ar>
# Contributor: Daniel Milewski <niitotantei@riseup.net>

pkgname=pacman
pkgver=5.2.1
pkgrel=4
pkgrel+=.parabola3
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://www.archlinux.org/pacman/"
license=('GPL')
groups=('base-devel')
depends=('bash' 'glibc' 'libarchive' 'curl'
         'gpgme' 'pacman-mirrorlist' 'archlinux-keyring')
depends+=('parabola-keyring' 'archlinuxarm-keyring' 'archlinux32-keyring')
makedepends=('asciidoc')
checkdepends=('python' 'fakechroot')
optdepends=('perl-locale-gettext: translation support in makepkg-template')
provides=('libalpm.so')
provides+=('pacman-parabola')
conflicts=('pacman-parabola')
replaces=('pacman-parabola')
backup=(etc/pacman.conf
        etc/makepkg.conf)
options=('strip' 'debug')
validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD'  # Allan McRae <allan@archlinux.org>
              'B8151B117037781095514CA7BBDFFC92306B1121') # Andrew Gregory (pacman) <andrew@archlinux.org>
source=(https://sources.archlinux.org/other/pacman/$pkgname-$pkgver.tar.gz{,.sig}
        pacman-5.2.1-fix-pactest-package-tar-format.patch::https://git.archlinux.org/pacman.git/patch/?id=b9faf652735c603d1bdf849a570185eb721f11c1
        makepkg-fix-one-more-file-seccomp-issue.patch
        "${arch[@]/#/pacman.conf.}"
        makepkg.conf.in
        pacman-keyring.service
        pacman-keyring.timer
        0004-makepkg-Treat-pkgrel-more-similarly-to-pkgver.patch)
source_armv7h=(0001-Sychronize-filesystem.patch
               0002-Revert-close-stdin-before-running-install-scripts.patch
               0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch)
sha256sums=('1930c407265fd039cb3a8e6edc82f69e122aa9239d216d9d57b9d1b9315af312'
            'SKIP'
            'd268379269c9dfa6eb3358f8931d3c84ef5fa4d47fe22567022fcbac8e4638c1'
            'e481a161bba76729cd434c97e0b319ddfcb1d93b2e4890d72b4e8a32982531d9'
            '509a4f253a17670b9def43a0daa3aa17f113961aec65429d1996c93478d6693f'
            'e5632e1581a4283cf8b93f0d32618fc7a35480c9caaf2d256c95f77645ae4265'
            'd9bed26a58377b726ebadabd9729008e484f8719632b9c3e76c9320c2fcaa22c'
            '78be8885fd61999cdd65e61ceb70eed3828fd87f89dec19f4a04d87c8924d451'
            '220f1b25a64727041dc6fa3fd486b0a043f735a3f6cecedc4e2f7c47ec6ce66d'
            '2a857061f032ff5485f5c75ab74e6f6532621e08963ef48640a792cca16cacd6'
            '9ccc7ef5bd27a68d8788f10c6e5b36495c5d9038d4eb160f9ea4dc9901b622d8')
sha256sums_armv7h=('8d70fb5094f58aad98b601bbc42be354c2014b9fe734a1ee0b1e14bb041cc9cc'
                   '0e771370da68c855bfb4eaad4c2ae137883a474886a049b934dac2e775574cb9'
                   '2f586f72c34150330389854575a21be1d3ef3637c4f94bec2e948c2717a5aecb')

prepare() {
  cd "$pkgname-$pkgver"

  patch -Np1 < ../pacman-5.2.1-fix-pactest-package-tar-format.patch
  patch -Np1 < ../makepkg-fix-one-more-file-seccomp-issue.patch

  # From Arch ARM
  if [ "${CARCH}" = "armv7h" ]; then
    patch -p1 -i ../0001-Sychronize-filesystem.patch
    patch -p1 -i ../0002-Revert-close-stdin-before-running-install-scripts.patch
    patch -p1 -i ../0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch
  fi

  # From Parabola
  patch -p1 -i ../0004-makepkg-Treat-pkgrel-more-similarly-to-pkgver.patch
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --enable-doc \
    --with-scriptlet-shell=/usr/bin/bash \
    --with-ldconfig=/usr/bin/ldconfig
  make V=1

  # Generate the architecture-specific makepkg.conf files
  local carch mycarch mychost myflags myldflags
  for carch in "${arch[@]}"; do
    case $carch in
      i686)
        mycarch="i686"
        mychost="i686-pc-linux-gnu"
        myflags="-march=i686 -mtune=generic -O2 -pipe -fno-plt"
        ;;
      x86_64)
        mycarch="x86_64"
        mychost="x86_64-pc-linux-gnu"
        myflags="-march=x86-64 -mtune=generic -O2 -pipe -fno-plt"
        ;;
      armv7h)
        mycarch="armv7h"
        mychost="armv7l-unknown-linux-gnueabihf"
        myflags="-march=armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16 -O2 -pipe -fno-plt"
        ;;
    esac
    myldflags="-Wl,-O1,--sort-common,--as-needed,-z,relro,-z,now"

    # set things correctly in the default conf file
    sed < "$srcdir/makepkg.conf.in" > "$srcdir/makepkg.conf.$carch" \
        -e "s|@CARCH[@]|$mycarch|g" \
        -e "s|@CHOST[@]|$mychost|g" \
        -e "s|@CARCHFLAGS[@]|$myflags|g" \
        -e "s|@LDFLAGS[@]|$myldflags|g"
  done
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  # install distro-specific stuff
  install -dm755 "$pkgdir"/etc/{makepkg,pacman}.d
  install -m644 "$srcdir/pacman.conf.$CARCH" "$pkgdir/etc/pacman.conf"
  install -m644 "$srcdir/makepkg.conf.$CARCH" "$pkgdir/etc/makepkg.conf"
  echo '# There must be at least 1 file matching /etc/pacman.d/*.conf' > "$pkgdir/etc/pacman.d/empty.conf"

  install -dm755 "$pkgdir/usr/share/pacman/defaults"
  local carch
  for carch in "${arch[@]}"; do
    install -m644 "$srcdir/pacman.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
    install -m644 "$srcdir/makepkg.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
  done

  # Parabola's pacman began shipping a weekly job for this back in
  # 2014.  Why is it nescessary for Parabola installs, but it
  # seemingly isn't for Arch installs?
  install -Dm644 "$srcdir/pacman-keyring.service" "$pkgdir/usr/lib/systemd/system/pacman-keyring.service"
  install -Dm644 "$srcdir/pacman-keyring.timer" "$pkgdir/usr/lib/systemd/system/pacman-keyring.timer"
  install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/system-preset/90-pacman.preset" <<<"enable pacman-keyring.timer"
}