abslibre/unmaintained/uboot-omap4_panda/PKGBUILD

# U-Boot: PandaBoard and PandaBoard ES
# Maintainer: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgname=uboot-omap4_panda
pkgver=2016.01
pkgrel=1
pkgdesc="U-Boot for PandaBoard and PandaBoard ES"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
replaces=('uboot-pandaboard-linux-libre' 'uboot-pandaboard')
conflicts=('uboot4extlinux-omap4_panda' 'uboot4grub-omap4_panda')
makedepends=('bc')
depends=('linux-libre')
license=('GPL')
install=${pkgname}.install
backup=('boot/uEnv.txt')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'uEnv.txt')
md5sums=('7d4f65fd43d4d706f5c5650e020d899d'
         'e47c5f7b3bf0504ce36ce718eb982a77'
         '86004660f2912861a040e335c9c0e85b')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS

  make distclean
  make omap4_panda_config
  make
}

package() {
  cd u-boot-${pkgver}

  mkdir -p "${pkgdir}"/boot
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
}