abslibre/libre/vhba-module/PKGBUILD

# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: Mateusz Herych <heniekk@gmail.com>
# Contributor: Charles Lindsay <charles@chaoslizard.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_basekernel=5.12.6

pkgbase=vhba-module
pkgname=(vhba-module vhba-module-dkms)
pkgver=20210418
pkgrel=15
pkgrel+=.parabola1.basekernel${_basekernel%-*}
pkgdesc="Kernel module that emulates SCSI devices"
pkgdesc+=" (built for the linux-libre kernel package)"
url="https://cdemu.sourceforge.io/"
arch=(x86_64)
arch+=(i686)
license=(GPL)
makedepends=(linux-libre-headers=${_basekernel%-*} git libelf)
source=("https://downloads.sourceforge.net/cdemu/$pkgbase-$pkgver.tar.xz"
        60-vhba.rules dkms.conf)
sha256sums=('18bd82ae27721ad1612b3c31accd81898ae326370964385ca52a2a66b67a3f85'
            '3052cb1cadbdf4bfb0b588bb8ed80691940d8dd63dc5502943d597eaf9f40c3b'
            '8cab0ebb4fee72069d63616b0983f105b98d1261e72e9bef5509a6e60bc382a7')

prepare() {
  cd $pkgbase-$pkgver
  sed -i 's/20190302/20190410/' Makefile  # Fixup VHBA_VERSION
}

build() {
  cd $pkgbase-$pkgver
  make KERNELRELEASE="$(</usr/src/linux-libre/version)"
}

package_vhba-module() {
  depends=(linux-libre=${_basekernel%-*})
  provides=(VHBA-MODULE)

  local extradir="/usr/lib/modules/$(</usr/src/linux-libre/version)/extramodules"
  cd $pkgbase-$pkgver
  install -Dt "$pkgdir$extradir" -m644 *.ko
  install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
  echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"

  find "$pkgdir" -name '*.ko' -exec strip --strip-debug {} +
  find "$pkgdir" -name '*.ko' -exec xz {} +
}

package_vhba-module-dkms() {
  depends=(dkms)
  provides=(VHBA-MODULE)
  conflicts=(vhba-module)

  cd $pkgbase-$pkgver
  install -Dt "$pkgdir/usr/src/$pkgbase-$pkgver" -m644 Makefile vhba.c ../dkms.conf
  install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
  echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"
}

# vim:set ts=2 sw=2 et: