core/psmisc/PKGBUILD

# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Enmanuel E. Saravia <saravia@riseup.net>

pkgname=psmisc
pkgver=23.3
_debver=23.3
_debrel=1
pkgrel=1
pkgdesc="Miscellaneous procfs tools"
arch=('i686' 'x86_64')
url="http://psmisc.sourceforge.net/index.html"
license=('GPL-2')
groups=('base')
depends=('ncurses')
makedepends=('quilt')
source=(https://downloads.sourceforge.net/psmisc/${pkgname}-${pkgver}.tar.xz
        https://deb.debian.org/debian/pool/main/p/psmisc/psmisc_$_debver-$_debrel.debian.tar.xz)
sha512sums=('791ffef78d87b092d653da98710b338017466a9e1e1935968b9f0194ccef8da941317aa0c39d821d46b20d95d6539ccf78e5ebb71ad1032ae62337a397180d58'
            '454180ef80d1b3eec3c799d0ce779e54b8453691148e20cf244d457e68609ec7b1462d94b816a4dfa0e40efc7aa6c8724c07fc78202b74d919de1d9999ba9cc3')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -d -m755 ${pkgdir}/bin
  mv ${pkgdir}/usr/bin/fuser ${pkgdir}/bin
  install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}

# vim:set ts=2 sw=2 et: