# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=printrun
pkgver=20140126
pkgdesc="Host software for 3D printing"
url="https://github.com/kliment/Printrun"
license=('GPL3') # GPLv3+

pkgrel=1
arch=('any')
depends=('python2-pyserial' 'python2-pyglet' 'wxpython')
optdepends=(
	'python2-numpy: for 3D view'
	'python2-cairo: for Projector feature'
#	'python2-tornado: for prontserve'
)

source=("https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz")
md5sums=('d8b04115306d7b6b07d712af15383db7')

mkdepends=('git')
mksource=("$pkgname-$pkgver::git://github.com/kliment/Printrun.git#tag=$pkgname-$pkgver")
mkmd5sums=('SKIP')

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	python2 setup.py build
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	python2 setup.py install --root="${pkgdir}" --prefix=/usr

	local file
	for file in "$pkgdir"/usr/bin/*.py; do
		mv "$file" "${file%.py}"
	done
}
