# Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Loui Chang <louipc dot ist at gmail company>
# Contributor: Jeff Mickey <j@codemac.net>
# Contributor: Aaron Griffin <aaron@archlinux.org>

_pkgname=esmtp
pkgver=1.2
pkgname=$_pkgname-lukeshu
provides=($_pkgname=$pkgver)
conflicts=($_pkgname)
pkgrel=6
pkgdesc="An easy SMTP forwarder."
arch=('i686' 'x86_64')
url='http://esmtp.sourceforge.net'
url='https://git.lukeshu.com/esmtp/'
license=('GPL')
depends=('libesmtp-lukeshu' 'openssl')
optdepends=('liblockfile: for esmtp-wrapper script'
            'procmail: for local mail delivery')
provides=('smtp-forwarder')
conflicts=('smtp-forwarder')
source=("http://downloads.sourceforge.net/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2"
        "0001-Produce-more-useful-Invalid-peer-certificate-error-m.patch")
md5sums=('79a9c1f9023d53f35bb82bf446150a72'
         '799571f0b37f85f60928e32e03afdf51')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  patch -Np1 -i ../0001-Produce-more-useful-Invalid-peer-certificate-error-m.patch
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  install -Dm0644 README "${pkgdir}/usr/share/doc/esmtp/README"
  install -Dm0644 sample.esmtprc "${pkgdir}/usr/share/doc/esmtp/sample.esmtprc"
  install -Dm0755 esmtp-wrapper "${pkgdir}/usr/share/esmtp/esmtp-wrapper"
  install -Dm0755 ylwrap "${pkgdir}/usr/share/esmtp/ylwrap"
}
