abslibre/libre-testing/uboot4grub-omap3_beagle/PKGBUILD

# U-Boot: BeagleBoard and BeagleBoard-xM
# Maintainer: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgname=uboot4grub-omap3_beagle
pkgver=2015.04
pkgrel=2
pkgdesc="U-Boot with GRUB support for BeagleBoard and BeagleBoard-xM"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
depends=('grub-beagleboard')
makedepends=('bc')
replaces=('uboot-beagleboard' 'uboot-beagleboard-linux-libre' 'uboot-beagleboard-linux-libre-lts'
          'uboot-beagleboard-linux-libre-grsec' 'uboot-beagleboard-linux-libre-pck'
          'uboot-beagleboard-linux-libre-knock' 'uboot-beagleboard-linux-libre-lts-knock'
          'uboot-beagleboard-linux-libre-audit' 'uboot-beagleboard-linux-libre-rt'
          'uboot-beagleboard-linux-libre-grsec-knock')
conflicts=('uboot-beagleboard' 'uboot-beagleboard-linux-libre' 'uboot-beagleboard-linux-libre-lts'
           'uboot-beagleboard-linux-libre-grsec' 'uboot-beagleboard-linux-libre-pck'
           'uboot-beagleboard-linux-libre-knock' 'uboot-beagleboard-linux-libre-lts-knock'
           'uboot-beagleboard-linux-libre-audit' 'uboot-beagleboard-linux-libre-rt'
           'uboot-beagleboard-linux-libre-grsec-knock' 'uboot4grub')
provides=('uboot-beagleboard' 'uboot4grub')

source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications+grub-support.patch'
        'uEnv.txt')
md5sums=('570bdc2c47270c2a98ca60ff6c5c74cd'
         '0191ec435ed2eb1d02d0f9178296146c'
         'd41d8cd98f00b204e9800998ecf8427e')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications+grub-support.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS CFLAGS CXXFLAGS

  make distclean 
  make omap3_beagle_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}"/boot
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
}