abslibre/libre/base/PKGBUILD

# Maintainer: Parabola GNU/Linux-libre Team
# Maintainer (Arch): Arch Linux Team
# Contributor (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Eli Schwartz <eschwartz@archlinux.org>

pkgname=base
pkgver=3
pkgrel=2
pkgdesc='Minimal package set to define a basic Arch Linux installation'
url='https://www.archlinux.org'
arch=('any')
license=('GPL')
depends=(
  # very very base
  'filesystem' 'gcc-libs' 'glibc' 'bash'

  # POSIX tools
  'coreutils' 'file' 'findutils' 'gawk' 'grep' 'procps-ng' 'sed' 'tar'

  # standard linux toolset
  'gettext' 'pciutils' 'psmisc' 'shadow' 'util-linux' 'bzip2' 'gzip' 'xz'

  # distro defined requirements
  'licenses' 'pacman' 'archlinux-keyring' 'systemd' 'systemd-sysvcompat'

  # networking, ping, etc
  'iputils' 'iproute2'
)
optdepends=(
  'linux: bare metal support'
)

# Basic Arch→Parabola changes:
pkgrel+=.parabola1
pkgdesc="${pkgdesc/Arch Linux/'Parabola GNU/Linux-libre'}"
url='https://www.parabola.nu'
depends=(
  "${depends[@]/archlinux/parabola}"
)
optdepends=(
  "${optdepends[@]/linux/linux-libre}"
  'your-freedom: Conflict with known non-free packages'
)

# Deal with the fact that Parabola imports binaries from Arch{,32,ARM}:
arch=('x86_64' 'i686' 'armv7h')
depends+=('archlinux-keyring') # XXX: Should this really be nescessary on non-x86_64 architectures?
depends_i686=('archlinux32-keyring')
depends_armv7h=('archlinuxarm-keyring')

# vim:set sw=2 sts=-1 et: