QT += multimedia

# Add more folders to ship with the application, here
folder_01.source = qml/mototrialracer
folder_01.target = qml
DEPLOYMENTFOLDERS = folder_01

# Additional import path used to resolve QML modules in Creator's code model
QML_IMPORT_PATH =

INCLUDEPATH += ./box2dqmlplugin

VERSION = 1.2.2

SOURCES += \
    box2dqmlplugin/box2dworld.cpp \
    box2dqmlplugin/box2dweldjoint.cpp \
    box2dqmlplugin/box2drevolutejoint.cpp \
    box2dqmlplugin/box2dprismaticjoint.cpp \
    box2dqmlplugin/box2dplugin.cpp \
    box2dqmlplugin/box2djoint.cpp \
    box2dqmlplugin/box2dfixture.cpp \
    box2dqmlplugin/box2ddistancejoint.cpp \
    box2dqmlplugin/box2ddebugdraw.cpp \
    box2dqmlplugin/box2dbody.cpp \
    GEAudio/GEInterfaces.cpp \
    GEAudio/GEAudioOut.cpp \
    GEAudio/GEAudioMixer.cpp \
    GEAudio/GEAudioBufferPlayInstance.cpp \
    GEAudio/GEAudioBuffer.cpp \
    src/audioplayer.cpp \
    src/main.cpp \
    src/myqmlapplicationviewer.cpp \
    src/screensizeprovider.cpp 

# Please do not modify the following two lines. Required for deployment.
include(qmlapplicationviewer/qmlapplicationviewer.pri)
qtcAddDeployment()

include(Box2D/box2d.pri)

HEADERS += \
    box2dqmlplugin/box2dworld.h \
    box2dqmlplugin/box2dweldjoint.h \
    box2dqmlplugin/box2drevolutejoint.h \
    box2dqmlplugin/box2dprismaticjoint.h \
    box2dqmlplugin/box2dplugin.h \
    box2dqmlplugin/box2djoint.h \
    box2dqmlplugin/box2dfixture.h \
    box2dqmlplugin/box2ddistancejoint.h \
    box2dqmlplugin/box2ddebugdraw.h \
    box2dqmlplugin/box2dbody.h \
    GEAudio/GEInterfaces.h \
    GEAudio/GEAudioOut.h \
    GEAudio/GEAudioMixer.h \
    GEAudio/GEAudioBufferPlayInstance.h \
    GEAudio/GEAudioBuffer.h \
    GEAudio/trace.h \
    src/audioplayer.h \
    src/myqmlapplicationviewer.h \
    src/screensizeprovider.h \
    src/in_application_billing/catalog_constants.h

RESOURCES += \
    sounds.qrc

symbian {
    TARGET = MotoTrialRacer
    TARGET.UID3 = 0xE1145BC9

    # In-application Purchase API
    # For more details please check the project wiki
    # http://projects.developer.nokia.com/mototrialracer/wiki/IapIntegration
    DEFINES += INAPP_BILLING
    contains(DEFINES, INAPP_BILLING){
        message(In-App Purchase API enabled)
        include(src/in_application_billing/in_application_billing.pri)
    }

    # For enabling split screen virtual keyboard
    LIBS += -lcone -lws32 -lavkon -leikctl -leikcoctl -luiklaf -lform -lfepbase

    CONFIG += mobility
    MOBILITY += sensors systeminfo

    HEADERS += \
        src/rotationdata.h
    SOURCES += \
        src/rotationdata.cpp

    TARGET.EPOCHEAPSIZE = 0x100000 0x2000000
    TARGET.EPOCSTACKSIZE = 0x14000

    # For enabling hardware floats
    MMP_RULES += "OPTION gcce -march=armv6"
    MMP_RULES += "OPTION gcce -mfpu=vfp"
    MMP_RULES += "OPTION gcce -mfloat-abi=softfp"
    MMP_RULES += "OPTION gcce -marm"
}

# Harmattan
unix:!symbian:!maemo5 {
    message(Harmattan build)

    TARGET = mototrialracer
    DEFINES += Q_WS_MAEMO_6

    QT -= multimedia
    CONFIG += mobility
    MOBILITY += sensors systeminfo multimedia

    HEADERS += \
        src/rotationdata.h
    SOURCES += \
        src/rotationdata.cpp

    desktopfile.files = qtc_packaging/debian_harmattan/$${TARGET}.desktop
    desktopfile.path = /usr/share/applications
    icon.files = mototrialracer.png
    icon.path = /usr/share/icons/hicolor/64x64/apps

    # Classify the application as a game to support volume keys on Harmattan.
    gameclassify.files += qtc_packaging/debian_harmattan/mototrialracer.conf
    gameclassify.path = /usr/share/policy/etc/syspart.conf.d

    INSTALLS += \
        target \
        desktopfile \
        icon \
        gameclassify
}

OTHER_FILES += \
    box2dqmlplugin/box2d-static.pri \
    gfx/wheel.png \
    gfx/susp_upper.png \
    gfx/susp_lower_long.png \
    gfx/susp_lower.png \
    gfx/splash.png \
    gfx/sky.png \
    gfx/resume_select.png \
    gfx/resume.png \
    gfx/rearWheel.png \
    gfx/rearFork.png \
    gfx/options_select.png \
    gfx/options.png \
    gfx/ok_select.png \
    gfx/ok.png \
    gfx/newGame_select.png \
    gfx/newGame.png \
    gfx/nail.png \
    gfx/MotoTrial.png \
    gfx/jump.png \
    gfx/info_select.png \
    gfx/info.png \
    gfx/human.png \
    gfx/highScores_select.png \
    gfx/highScores.png \
    gfx/head.png \
    gfx/hand.png \
    gfx/grass.png \
    gfx/finish.png \
    gfx/exit_select.png \
    gfx/exit.png \
    gfx/bikeBody.png \
    gfx/arm.png

