abslibre/nonsystemd/util-linux/PKGBUILD

# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Artix): Tom Gundersen <teg@jklm.no>
# Maintainer (Artix): Dave Reisner <dreisner@archlinux.org>
# Contributor (Artix): judd <jvinet@zeroflux.org>

pkgbase=util-linux
pkgname=(util-linux util-linux-libs)
_pkgmajor=2.37
_realver=${_pkgmajor}.2
pkgver=${_realver/-/}
pkgrel=5
pkgrel+=.nonsystemd1
pkgdesc='Miscellaneous system utilities for Linux'
url='https://github.com/karelzak/util-linux'
arch=('x86_64')
arch+=('i686' 'armv7h')
makedepends=('asciidoctor' 'libcap-ng' 'libxcrypt' 'python' 'udev')
license=('GPL2')
options=('strip')
validpgpkeys=('B0C64D14301CC6EFAEDF60E4E4B71D5EEC39C284')  # Karel Zak
source=("https://www.kernel.org/pub/linux/utils/util-linux/v${_pkgmajor}/${pkgbase}-${_realver}.tar."{xz,sign}
        '0001-agetty-resolve-tty-name-even-if-stdin-is-specified.patch'
        pam-{login,common,runuser,su}
        'util-linux.sysusers'
        '60-rfkill.rules')
sha256sums=('6a0764c1aae7fb607ef8a6dd2c0f6c47d5e5fd27aa08820abaad9ec14e28e9d9'
            'SKIP'
            '53395b7e434b32e6fee25f1b6fa59330ab72c1a2f99a17c3d3fd92473379fd9a'
            '99cd77f21ee44a0c5e57b0f3670f711a00496f198fc5704d7e44f5d817c81a0f'
            '57e057758944f4557762c6def939410c04ca5803cbdd2bfa2153ce47ffe7a4af'
            '48d6fba767631e3dd3620cf02a71a74c5d65a525d4c4ce4b5a0b7d9f41ebfea1'
            'b28f31fcafa401b0eb26bc0c710002acc4f7718f97af45b0d444e4af6dfb15a8'
            '10b0505351263a099163c0d928132706e501dd0a008dac2835b052167b14abe3'
            '7423aaaa09fee7f47baa83df9ea6fef525ff9aec395c8cbd9fe848ceb2643f37')

prepare() {
  cd "${pkgbase}-${_realver}"

  patch -Np1 < ../0001-agetty-resolve-tty-name-even-if-stdin-is-specified.patch
}

build() {
  cd "${pkgbase}-${_realver}"

  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib \
    --bindir=/usr/bin \
    --sbindir=/usr/bin \
    --localstatedir=/var \
    --enable-usrdir-path \
    --enable-fs-paths-default=/usr/bin:/usr/local/bin \
    --enable-raw \
    --enable-vipw \
    --enable-newgrp \
    --enable-chfn-chsh \
    --enable-write \
    --enable-mesg \
    --without-systemd \
    --with-python=3

  make
}

package_util-linux() {
  conflicts=('rfkill' 'hardlink')
  provides=('rfkill' 'hardlink')
  replaces=('rfkill' 'hardlink')
  depends=('pam' 'shadow' 'coreutils' 'libudev' 'libudev.so'
           'libcap-ng' 'libxcrypt' 'libcrypt.so' 'util-linux-libs'
           'libmagic.so' 'libncursesw.so' 'libreadline.so')
  optdepends=('python: python bindings to libmount'
              'words: default dictionary for look')
  backup=(etc/pam.d/chfn
          etc/pam.d/chsh
          etc/pam.d/login
          etc/pam.d/runuser
          etc/pam.d/runuser-l
          etc/pam.d/su
          etc/pam.d/su-l)

  cd "${pkgbase}-${_realver}"

  make DESTDIR="${pkgdir}" install

  # setuid chfn and chsh
  chmod 4755 "${pkgdir}"/usr/bin/{newgrp,ch{sh,fn}}

  # install PAM files for login-utils
  install -Dm0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chfn"
  install -m0644 "${srcdir}/pam-common" "${pkgdir}/etc/pam.d/chsh"
  install -m0644 "${srcdir}/pam-login" "${pkgdir}/etc/pam.d/login"
  install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser"
  install -m0644 "${srcdir}/pam-runuser" "${pkgdir}/etc/pam.d/runuser-l"
  install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su"
  install -m0644 "${srcdir}/pam-su" "${pkgdir}/etc/pam.d/su-l"

  # adjust for usrmove
  # TODO(dreisner): fix configure.ac upstream so that this isn't needed
  cd "${pkgdir}"
  mv usr/sbin/* usr/bin
  rmdir usr/sbin

  ### runtime libs are shipped as part of util-linux-libs
  rm "${pkgdir}"/usr/lib/lib*.{a,so}*

  ### install sysusers
  install -Dm0644 "${srcdir}/util-linux.sysusers" \
    "${pkgdir}/usr/lib/sysusers.d/util-linux.conf"

  install -Dm0644 "${srcdir}/60-rfkill.rules" \
    "${pkgdir}/usr/lib/udev/rules.d/60-rfkill.rules"
}

package_util-linux-libs() {
  pkgdesc="util-linux runtime libraries"
  provides=('libutil-linux' 'libblkid.so' 'libfdisk.so' 'libmount.so' 'libsmartcols.so' 'libuuid.so')
  conflicts=('libutil-linux')
  replaces=('libutil-linux')

  make -C "${pkgbase}-${_realver}" DESTDIR="${pkgdir}" install-usrlib_execLTLIBRARIES
}