core/iputils/PKGBUILD

# Maintainer (Arch): Stéphane Gaudreault <stephane@archlinux.org>
# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor (Arch): Aaron Griffin <aaron@archlinux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=iputils
pkgver=20200821
pkgrel=2
pkgdesc="Network monitoring tools, including ping"
arch=('i686' 'x86_64')
license=('Modified-BSD' 'GPL-2' 'custom:Rdisc')
url="http://www.skbuff.net/iputils/"
groups=('base')
depends=('libressl' 'libcap' 'libidn2')
makedepends=('perl-sgmls' 'docbook-xsl' 'meson')
conflicts=('netkit-base' 'arping' 'netkit-tftpd')
replaces=('netkit-base')
install=${pkgname}.install
source=(https://github.com/iputils/iputils/archive/s${pkgver}.tar.gz
        copyright)
sha512sums=('4a57c3637cdd9aab2600682774e27370716cbdf1c7ac8ae61bf86c21c08701a5b697792df4aa95309b196eaa74f3cb6b2836a40f04da0e602156e982ac99d8c9'
            '7807777f7c5a5f0d6b0dda43169c0de5436360f26eeb64002f1400791fcfaf1c08c9c1e3c25af84e494b024d194f30ea804cc70c299ee152e5103cf8b47055eb')

build() {
  mkdir -p build
  cd build

  hyperbola-meson ../$pkgname-s$pkgver -DBUILD_RARPD=true
  ninja
}

package() {
  cd build

  DESTDIR="$pkgdir" ninja install

  # make iputils FHS compliant
  install -dm755 "${pkgdir}"/bin
  mv "${pkgdir}"/{usr/,}bin/ping
  mv "${pkgdir}"/{usr/s,}bin/rdisc

  install -Dm644 "${srcdir}"/copyright "${pkgdir}"/usr/share/licenses/${pkgname}/copyright
}