
//Sprite edit by Blue Shadow, edited from some Hexen elements
//Translation by Gez, decorate by Ghastly

Actor Champion : HPKnight 16512
{
  //$Category Monsters
  //$Title Undead Champion
  Health 260
  PainChance 50
  +MissileMore
  +DontHurtSpecies
  Translation "145:160=225:240", "209:224=145:160", "98:110=96:108"
  Obituary "$OB_CHAMPION"
  HitObituary "$OB_CHAMPIONH"
  Tag "$FN_CHAMPION"
  SeeSound "champion/sight"
  PainSound "champion/pain"
  DeathSound "champion/death"
  ActiveSound "champion/active"
  Speed 10
  States
  {
  Spawn:
    UDCH AB 10 A_Look
    Loop
  See:
    UDCH AABBCCDD 2 A_Chase
    Loop
  Melee:
  Missile:
    UDCH E 0 A_Jump(128, "Missile2")
  Missile1:
    UDCH E 8 A_FaceTarget
    UDCH F 6 A_FaceTarget
    UDCH G 6 A_CustomComboAttack("BloodyAxe", 32, 3, "HKnight/Melee") //A_KnightAttack
    UDCH G 0 A_Jump(128, "Missile2")
    Goto See
  Missile2:
    UDCH H 8 A_FaceTarget
    UDCH I 6 A_FaceTarget
    UDCH J 6 A_CustomComboAttack("BloodyAxe", 32, 3, "HKnight/Melee") //A_KnightAttack
    UDCH J 0 A_Jump(128, "Missile1")
    Goto See
  Pain:
    UDCH K 3
    UDCH K 3 A_Pain
    Goto See
  Death:
    UDCH L 6
    UDCH M 6 A_Scream
    UDCH N 6
    UDCH O 6 A_NoBlocking
    UDCH PQ 6
    UDCH R -1
    Stop
  Raise:
    UDCH RQPOMNL 6
    Goto Spawn
  }
}

Actor BloodyAxe : RedAxe replaces RedAxe
{
  Decal BloodSmear
  States
  {
  Spawn:
    RAXE A 0 A_PlaySound("hknight/axewhoosh")
    RAXE A 3 Bright A_DripBlood
    RAXE B 3 Bright
    RAXE C 3 Bright A_DripBlood
    Loop
  Death:
    RAXE DEF 6 Bright
    Stop
  }
}