configure.ac 1.5 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950
  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ([2.69])
  4. AC_INIT([Guile-zstd], [0.1.0], [guile-user@gnu.org], [guile-zstd],
  5. [https://notabug.org/guile-zstd/guile-zstd])
  6. AC_CONFIG_SRCDIR([zstd.scm])
  7. AC_CONFIG_AUX_DIR([build-aux])
  8. AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects color-tests parallel-tests -Wno-portability])
  9. AM_SILENT_RULES([yes])
  10. AC_CONFIG_FILES([Makefile])
  11. AC_CONFIG_FILES([zstd/config.scm])
  12. AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
  13. dnl Search for 'guile' and 'guild'. This macro defines
  14. dnl 'GUILE_EFFECTIVE_VERSION'.
  15. GUILE_PKG([3.0 2.2 2.0])
  16. GUILE_PROGS
  17. if test "x$GUILD" = "x"; then
  18. AC_MSG_ERROR(['guild' binary not found; please check your GNU Guile installation.])
  19. fi
  20. if test "$cross_compiling" != no; then
  21. GUILE_TARGET="--target=$host_alias"
  22. AC_SUBST([GUILE_TARGET])
  23. fi
  24. PKG_CHECK_MODULES([ZSTD], [libzstd], [:],
  25. [AC_MSG_ERROR([Libzstd not found; please install it first.])])
  26. AC_MSG_CHECKING([zstd library directory])
  27. PKG_CHECK_VAR([ZSTD_LIBDIR], [libzstd], [libdir])
  28. AC_MSG_RESULT([$ZSTD_LIBDIR])
  29. AS_IF([test "x$ZSTD_LIBDIR" = "x"], [
  30. AC_MSG_ERROR([unable to identify zstd library directory])
  31. ])
  32. AC_SUBST([ZSTD_LIBDIR])
  33. dnl Installation directories for .scm and .go files.
  34. guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  35. guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  36. AC_SUBST([guilemoduledir])
  37. AC_SUBST([guileobjectdir])
  38. AC_OUTPUT