abslibre/libre/atool/PKGBUILD

# Maintainer (arch): Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor: leif_thande <leif.thande@gmail.com>
# Contributor: tranquility <trankas@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: Márcio Silva <coadde@hyperbola.info>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgname=atool
pkgver=0.39.0
pkgrel=6
pkgrel+=.par1
pkgdesc="A script for managing file archives of various types"
pkgdesc+=", without nonfree unace and unrar support"
arch=('any')
url="http://www.nongnu.org/$pkgname/"
license=('GPL3')
depends=('file' 'perl')
replaces=("$pkgname-libre")
conflicts=("$pkgname-libre")
optdepends=("bzip2: for using $pkgname with bzip2 compressed archives"
            "cpio: for using $pkgname with cpio archives"
            "gzip: for using $pkgname with gzip compressed archives"
            "lhasa: for using $pkgname with lha, lharc and similar archives"
            "xz: for using $pkgname with lzma compressed archives"
            "lzop: for using $pkgname with lzop compressed archives"
            "p7zip: for using $pkgname with 7z archives"
            "tar: for using $pkgname with tar archives"
            "zip: for using $pkgname for creating zip archives"
            "unzip: for using $pkgname for unpacking archives")
source=(http://savannah.nongnu.org/download/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
        libre.patch)
validpgpkeys=('4E6E6521EF300E30457D7AFB8AAAC30E7088EFCB') # Oskar Liljeblad <oskar@osk.mine.nu>
sha256sums=('aaf60095884abb872e25f8e919a8a63d0dabaeca46faeba87d12812d6efc703b'
            'SKIP'
            'c9aa3c72e4c979d236dd659f16cc1eb6841f0860e6ef4d2c90f021d6e5aca578')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}

  # remove nonfree unace and unrar support
  patch -Np1 -i ../libre.patch
}

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  ./configure --prefix=/usr --sysconfdir=/etc
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}