# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer (Artix): artoo <artoo@artixlinux.org>

_pkgname=udev-gentoo-scripts

pkgname=udev-init-scripts
pkgver=33
pkgrel=1
pkgdesc="udev startup scripts for OpenRC"
arch=('any')
url="https://gitweb.gentoo.org/proj/udev-gentoo-scripts.git"
license=('GPL2')
depends=('eudev')
provides=('udev-openrc' 'eudev-openrc')
conflicts=(${provides[@]})
replaces=(${provides[@]})
source=(#"http://dev.gentoo.org/~williamh/dist/${pkgname}-${pkgver}.tar.gz"
        "${url}/snapshot/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('62c8ad0f75bdd1c1039478007336b64a91245e1405591ba4ec3d7bd59b2bec54')

package(){
    cd "${_pkgname}-${pkgver}"
    make DESTDIR="${pkgdir}" install

    for f in ${pkgdir}/etc/init.d/*;do
        sed -e "s|/bin/udevadm|/usr/bin/udevadm|g" \
            -e "s|/sbin/udevd|/usr/bin/udevd|g" \
            -e 's|#!/sbin/openrc-run|#!/usr/bin/openrc-run|g' \
            -i "$f"
    done

    install -d "${pkgdir}/etc/runlevels/sysinit"
    ln -sf "/etc/init.d/udev" "${pkgdir}/etc/runlevels/sysinit/udev"
    ln -sf "/etc/init.d/udev-trigger" "${pkgdir}/etc/runlevels/sysinit/udev-trigger"
}
