abslibre/nonprism/gnome-online-accounts/PKGBUILD

# $Id$
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Maintainers: Parabola hackers <dev@lists.parabola.nu>

# parabola changes and rationale:
#  - removed support for possibly unsafe protocols

pkgname=gnome-online-accounts
pkgver=3.34.1
pkgrel=1.nonprism1
pkgdesc="Single sign-on framework for GNOME, without support for unsafe and dangerous for privacy protocols"
url="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
arch=(x86_64 i686 armv7h)
license=(LGPL)
depends=(webkit2gtk json-glib libnotify rest libsecret telepathy-glib krb5 gcr)
makedepends=(gobject-introspection gtk-doc vala autoconf-archive gnome-common git)
optdepends=('gvfs-goa: Virtual file systems (e.g. OwnCloud)')

_commit=a57487846b75dccd7a272f8682d647766ce222cd  # tags/3.34.1^0
source=("git+https://git.gnome.org/browse/gnome-online-accounts#commit=$_commit"
        "git+https://git.gnome.org/browse/telepathy-account-widgets")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.telepathy-account-widgets.url "$srcdir/telepathy-account-widgets"
  git submodule update

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib \
    --disable-static \
    --enable-compile-warnings=minimum \
    --enable-inspector \
    --enable-media-server \
    --enable-kerberos \
    --enable-telepathy \
    --enable-owncloud \
    --enable-imap-smtp \
    --disable-lastfm \
    --disable-todoist \
    --disable-exchange \
    --disable-facebook \
    --disable-flickr \
    --disable-google \
    --disable-pocket \
    --disable-windows-live \
    --disable-twitter \
    --disable-yahoo \
    --disable-foursquare \
    --enable-gtk-doc

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}