# Copyright (c) 2010 Nokia Corporation.

QT       += core gui
QT       += declarative

TARGET = qtquickplayground
TEMPLATE = app

VERSION = 1.2.0

SOURCES += main.cpp\
           qmlcodeprovider.cpp \
           taskswitcher.cpp

HEADERS  += qmlcodeprovider.h \
            taskswitcher.h

OTHER_FILES += demochooser.qml \
               content/button.qml \
               content/demoitem.qml \
               content/sidepanel.qml \
               content/texteditor.qml \
               content/demoitemcore.js \
               content/codebutton.qml \
               content/fancypicker/fancypicker.qml \
               content/fancypicker/slider.qml \
               content/helloworld/hello.qml \
               content/memorygame/memorygame.js \
               content/memorygame/memorygame.qml \
               content/samegame/samegame.qml \
               content/samegame/SameGameCore/boomblock.qml \
               content/samegame/SameGameCore/button.qml \
               content/samegame/SameGameCore/dialog.qml \
               content/samegame/SameGameCore/samegame.js \
               content/slideshow/slideshow.qml \
               content/webcontent/webcontent.qml \
               content/memorygame/card.qml \
               content/errordialog.qml 

RESOURCES =    resources.qrc


win32: !simulator {
    QT += opengl
    RC_FILE = qtquickplayground.rc
}


maemo5 {
    QT += opengl

    isEmpty(PREFIX):PREFIX = /usr
    BINDIR = $$PREFIX/bin
    DATADIR =$$PREFIX/share
    DEFINES += DATADIR=\\\"$$DATADIR\\\" \
        PKGDATADIR=\\\"$$PKGDATADIR\\\"
    INSTALLS += target \
        desktop \
        iconxpm \
        icon26 \
        icon40 \
        icon64

    target.path = $$BINDIR
    desktop.path = $$DATADIR/applications/hildon
    desktop.files += $${TARGET}.desktop

    iconxpm.path = $$DATADIR/pixmap
    iconxpm.files += icons/xpm/qtquickplayground.xpm

    icon26.path = $$DATADIR/icons/hicolor/26x26/apps
    icon26.files += icons/26x26/qtquickplayground.png

    icon40.path = $$DATADIR/icons/hicolor/40x40/apps
    icon40.files += icons/40x40/qtquickplayground.png

    icon64.path = $$DATADIR/icons/hicolor/64x64/apps
    icon64.files += icons/64x64/qtquickplayrground.png
}

symbian {
    ICON = icons/qtqpg.svg

    # To lock the application to landscape orientation
    LIBS += -lcone -leikcore -lavkon

    # WebView demo requires access to network
    TARGET.CAPABILITY = NetworkServices

    # Increase heap and stack size, FancyPicker consumes lots of memory
    # when viewing images
    TARGET.EPOCHEAPSIZE = 0x100000 0x2000000
    TARGET.EPOCSTACKSIZE = 0x14000
}
