abslibre/pcr-testing/gsequencer/PKGBUILD

# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (aur): JoëlKrähemann <jkraehemann@gmail.com>


pkgname=gsequencer
pkgver=1.4.31
pkgrel=1
pkgdesc="Advanced Gtk+ Sequencer"
arch=('i686' 'x86_64')
license=('GPL')
url=http://www.nongnu.org/gsequencer/

makedepends=('cairo' 'fontconfig' 'gtk2' 'gdk-pixbuf2' 'libinstpatch' 'libpulse' 'libx11' 'libxml2')
depends=('dssi' 'ladspa' 'lv2')
provides=('gsequencer' 'midi2xml')

_release=${pkgname}-${pkgver}
_build_dir=${_release}
source=(https://download.savannah.gnu.org/releases/${pkgname}/${pkgver%.*}.x/${_release}.tar.gz
        alsa-replace-pulse.patch)
sha256sums=('e293937f90415e7916114dc8223882c21dc1e8b9136b952b99af5aa923f96fe2'
            'df4f22779ec1b476c368229d89beb661adb7a6817d148dc48be827b00c63f3f1')


prepare()
{
  cd ${_build_dir}

  patch -p0 < ${srcdir}/alsa-replace-pulse.patch
}

build()
{
  cd ${_build_dir}

  autoreconf -ifv
  ./configure --prefix=/usr
  make
}

package()
{
  cd ${_build_dir}

  make DESTDIR=${pkgdir} install
}