# Maintainer (Arch): Alad Wenter <alad@archlinux.org>
# Maintainer (Arch): schuay <jakob.gruber@gmail.com>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=mc
pkgver=4.8.26
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A file manager that emulates Norton Commander"
pkgdesc+=", with arj recommendation included and nonfree unace and unrar support removed"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://midnight-commander.org/"
license=('GPL')
depends=('e2fsprogs' 'glib2' 'gpm' 'libssh2' 'slang' 'which')
makedepends=('libxt' 'libx11' 'unzip')
optdepends=('aspell: spelling corrections'
            'cabextract: ucab extfs'
            'cdparanoia: audio extfs'
            'cdrkit: iso9660 extfs'
            'cvs: CVS support'
            'gawk: hp48+ extfs'
            'mtools: a+ extfs'
            'p7zip: support for 7zip archives'
            'perl: needed by several extfs scripts'
            'python: to access uc1541 or s3 storage'
            'python-boto: s3+ extfs'
            'python-pytz: s3+ extfs'
            'samba: VFS support'
            'arj: uarj extfs'
            'zip: uzip extfs')
conflicts=('mc-libre')
replaces=('mc-libre')
backup=('etc/mc/edit.indent.rc'
        'etc/mc/filehighlight.ini'
        'etc/mc/mc.ext'
        'etc/mc/mc.keymap'
        'etc/mc/mc.menu'
        'etc/mc/mcedit.menu'
        'etc/mc/sfs.ini')
options=('!emptydirs')
source=("http://ftp.midnight-commander.org/${pkgname}-${pkgver}.tar.xz"
        "mc-mksh-subshell-v2.patch"
        "mc-python3.patch"
        'libre.patch')
sha256sums=('c6deadc50595f2d9a22dc6c299a9f28b393e358346ebf6ca444a8469dc166c27'
            '5147afa3f9dfc00d8b7b36bbb144bcdb78d86301a0f8196686262a9eee41fb96'
            '10ab8b8c03770f8fe51f0bdbf0d66a44313bf2eed687cf769397909c07d8e8d5'
            'e3124bb9c43bdf43765e5538381c6b8749619e2fdde4f711e6a17d0ff6946dd8')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -p1 < "$srcdir"/mc-mksh-subshell-v2.patch
  patch -p1 < "$srcdir"/mc-python3.patch
  patch -Np1 -i ../libre.patch
  rm -v src/vfs/extfs/helpers/u{ace,rar}.in
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
      --prefix=/usr \
      --libexecdir=/usr/lib \
      --sysconfdir=/etc \
      --enable-vfs-smb \
      --with-screen=slang \
      --with-x
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # Replace mc.keymap symlink with target file to fix backup mechanism (FS#50889).
  rm "${pkgdir}"/etc/mc/mc.keymap && cp "${pkgdir}"/etc/mc/mc{.default,}.keymap
}
