core/xfsprogs/PKGBUILD

# Maintainer (Arch):
# Maintainer: André Silva <emulatorman@hyperbola.info>
pkgname=xfsprogs
pkgver=5.6.0
pkgrel=1
pkgdesc="XFS filesystem utilities"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
url="https://xfs.org/index.php/Main_Page"
groups=('base')
depends=('sh' 'libutil-linux' 'readline' 'icu' 'device-mapper')
makedepends=('gettext-tiny')
options=('!makeflags')
source=("https://www.kernel.org/pub/linux/utils/fs/xfs/xfsprogs/xfsprogs-${pkgver}.tar."{xz,sign})
sha512sums=('a6bee55b0a23316c73f3921234d1dbaa4cbe91c12e79264e5f9bfe1356a24baa0ab25270405a46e4613a7e48443ef21997ff4f5962663777bed373f89ca29701'
            'SKIP')
validpgpkeys=('2B8185919E8D248981869DED20AE1692E13DDEE0') # Eric R. Sandeen

build() {
  cd ${pkgname}-${pkgver}
  make configure
  export OPTIMIZER="-march=${CARCH/_/-} -O1"
  export DEBUG=-DNDEBUG
  ./configure --prefix=/usr --enable-readline
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DIST_ROOT="${pkgdir}" install install-dev
  rm -rf ${pkgdir}/usr/lib
  install -Dm644 LICENSES/LGPL-2.1 "${pkgdir}/usr/share/licenses/${pkgname}/LGPL-2.1"
}