abslibre/libre/quassel/PKGBUILD

# Maintainer (arch): Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: Vesa Kaihlavirta <vegai@iki.fi>
# Maintainer: bill-auger <bill-auger@programmer.net>

# parabola changes and rationale:
# - repalce qt5-webengine with qt5-webkit (for URL previews)


pkgbase=quassel
pkgname=('quassel-core'
         'quassel-client'
         'quassel-client-small'
         'quassel-monolithic')
pkgver=0.13.1
pkgrel=4
pkgrel+=.parabola1
pkgdesc="Next-generation distributed IRC client"
arch=('x86_64')
arch+=('armv7h' 'i686')
url="https://quassel-irc.org/"
license=('GPL')
makedepends=('qt5-base' 'qt5-tools' 'qt5-webengine' 'qca-qt5' 'qt5-script'
             'qt5-multimedia' 'knotifyconfig' 'sonnet' 'libldap' 'cmake'
             'extra-cmake-modules' 'python' 'hicolor-icon-theme')
makedepends=(${makedepends[*]/qt5-webengine/qt5-webkit})
source=(https://quassel-irc.org/pub/$pkgbase-$pkgver.tar.bz2
        0001-qtui-Set-desktop-file-name.patch
        quassel-0.13.1-qt5.14.patch
        search-duck.patch
        $pkgbase.service
        $pkgbase.sysusers
        $pkgbase.tmpfiles
        $pkgbase.conf)
sha256sums=('48efee9778743b1db9f44efb91d1c913104db01190c57f2ff57483c39a97e855'
            '695ff3b605ea62ccfdf9ec4b9e6ffa74f3e2c0ac81402d51a74d263c47886c92'
            '3d43f498df04db59a5199e0a81b8fd7ac37ef46fffb0c69ab5a17bcafb6d8c65'
            '3d90a7edfa2b2e27e5f56b25f7583585efbcd35219c04a3bf138d9fe9bb9eab2'
            '5dbe20290f3361b9b7a74a52905137e76b656976febf2d31082a2276f9dcde7f'
            '3c72441a99e2668c6a8a751fa07beeb44f937576c8a1b5f615e4a55f841d93d9'
            '2afd4340c7713f6533e5d175a86b28fd118ecd907776c2b10925d1a4fb31cdca'
            'f3031ea8217e01ba42cea14606169e3e27affa5918968ffd5a03c21ae92fe2b8')

prepare() {
  cd $pkgbase-$pkgver
  patch -Np1 -i ../0001-qtui-Set-desktop-file-name.patch
  patch -Np1 -i ../quassel-0.13.1-qt5.14.patch
  patch -Np1 -i ../search-duck.patch
}

_build() (
  cmake -H$pkgbase-$pkgver -Bbuild-$1 \
    -DCMAKE_INSTALL_PREFIX=/usr/ \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_CXX_FLAGS="$CXXFLAGS -Wno-suggest-override" \
    -DHAVE_SSL=ON \
    "${@:2}" \
    -Wno-dev
  cmake --build build-$1
)

_install() {
  DESTDIR="${pkgdir}" cmake --build build-$1 --target install
}

build() {
  _build core \
    -DWANT_QTCLIENT=OFF \
    -DWANT_MONO=OFF \
    -DWITH_BUNDLED_ICONS=OFF \
    -DWITH_WEBKIT=OFF \
    -DWITH_WEBENGINE=OFF

  _build monolithic \
    -DWANT_CORE=OFF \
    -DWANT_QTCLIENT=OFF \
    -DWITH_WEBKIT=ON \
    -DWITH_WEBENGINE=OFF \
    -DWITH_KDE=ON

  _build client \
    -DWANT_CORE=OFF \
    -DWANT_MONO=OFF \
    -DWITH_WEBKIT=ON \
    -DWITH_WEBENGINE=OFF \
    -DWITH_KDE=ON

  _build client-small \
    -DWANT_CORE=OFF \
    -DWANT_MONO=OFF \
    -DWITH_WEBKIT=OFF \
    -DWITH_WEBENGINE=OFF \
    -DCMAKE_DISABLE_FIND_PACKAGE_dbusmenu-qt5=ON \
    -DCMAKE_DISABLE_FIND_PACKAGE_Qt5Multimedia=ON \
    -DCMAKE_DISABLE_FIND_PACKAGE_Phonon4Qt5=ON
}

package_quassel-core() {
pkgdesc="Next-generation distributed IRC client - core only"
depends=('icu' 'qca-qt5' 'qt5-script' 'libldap')
optdepends=('postgresql: PostgreSQL database support')
backup=(etc/conf.d/quassel)

  _install core

  # Remove unneeded pixmap icons
  rm -r "${pkgdir}"/usr/share

  install -Dm644 $pkgbase.sysusers \
    "${pkgdir}"/usr/lib/sysusers.d/$pkgbase.conf
  install -Dm644 $pkgbase.tmpfiles \
    "${pkgdir}"/usr/lib/tmpfiles.d/$pkgbase.conf
  install -Dm644 $pkgbase.service \
    "${pkgdir}"/usr/lib/systemd/system/$pkgbase.service
  install -Dm644 $pkgbase.conf \
    "${pkgdir}"/etc/conf.d/$pkgbase
}

package_quassel-client() {
pkgdesc="Next-generation distributed IRC client - client only"
pkgdesc+=" (with webkit HTML rendering)"
depends=('qt5-base' 'qt5-webengine' 'qt5-multimedia' 'knotifyconfig'
         'hicolor-icon-theme')
depends=(${depends[*]/qt5-webengine/qt5-webkit})
optdepends=('perl: for builtin /exec scripts')
conflicts=('quassel-monolithic' 'quassel-client-small')

  _install client
  install -Dm644 $pkgbase-$pkgver/data/quasselclient.appdata.xml "$pkgdir/usr/share/metainfo/quasselclient.appdata.xml"
}

package_quassel-client-small() {
pkgdesc="Next-generation distributed IRC client - client only, reduced deps"
depends=('qt5-base' 'qt5-svg' 'sonnet' 'hicolor-icon-theme')
optdepends=('perl: for builtin /exec scripts')
conflicts=('quassel-monolithic' 'quassel-client')
replaces=('quassel-remote')

  _install client-small

  # Ignore package by AppStream to avoid duplicated IDs
  echo 'X-AppStream-Ignore=true' >> "$pkgdir/usr/share/applications/quasselclient.desktop"
}

package_quassel-monolithic() {
pkgdesc="Next-generation distributed IRC client - monolithic"
pkgdesc+=" (with webkit HTML rendering)"
depends=('qt5-base' 'qt5-webengine' 'qt5-multimedia' 'qt5-script' 'qca-qt5'
         'knotifyconfig' 'libldap' 'hicolor-icon-theme')
depends=(${depends[*]/qt5-webengine/qt5-webkit})
optdepends=('perl: for builtin /exec scripts'
            'postgresql: PostgreSQL database support')
conflicts=('quassel-client' 'quassel-client-small')

  _install monolithic
  install -Dm644 $pkgbase-$pkgver/data/quassel.appdata.xml "$pkgdir/usr/share/metainfo/quassel.appdata.xml"
}