abslibre/libre/kile/PKGBUILD

# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Ronald van Haren <ronald.archlinux.org>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Damir Perisa <damir.perisa@bluewin.ch>

pkgname=kile
pkgver=2.9.94
pkgrel=1
pkgdesc='A user friendly TeX/LaTeX frontend for KDE'
pkgdesc+=', without nonfree Adobe Reader recommendation'
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL-2.0-or-later)
url='https://apps.kde.org/kile/'
depends=(gcc-libs
         glibc
         kcodecs
         kcolorscheme
         kcompletion
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         kdbusaddons
         kguiaddons
         ki18n
         kiconthemes
         kio
         kparts
         kservice
         ktexteditor
         ktextwidgets
         kwidgetsaddons
         kwindowsystem
         kxmlgui
         okular
         perl
         poppler-qt6
         qt6-5compat
         qt6-base
         qt6-declarative
         texlive-basic)
makedepends=(extra-cmake-modules
             kdoctools)
optdepends=('imagemagick: for some file type conversions'
            'konsole: embedded terminal')
source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.bz2)
source+=(libre.patch)
sha256sums=('53c6742bd83fb095cbdc898b03fdf8e15ab680a81693ccaf9c5076b93ad1a3ca'
            '254eb9ef48c53d67eac107c6b99f7a10c69d88327f860543d35c4240cec9a2ed')

prepare() {
  # Remove nonfree Adobe Reader recommendation
  patch -d $pkgname-$pkgver -p1 < libre.patch
}

build() {
  cmake -B build -S $pkgname-$pkgver
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}