abslibre/libre/pacman/PKGBUILD

# Maintainer (arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer (arch): Morten Linderud <foxboron@archlinux.org>
# Maintainer (archarm): Kevin Mihelich <kevin@archlinuxarm.org>

# Maintainer: Luke T. Shumaker <lukeshu@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Nicolás Reynolds <fauno@kiwwwi.com.ar>
# Contributor: Daniel Milewski <niitotantei@riseup.net>
# Contributor: bill-auger <bill-auger@programmer.net>


# ALARM: Kevin Mihelich <kevin@archlinuxarm.org>
#  - arch/host/flags for armv7h, and aarch64
#  - pacman.conf: architecture=armv7h/aarch64, added our aur and alarm repos
#  - makepkg.conf: adjusted C/CXX/LDFLAGS
#  - patch to sync filesystem after install/remove
#  - reverts to allow scriplet input on stdin
#  - patch to fix application/gzip change in file 5.37

# Parabola:
#  - pacman.conf, makepkg.conf: Provide the default files for all
#    architectures.
#  - makepkg: Allow "${X}.parabola${Y}" pkgrel values
#  - pacman-key: Always regenerate GPG trust DB per `pacman-key --updatedb`,
#    which can help to maintain sanity (new/expired keys, rapid churn, etc).


pkgname=pacman
pkgver=7.0.0.r3.g7736133
pkgrel=1
pkgrel+=.parabola1
# use annotated tag and patch level commit from release branch (can be empty for no patches)
_git_tag=7.0.0
_git_patch_level_commit=77361331ae3864c6ea880e715c5864d59336f275
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
arch+=('armv7h' 'i686')
url="https://www.archlinux.org/pacman/"
license=('GPL-2.0-or-later')
depends=(
  bash
  coreutils
  curl
  gawk
  gettext
  glibc
  gnupg
  gpgme
  grep
  libarchive
  pacman-mirrorlist
  systemd
)
makedepends=(
  asciidoc
  doxygen
  git
  meson
)
checkdepends=(
  fakechroot
  python
)
optdepends=(
  'base-devel: required to use makepkg'
  'perl-locale-gettext: translation support in makepkg-template'
)
provides=('libalpm.so')
backup=(etc/pacman.conf
        etc/makepkg.conf
        etc/makepkg.conf.d/rust.conf)
validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD'  # Allan McRae <allan@archlinux.org>
              'B8151B117037781095514CA7BBDFFC92306B1121') # Andrew Gregory (pacman) <andrew@archlinux.org>
source=("git+https://gitlab.archlinux.org/pacman/pacman.git#tag=v${_git_tag}?signed"
        revertme-makepkg-remove-libdepends-and-libprovides.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/354a300cd26bb1c7e6551473596be5ecced921de.patch
        pacman.conf
        makepkg.conf
        alpm.sysusers
        rust.conf)
source=(${source[@]/pacman.conf/"${arch[@]/#/pacman.conf.}"}) # Parabola: pacman.conf  -> pacman.conf.{armv7h,i686,x86_64}
source=("${source[@]/makepkg.conf/makepkg.conf.in}")          # Parabola: makepkg.conf -> makepkg.conf.in
source+=(9001-makepkg-Treat-pkgrel-more-similarly-to-pkgver.patch
         9002-pacman-key-updatedb.patch)
source_armv7h=(arm-0001-Sychronize-filesystem.patch
               arm-0002-Revert-close-stdin-before-running-install-scripts.patch
               arm-0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch)
sha256sums=('06d082c3ce6f0811ca728515aa82d69d372800bd3ada99f5c445ef9429b6e3a6'
            'b3bce9d662e189e8e49013b818f255d08494a57e13fc264625f852f087d3def2'
            '94ba39177f80b258696ce5a5a468f0bc3a538c961ae013b84f54b6cfad986624' # DIFF: should differ from arch (pacman.conf.x86_64)
            'e73fab040e3b5d5e849a1d3eb64421a17c96cbdbbc2c5d9a465ab129435107de' # DIFF: should differ from arch (pacman.conf.armv7h)
            'b6acea271bb38f25376eb28f08fc55cf18c1ec3c47c7a0c19ad1ed0ffe753eef' # DIFF: should differ from arch (pacman.conf.i686  )
            '72c606c676252b72fcaab5ac3aa057332d748e1930200c7fa95c73e09208d898' # DIFF: should differ from arch (makepkg.conf)
            '8c12bfb5af83a1a6ae48dabaa3a92fed0fc28ad46df1cd5cac848923586408a7' # DIFF: should differ from arch (naming confusion)
            '59a8bbdc32830c90dbce5ead9f90074a2bb31cd85ec92bc5f92251bb4bcf8a1d')
sha256sums+=('9ccc7ef5bd27a68d8788f10c6e5b36495c5d9038d4eb160f9ea4dc9901b622d8'
             '39e4db3eed5dc522baffb7f853a7dbb7b417cc7a718599d768297adfbe99e263')
sha256sums_armv7h=('8d70fb5094f58aad98b601bbc42be354c2014b9fe734a1ee0b1e14bb041cc9cc'
                   '0e771370da68c855bfb4eaad4c2ae137883a474886a049b934dac2e775574cb9'
                   '2f586f72c34150330389854575a21be1d3ef3637c4f94bec2e948c2717a5aecb')


pkgver() {
  cd "$pkgname"
  git describe --abbrev=7 --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$pkgname"

  # apply patch level commits on top of annotated tag
  if [[ -n ${_git_patch_level_commit} ]]; then
    if [[ v${_git_tag} != $(git describe --tags --abbrev=0 "${_git_patch_level_commit}") ]] then
      error "patch level commit ${_git_patch_level_commit} is not a descendant of v${_git_tag}"
      exit 1
    fi
    git rebase "${_git_patch_level_commit}"
  fi

  # handle patches
  local -a patches
  patches=($(printf '%s\n' "${source[@]}" | grep '.patch'))
  patches=("${patches[@]%%::*}")
  patches=("${patches[@]##*/}")

  if (( ${#patches[@]} != 0 )); then
    for patch in "${patches[@]}"; do
      if [[ $patch =~ revertme-* ]]; then
        msg2 "Reverting patch $patch..."
        patch -RNp1 < "../$patch"
      else
        msg2 "Applying patch $patch..."
        patch -Np1 < "../$patch"
      fi
    done
  fi

  ## Parabola changes ##

  # Generate a "makepkg.conf.${carch}" file for each "${arch[@]}".
  local carch chost cflags ldflags
  local cxxflags ltoflags rustflags dbgflags dbgrustflags options libdirs
  for carch in "${arch[@]}"; do

    # Base definitions.  Each architecture must still set `chost`,
    # `cflags`, and `ldflags`; and may modify these base definitions.
    cxxflags='$CFLAGS -Wp,-D_GLIBCXX_ASSERTIONS'
    ltoflags='-flto=auto'
    rustflags='-Cforce-frame-pointers=yes'
    dbgflags='-g'
    dbgrustflags='-C debuginfo=2'
    options=(strip docs !libtool !staticlibs emptydirs zipman purge debug lto)
    libdirs=('lib:usr/lib')
    zstdflags=(-T0 --ultra -20)

    case "$carch" in
      armv7h)
        chost='armv7l-unknown-linux-gnueabihf'

        # ALARM includes '-mno-omit-leaf-frame-pointer' in CFLAGS in
        # their pacman-6.1.0-3-armv7h.pkg.tar.xz, even though that
        # flag doesn't exist on armv7h (as of
        # gcc-14.1.1+r1+g43b730b9134-1-armv7h.pkg.tar.xz).  So I guess
        # ALARM is just shipping a broken makepkg.conf?
        cflags='-march=armv7-a -mfloat-abi=hard -mfpu=neon -O2 -pipe -fstack-protector-strong -fno-plt -fexceptions \
        -Wp,-D_FORTIFY_SOURCE=3 -Wformat -Werror=format-security \
        -fstack-clash-protection \
        -fno-omit-frame-pointer'

        # ALARM includes '-Wl,-z,pack-relative-relocs' in LDFLAGS in
        # their pacman-6.1.0-3-armv7h.pkg.tar.xz, even though that
        # flag is x86- (and ppc64-?) -only.  Depending on how the
        # compiler is called, that may result in a harmless warning on
        # stderr, or it may result in the compiler failing.
        ldflags='-Wl,-O1 -Wl,--sort-common -Wl,--as-needed -Wl,-z,relro -Wl,-z,now'

        # overrides
        ltoflags=""
        rustflags=""
        dbgrustflags=""
        options=("${options[@]/#lto/!lto}") # disable lto
        zstdflags=(--single-thread) # optimize for memory use
        ;;
      i686)
        chost='i686-pc-linux-gnu'

        cflags='-march=i686 -mtune=generic -O2 -pipe -fno-plt -fexceptions \
        -Wp,-D_FORTIFY_SOURCE=3 -Wformat -Werror=format-security \
        -fstack-clash-protection -fcf-protection \
        -fno-omit-frame-pointer -mno-omit-leaf-frame-pointer'

        ldflags='-Wl,-O1 -Wl,--sort-common -Wl,--as-needed -Wl,-z,relro -Wl,-z,now \
         -Wl,-z,pack-relative-relocs'
        ;;
      x86_64)
        chost='x86_64-pc-linux-gnu'

        cflags='-march=x86-64 -mtune=generic -O2 -pipe -fno-plt -fexceptions \
        -Wp,-D_FORTIFY_SOURCE=3 -Wformat -Werror=format-security \
        -fstack-clash-protection -fcf-protection \
        -fno-omit-frame-pointer -mno-omit-leaf-frame-pointer'

        ldflags='-Wl,-O1 -Wl,--sort-common -Wl,--as-needed -Wl,-z,relro -Wl,-z,now \
         -Wl,-z,pack-relative-relocs'

        # overrides
        libdirs+=('lib32:usr/lib32')
        ;;
      esac

      sed < "${srcdir}"/makepkg.conf.in > "${srcdir}/makepkg.conf.${carch}" \
          -e "s|@CARCH@|${carch}|g"                                         \
          -e "s|@CHOST@|${chost}|g"                                         \
          -e "s|@CFLAGS@|${cflags//'\'/'\\\'}|g"                            \
          -e "s|@CXXFLAGS@|${cxxflags//'\'/'\\\'}|g"                        \
          -e "s|@LDFLAGS@|${ldflags//'\'/'\\\'}|g"                          \
          -e "s|@LTOFLAGS@|${ltoflags//'\'/'\\\'}|g"                        \
          -e "s|@RUSTFLAGS@|${rustflags//'\'/'\\\'}|g"                      \
          -e "s|@DBGFLAGS@|${dbgflags//'\'/'\\\'}|g"                        \
          -e "s|@DBGRUSTFLAGS@|${dbgrustflags//'\'/'\\\'}|g"                \
          -e "s|@OPTIONS@|${options[*]}|g"                                  \
          -e "s|@LIBDIRS@|${libdirs[*]@Q}|g"                                \
          -e "s|@ZSTDFLAGS@|${zstdflags[*]}|g"
  done

  # Put the files for this arch at a neutral location.
  cp -T "${srcdir}/pacman.conf.${CARCH}"  "${srcdir}"/pacman.conf
  cp -T "${srcdir}/makepkg.conf.${CARCH}" "${srcdir}"/makepkg.conf
}

build() {
  cd "$pkgname"

  meson --prefix=/usr \
        --buildtype=plain \
        -Ddoc=enabled \
        -Ddoxygen=enabled \
        -Dscriptlet-shell=/usr/bin/bash \
        -Dldconfig=/usr/bin/ldconfig \
        build

  meson compile -C build
}

check() {
  cd "$pkgname"

  meson test -C build
}

package() {
  cd "$pkgname"

  DESTDIR="$pkgdir" meson install -C build

  # install Arch specific stuff
  install -dm755 "$pkgdir/etc"
  install -m644 "$srcdir/pacman.conf" "$pkgdir/etc"
  install -m644 "$srcdir/makepkg.conf" "$pkgdir/etc"
  install -D -m644 "$srcdir/alpm.sysusers" "${pkgdir}"/usr/lib/sysusers.d/alpm.conf
  install -m644 "$srcdir/rust.conf" "$pkgdir/etc/makepkg.conf.d"

  local wantsdir="$pkgdir/usr/lib/systemd/system/sockets.target.wants"
  install -dm755 "$wantsdir"

  local unit
  for unit in dirmngr gpg-agent gpg-agent-{browser,extra,ssh} keyboxd; do
    ln -s "../${unit}@.socket" "$wantsdir/${unit}@etc-pacman.d-gnupg.socket"
  done


  ## install Parabola specific stuff ##

  # per-arch pacman.conf(s) and makepkg.conf(s)
  local carch
  for carch in "${arch[@]}"; do
    install -D -m644 -t "$pkgdir/usr/share/pacman/defaults/" "$srcdir/pacman.conf.$carch"
    install -D -m644 -t "$pkgdir/usr/share/pacman/defaults/" "$srcdir/makepkg.conf.$carch"
  done
}