# Maintainer (Arch): Antonio Rojas <arojas@archlinux,org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=konqueror
pkgver=19.12.3
pkgrel=1
pkgrel+=.parabola1
pkgdesc="KDE File Manager & Web Browser"
pkgdesc+=", without Google, nonfree software recommendation and nonfree qt5-webengine support"
arch=(x86_64)
arch+=(i686 armv7h)
url="https://konqueror.org/"
license=(LGPL)
depends=(dolphin keditbookmarks qt5-script kdelibs4support khtml)
makedepends=(extra-cmake-modules kdoctools kdesignerplugin kdesu)
optdepends=('kdesu: shell command plugin')
groups=(kde-applications kdebase)
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
source+=('libre.patch')
sha256sums=('0f2b31a1dae1740839232bd646bf22d7cb57e34995584b9a96271ebcb0da7f0e'
            'SKIP'
            '677a8cc6a725a1f66a97d79e2ca07d08f8a4328e9704f033f6686c921122f207')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  # Remove nonfree WebEngine support and nonfree software or Google recommendation
  rm -rv webenginepart
  patch -Np1 -i "$srcdir"/libre.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}
