abslibre/libre-multilib/lib32-libclc/PKGBUILD

# Maintainer: Márcio Silva <coadde@hyperbola.info>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgname=lib32-libclc
pkgver=0.2.0+334+520743b
pkgrel=1.1
pkgdesc="Library requirements of the OpenCL C programming language (32-bit)"
arch=('x86_64')
url="http://libclc.llvm.org/"
license=('MIT')
depends=('libclc')
makedepends=('lib32-clang' 'lib32-llvm' 'python2' 'git' 'gcc-multilib')
options=('staticlibs')
replaces=(lib32-libclc-svn)
provides=(lib32-libclc-svn)
conflicts=(lib32-libclc-svn)
source=('git+http://llvm.org/git/libclc#commit=520743b')
md5sums=(SKIP)

pkgver() {
  cd libclc

  echo 0.2.0+$(git rev-list --count HEAD)+$(git describe --always)
  #git describe --long | sed 's/-/+/g'
}

build() {
  cd libclc
  
  sed -i 's/"python < $in >/sys.executable + " < $in >/g' configure.py
  
  python2 ./configure.py --prefix=/usr \
   --libexecdir=/usr/lib32/clc \
   --pkgconfigdir=/usr/lib32/pkgconfig \
   --with-llvm-config=/usr/bin/llvm-config32 \
   --with-cxx-compiler="/usr/bin/g++ -m32"
  make
}

package() {
  cd libclc
  
  make install DESTDIR="$pkgdir"
  install -Dm644 LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  msg 'remove useless include dir'
  rm -vrf $pkgdir/usr/include
}