# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

pkgname=(parabolaweb-utils parabolaweb-dev)
pkgver=20190407.1
pkgdesc="Utilities for managing the ParabolaWeb website application"
url="https://git.parabola.nu/packages/parabolaweb-utils.git/"
license=('GPL2')
makedepends=('python-pip')

# The commit to get dependency info for
# Bump pkgrel instead of pkgver if updating this is the only change
_parabolaweb_commit=f013c8d8cb06f7c993bbc41519de5ab7dd2ce0c4

pkgrel=1
epoch=1
arch=('i686' 'x86_64' 'armv7h')

source=("https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig}
	"requirements_prod-${_parabolaweb_commit}.txt::https://git.parabola.nu/server/parabolaweb.git/plain/requirements_prod.txt?id=${_parabolaweb_commit}"
	"requirements-${_parabolaweb_commit}.txt::https://git.parabola.nu/server/parabolaweb.git/plain/requirements.txt?id=${_parabolaweb_commit}")
sha256sums=('c352e225d65597066cb986db263461cf5bc3d317b459b38fcea4212cabae7fa3'
            'SKIP'
            '67cf8fb90fd7f0e465d68b05ce3ff3d74ea5b0defd2bd26e0b46e66f3e44e380'
            '8d8b7dae5a36471e0db0832a0ac315409ef43972d98223a6ad4db038991dc7fb')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

prepare() {
	cd "$srcdir"
	ln -sf requirements-${_parabolaweb_commit}.txt requirements.txt
	ln -sf requirements_prod-${_parabolaweb_commit}.txt requirements_prod.txt
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	prod_file=../requirements_prod.txt make
}

package_parabolaweb-utils() {
	cd "$srcdir/$pkgbase-$pkgver"
	depends=($(< depends.txt))
	backup=('etc/conf.d/parabolaweb'
		'etc/uwsgi/parabolaweb.ini'
		'etc/sudoers.d/10-parabolaweb')
	make install DESTDIR="$pkgdir"
}

package_parabolaweb-dev() {
	cd "$srcdir/$pkgbase-$pkgver"
	pkgdesc="Depends on packages needed to develop ParabolaWeb"
	depends=($(sed -r -e 's/\s*#.*//' depends_make.txt))
}
