# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-freedom
pkgdesc="This package conflicts with every nonfree package known to date to ensure your system is free."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20210430
_gitver=27f2573c1389eff98fe918d54397c0bd3a6561ba
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/blacklist.txt?id=${_gitver})
sha512sums=('4c40dfa68e165613cc4a9839122739fdb70cfc1023c0f8f3a1ec2f2b8102fa33068877704004c333821f5c8ac05cd1c3386a9fe3af4a18b2e361764ac1181718')


package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}
