# Maintainer (AUR): Xavier Devlamynck <magicrhesus@ouranos.be>
# Contributors (AUR): Keshav P R, atommix aka Aleks Lifey, Xavion, Ananda Samaddar, Dan Serban, Xyne
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

# parabola changes and rationale:
#  - corrected used license
#  - fixed build by removing the following line:
#    . /etc/profile.d/apache-ant.sh
#  - removed bundled binaries

pkgname=jitsi
pkgver=2.10.5550
pkgrel=10
pkgdesc="An audio/video SIP VoIP phone and instant messenger written in Java (formerly SIP-Communicator)"
arch=('armv7h' 'i686' 'x86_64')
url="http://jitsi.org"
license=('Apache')
depends=('java-runtime=8')
makedepends=('ant' 'java-environment=8')
options=(!strip !emptydirs zipman !libtool docs)
source=("https://download.jitsi.org/jitsi/src/jitsi-src-${pkgver}.zip"
		jitsi.desktop
		jitsi.sh)
sha256sums=('cdfc6f038d1b877c42d26dba1864ac7c6b554dd55c18767a29f2db3618647287'
            '40a411ec494280490a0e1a137735ef5efca434d8d10f18b0124df9e93302f959'
            '366d2d33ee32375d24a5c754338ea7fcc824f18ce65b16db20adf28f642172ec')


prepare()
{
  cd "${srcdir}/${pkgname}"
  rm -rf lib/native
}

build()
{
  cd "${srcdir}/${pkgname}"
  # append the build revision to the jitsi version
  sed -i "s/0\.build\.by\.SVN/build.${pkgver}/" src/net/java/sip/communicator/impl/version/NightlyBuildID.java
  cd src/native
  ant rebuild
  cd ../..
  ant rebuild
}

package() {
  cd "${srcdir}/${pkgname}"
  find lib/ lib/bundle/ -maxdepth 1 -type f -exec install -Dm644 {} "${pkgdir}/usr/lib/${pkgname}/"{} \;
  shopt -sq extglob
  find sc-bundles/{,os-specific/linux/} -maxdepth 1 -type f -execdir install -Dm644 {} "${pkgdir}/usr/lib/${pkgname}/sc-bundles/"{} \;
  install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"

  cd "resources/install/debian/"
  for _file in *.{svg,xpm}; do
    install -Dm644 "$_file" "${pkgdir}/usr/share/pixmaps/${_file}"
  done
}
