core/gdbm/PKGBUILD

# Maintainer (Arch):  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch): Stéphane Gaudreault <stephane@archlinux.org>
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): judd <jvinet@zeroflux.org>
# Maintainer: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=gdbm
pkgver=1.18.1
_debver=1.18.1
_debrel=5.1
pkgrel=3
pkgdesc='GNU database library'
url='https://www.gnu.org/software/gdbm/gdbm.html'
license=(GPL-3)
arch=(i686 x86_64)
depends=(sh)
makedepends=(quilt)
options=(!makeflags)
source=(https://ftp.gnu.org/gnu/gdbm/${pkgname}-${pkgver}.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/g/gdbm/gdbm_$_debver-$_debrel.debian.tar.xz)
validpgpkeys=('325F650C4C2B6AD58807327A3602B07F55D0C732')
sha512sums=('adf9d6c5bc843ff0d7f88c2a1667d509973b2d63378d0001d7e74cc10aee6ea498a4513cc88ddf78c32ba4db5cb040b2794f4f1b3338c65d9894058850e2f5ef'
            'SKIP'
            'a8e5e70b5962ae6b662d868d8ab2d489a8a187a1f0ab2f46947bc38c2b5cfc1152449359666871ec19bd07a46536a4f49197396a553662de22aa049f4e71d293')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --enable-libgdbm-compat
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # create symlinks for compatibility
  install -dm755 "$pkgdir"/usr/include/gdbm
  ln -sf ../gdbm.h "$pkgdir"/usr/include/gdbm/gdbm.h
  ln -sf ../ndbm.h "$pkgdir"/usr/include/gdbm/ndbm.h
  ln -sf ../dbm.h  "$pkgdir"/usr/include/gdbm/dbm.h

  # install license
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}