abslibre/nonprism/evolution-data-server/PKGBUILD

# Maintainer (arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Freemor <freemor@freemor.ca>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
#  - removed libgweather support
#  - removed libgdata support
#  - removed google support
#  - pinned to 'icu' sodep
#  - build from versioned source-ball, not VCS


pkgname=evolution-data-server
pkgver=3.44.4
[[ "${CARCH}" == i686 ]] && pkgver=3.40.4
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="Centralized access to appointments and contacts"
pkgdesc+=", without google, libgweather, and libgdata support"
url="https://wiki.gnome.org/Apps/Evolution"
arch=(x86_64)
arch+=(armv7h i686)
depends=(gnome-online-accounts nss krb5 libgweather-4 libical db libgdata libphonenumber
         libcanberra)
depends=(${depends[*]/libgweather-4/})
depends=(${depends[*]/libgdata/})
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
makedepends=( ${makedepends[*]/git/} )
[[ "${CARCH}" == i686 ]] && depends+=( glib2=2.74.0 ) # Package dependency requirement 'glib-2.0 >= 2.74.0' could not be satisfied. If you want to disable GObject introspection, please use -DENABLE_INTROSPECTION=OFF
provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
          libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
          libedataserverui-1.2.so)
license=(GPL)
options=(debug)
source=(https://gitlab.gnome.org/GNOME/${pkgname}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha256sums=('9ee2f008c713102730d49ff8f56c1873ac9fa9c0210856cab094cfce5f4cfb33')
[[ "${CARCH}" == i686 ]] && sha256sums=('3adaba3e7b0f72d8f65b955995cb30373bbcfe71ab3f81f6260c2c8b80bd18cb')


prepare() {
  cd ${pkgname}-${pkgver}
}

build() {
  local privacy_options=( -DENABLE_UOA=OFF         \
                          -DENABLE_GOOGLE=OFF      \
                          -DHAVE_LIBGDATA=OFF      \
                          -DENABLE_GOOGLE_AUTH=OFF \
                          -DENABLE_WEATHER=OFF     \
                          -DWITH_GWEATHER4=OFF     )
  [[ "${CARCH}" == i686 ]] && privacy_options+=( -DWITH_PHONENUMBER=OFF ) # libphonenumber cannot be used.  Use -DWITH_PHONENUMBER=PATH to specify the library prefix, or -DWITH_PHONENUMBER=OFF to disable it.

  cmake -S ${pkgname}-${pkgver} -B build -G Ninja \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIBEXEC_INSTALL_DIR=/usr/lib \
    -DSYSCONF_INSTALL_DIR=/etc \
    -DENABLE_INTROSPECTION=ON \
    -DENABLE_VALA_BINDINGS=ON \
    -DENABLE_GTK_DOC=ON \
    -DWITH_PHONENUMBER=ON \
    ${privacy_options[*]}
  cmake --build build
}

check() {
  # with networking disabled:
  # |  The following tests FAILED:
  # |       56 - test-cal-component (Subprocess aborted)
  # with networking enabled:
  # |  The following tests FAILED:
  # |       34 - test-book-client-suppress-notifications (SIGTRAP)
  return 0

  cd build
  ctest --output-on-failure --stop-on-failure
}

package() {
  depends+=(libicui18n.so libicuuc.so)

  DESTDIR="$pkgdir" cmake --install build
}