# Maintainer: bzt <https://gitlab.com/bztsrc/easyboot/issues>
# Contributor: Ramadan Ali (alicavus) <rot13: ezqa@ezqa.ny>
pkgname=easyboot
pkgver=1.0.0
pkgrel=1
pkgdesc="Dependency-free, all-in-one boot manager and bootable disk image creator."
arch=("x86_64" "aarch64")
url="https://gitlab.com/bztsrc/easyboot"
license=("GPL-3.0-or-later")
makedepends=("clang")
source=("${url}/-/archive/main/${pkgname}-main.tar.gz")
b2sums=("SKIP")

pkgver() {
	cd "${pkgname}-main/src"
	printf "%s" `grep -m 1 ebver easyboot.c | cut -d '"' -f 2`
}

build() {
	cd "${pkgname}-main/src"
	make clean all
}

package() {
	cd "${pkgname}-main/src"
	DESTDIR=$pkgdir/ make install
}
