actor IceLich : Iceguy 16248
{
	//$Category Monsters
	//$Title Ice Lich
	Health 700
	Radius 40
	Height 72
	Mass 500
	Speed 7
	PainChance 16
	DamageFactor "Poison", 0
	DamageFactor "Ice", 0
	Species "IronLich"
	Monster
	+NOGRAVITY
	+NOBLOOD
	+FLOAT
	+NOTARGETSWITCH
	+DONTHARMSPECIES
	+MISSILEMORE
	+DONTBLAST
	+DONTMORPH
	+DONTSQUASH
	+NOICEDEATH
	+DONTSPLASH
	SeeSound "ironlich/sight"
	PainSound "ironlich/pain"
	DeathSound "freeze/shatter"
	ActiveSound "ironlich/active"
	AttackSound ""
	Obituary "$OB_ICELICH"
	Tag "$FN_ICELICH"
	DropItem "BlasterAmmo", 48, 16
	States
	{
	Spawn:
		ILCH A 10 A_Look
		loop
	See:
		ILCH AAAA 2 A_Chase
		ILCH A 0 A_SpawnItemEx("IceGuyWisp1", random(-20,20), random(-20,20), random(50,70), 0, 0, 0, 32, 128)
		ILCH AAAA 2 A_Chase
		ILCH A 0 A_SpawnItemEx("IceGuyWisp2", random(-20,20), random(-20,20), random(50,70), 0, 0, 0, 32, 128)
		Loop
	Missile:
		ILCH B 0 bright A_JumpIfCloser(300, "Breath")
		ILCH B 0 bright A_FaceTarget
		ILCH B 0 bright A_PlaySoundEx("misc/icefire", auto) 
		ILCH B 0 bright A_CustomMissile("IceGuyFX", 44, 10, 0, 1)
		ILCH B 3 bright A_CustomMissile("IceGuyFX", 44, -10, 0, 1)
		Goto See
	Breath:
		ILCH B 0 bright A_PlaySoundEx("ironlich/attack3", auto)
		ILCH B 0 bright A_FaceTarget
		ILCH BBB 2 bright A_CustomMissile("IceBreath", 20, 0, random(-10,10), CMF_CHECKTARGETDEAD)
		ILCH B 0 bright A_PlaySoundEx("ironlich/attack3", auto)
		ILCH B 0 bright A_FaceTarget
		ILCH BBB 2 bright A_CustomMissile("IceBreath", 20, 0, random(-10,10), CMF_CHECKTARGETDEAD)
		ILCH B 0 bright A_PlaySoundEx("ironlich/attack3", auto)
		ILCH B 0 bright A_FaceTarget
		ILCH BBB 2 bright A_CustomMissile("IceBreath", 20, 0, random(-10,10), CMF_CHECKTARGETDEAD)
		ILCH B 0 bright A_PlaySoundEx("ironlich/attack3", auto)
		ILCH B 0 bright A_FaceTarget
		ILCH BBB 2 bright A_CustomMissile("IceBreath", 20, 0, random(-10,10), CMF_CHECKTARGETDEAD)
		ILCH B 0 bright A_PlaySoundEx("ironlich/attack3", auto)
		ILCH B 0 bright A_FaceTarget
		ILCH BBB 2 bright A_CustomMissile("IceBreath", 20, 0, random(-10,10), CMF_CHECKTARGETDEAD)
		Goto See
	Pain:
		ILCH A 2 A_Pain
		Goto See
	Death:
		ILCH A 0 A_GenericFreezeDeath
		ILCH A 3 A_Scream
		ILCH A 1 A_IceGuyDie
		Stop
	}
}

actor IceBreath
{
	Radius 12
	Height 8
	Speed 8
	Damage 1
	RenderStyle Translucent
	Alpha 0.2
	Projectile
	-NOBLOCKMAP
	-ACTIVATEIMPACT
	-ACTIVATEPCROSS
	+WINDTHRUST
	+SPAWNSOUNDSOURCE
	+BLOODLESSIMPACT
	+ICEDAMAGE
	states
	{
	Spawn:
		IBRT ABABABABABABABABABAB 2 Bright
	Death:
		IBRT AB 2 Bright
		Stop
	}
}
