# Maintainer (arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contrbutor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
#  - remove foomatic-db-nonfree recommendation
#  - pin to strongly-coupled dependency versions
#  - substitute 'systemd' dependency with 'udev'


pkgname=cups-filters
pkgver=1.28.8
pkgrel=1
pkgrel+=.parabola4
pkgdesc="OpenPrinting CUPS Filters"
pkgdesc+=", without foomatic-db-nonfree recommendation"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="https://wiki.linuxfoundation.org/openprinting/cups-filters"
license=('custom')
depends=('lcms2' 'poppler' 'qpdf' 'imagemagick' 'liblouis' 'ijs' 'libcups>=2.2.6-2' 'systemd')
depends=( ${depends[@]/systemd/udev} )
makedepends=('ghostscript' 'ttf-dejavu' 'python' 'mupdf-tools') # ttf-dejavu for make check
makedepends_i686=('pkgconf')
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
            'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
            'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly'
            'antiword: to convert MS Word documents'
            'docx2txt: to convert Microsoft OOXML text from DOCX files')
backup=(etc/cups/cups-browsed.conf)
source=(https://www.openprinting.org/download/cups-filters/$pkgname-$pkgver.tar.xz)
sha256sums=('f6fc4663f83ce37795c097f5accc866791fdce920b9999bb125564f6eeeca218')

build() {
  cd "$pkgname"-$pkgver
  ./configure --prefix=/usr  \
              --sysconfdir=/etc \
              --sbindir=/usr/bin \
              --localstatedir=/var \
              --with-rcdir=no \
              --enable-avahi \
              --with-browseremoteprotocols=DNSSD,CUPS \
              --enable-auto-setup-driverless \
              --with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

check() {
  cd "$pkgname"-$pkgver
  make check
}

package() {
  # pin to current 'poppler' lib
  local poppler_ver=$(pacman -S --print-format='%v' poppler)
  depends=( ${depends[@]/poppler/poppler=${poppler_ver}} )

  cd "$pkgname"-$pkgver
  make DESTDIR="$pkgdir/" install

  # add upstream systemd support file
  install -Dm644 utils/cups-browsed.service "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service
  sed -i "s|/usr/sbin/cups-browsed|/usr/bin/cups-browsed|" "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service
  #sed -i "s|cups.service|org.cups.cupsd.service|g" "${pkgdir}"/usr/lib/systemd/system/cups-browsed.service

  # use cups group from cups pkg FS#56818
  chgrp -R 209 "${pkgdir}"/etc/cups

  # license
  mkdir -p "${pkgdir}"/usr/share/licenses/${pkgname}
  install -m644 "${srcdir}"/${pkgname}-${pkgver}/COPYING "${pkgdir}"/usr/share/licenses/${pkgname}/
}
