abslibre/libre/cdrkit/PKGBUILD

# Ma# $Id: PKGBUILD 186761 2013-05-31 04:50:41Z allan $
# Maintainer (arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>

pkgname=cdrkit
_pkgname=$pkgname-libre
pkgver=1.1.11
pkgrel=3.parabola2
pkgdesc="Suite of programs for CD/DVD recording, ISO image creation, and audio CD extraction, without nonfree apple_driver utility"
arch=('i686' 'x86_64' 'armv7h')
url="http://$pkgname.org/"
license=('GPL2')
provides=('cdrtools')
conflicts=("$_pkgname" 'cdrtools')
replaces=("$_pkgname" 'cdrtools')
depends=('file' 'bzip2')
optdepends=('perl: for dirsplit')
makedepends=('cmake')
mksource=(http://$pkgname.org/releases/$pkgname-$pkgver.tar.gz)
source=(https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver.tar.gz)
mkmd5sums=('efe08e2f3ca478486037b053acd512e9')
md5sums=('SKIP')

mksource() {
  cd "$srcdir/$pkgname-$pkgver"

  # Remove nonfree apple_driver utility
  rm -rvf {doc/genisoimage/README.hfs_boot,genisoimage/apple_driver.{8,c}}
}

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  sed -i "s#sbin#bin#" netscsid/CMakeLists.txt
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make PREFIX="$pkgdir/usr" install

  # Make symlinks for cdrtools compatibility
  cd "$pkgdir/usr/bin"
  ln -s wodim cdrecord
  ln -s readom readcd
  ln -s genisoimage mkisofs
  ln -s genisoimage mkhybrid
  ln -s icedax cdda2wav

  cd "$pkgdir/usr/share/man/man1"
  ln -s wodim.1 cdrecord.1
  ln -s readom.1 readcd.1
  ln -s genisoimage.1 mkisofs.1
  ln -s genisoimage.1 mkhybrid.1
  ln -s icedax.1 cdda2wav.1
}