core/net-tools/PKGBUILD

# Maintainer (Arch): Ronald van Haren <ronald.archlinux.org>
# Contributor (Arch): judd <jvinet@zeroflux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=net-tools
pkgver=1.60+git20181103.0eebece
_debver=1.60+git20181103.0eebece
_debrel=1
pkgrel=1
pkgdesc="Configuration tools for GNU/Linux networking"
arch=('i686' 'x86_64')
license=('GPL-2')
url="https://sourceforge.net/projects/net-tools/"
depends=('glibc')
makedepends=('quilt')
replaces=('inetutils')
conflicts=('inetutils')
provides=('inetutils')
source=("https://deb.debian.org/debian/pool/main/n/net-tools/net-tools_$pkgver.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/n/net-tools/net-tools_$_debver-$_debrel.debian.tar.xz"
        'make-net-tools-fhs-compliant.patch')
options=(!makeflags)
sha512sums=('2ae46a478eecbdc42b5233505329fd296137e1f7d603304f55afcc8ed1f0c89877305f2f47ff0794126e5dab063a380992fb4a57ee12f4803f26ef30ae164345'
            'dbec7e5a3220c7c9656c03815ef0f772d082e358d8330644c70b9a50ba4634b77c76f9533e171af1d7a21643166e83c97b9762056cead839a8edd215c2c42c1c'
            '9ce8aeda32a8c7be60d96ce32e989f863dfb984aaee2327cde0bbe514e2cd0f2271b459923b5d1baac92d805637b6516776a02a5f035326ea76a0d0e21fe8a07')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # make net-tools FHS compliant
  patch -p1 -i ../make-net-tools-fhs-compliant.patch

  if [[ ${pkgver%.*} = ${_debver%.*.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${srcdir}/${pkgname}-${pkgver}
  yes "" | make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} update

  # the following is provided by yp-tools
  rm "${pkgdir}"/bin/{nis,yp}domainname
  rm "${pkgdir}"/usr/share/man/man1/{nis,yp}domainname.1

  # install license
  install -Dm644 COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/COPYING
}