abslibre/libre/ponysay/PKGBUILD

# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): Erkin Batu Altunbaş <erkinbatu@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=ponysay-libre
pkgname=ponysay
pkgver=3.0.3
pkgrel=1.parabola1
pkgdesc="cowsay reimplemention for ponies, without nonfree pony graphics"
url="http://erkin.github.com/ponysay/"
arch=('any')
license=('GPL3')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('python' 'bash')
makedepends=('git')
mksource=("ponysay-$pkgver.tar.gz::https://github.com/erkin/ponysay/tarball/$pkgver")
source=("https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver.tar.gz")
mksha512sums=('ee4340b3a4902465217fcf0e0a31acf2771697ebfff9ce1897d5e0062782efd36ceb91672a6eb45a9b70aeb7f50f48e2ebd7671dab3cf5af1ec4043f2767edd7')
sha512sums=('460dd96fd54494bcfb51983030a54fc57aca6ea17761f2679cb754472a62e3c9532ec9f1af9aa09f5c4dcea510964cfaf05cae31500a45e23ddbd5886c503bc1')

mksource() {
  cd "$srcdir/erkin-ponysay-"*

  # Generate a nonfree pony graphics list to replace it with empty files
  # NOTE: empty files are necessary for the building checking only, --freedom=strict will not include them for the packaging
  grep -rIl 'FREE: sharable' | cat > nonfree-pony-graphics-list.txt
  grep -rIl 'FREE: no' | cat >> nonfree-pony-graphics-list.txt

  # Remove nonfree pony graphics
  rm -v $(grep -rIl 'FREE: sharable')
  rm -v $(grep -rIl 'FREE: no')

  # Generate empty files
  for x in $(cat nonfree-pony-graphics-list.txt); do
    touch $x
  done

  # Remove list
  rm -v nonfree-pony-graphics-list.txt
}

package() {
  cd "$srcdir/erkin-ponysay-"*

  python3 setup.py --prefix=/usr --dest-dir=$pkgdir --freedom=strict --everything --with-pdf=/usr/share/doc/ponysay --without-pdf-compression install
}