# Maintainer: Freemor <freeor@freemor.ca>

pkgname=dasher
pkgver=4.11
pkgrel=1
pkgdesc="Information-efficient text-entry interface, driven by natural continuous pointing gestures"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
depends=('speech-dispatcher' 'gtk3')
makedepends=('git' 'gnome-common' 'gnome-doc-utils')
url="https://github.com/dasher-project/dasher"
source=('git+https://github.com/dasher-project/dasher.git')
sha256sums=('SKIP')


pkgver() {
  cd $pkgname
  git describe --long | sed -e 's/-/+/g' -e 's/^DASHER_//' -e 's/_/./g'
}

prepare() {
  cd $pkgname
  ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-scrollkeeper --enable-speech
  make
}

package() {
  cd $pkgname
  make DESTDIR="${pkgdir}" install
}
