# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_libname=avalon-logkit
pkgname=java-${_libname}
pkgver=2.1
pkgrel=1
pkgdesc="Lightweight and fast designed logging toolkit for Java"
arch=('any')
url="https://avalon.apache.org"
license=('APACHE')
depends=('java-runtime')
makedepends=('apache-ant' 'java-geronimo-jms' 'javamail' 'jh' 'junit' 'log4j-1.2' 'tomcat8')
source=("https://archive.apache.org/dist/excalibur/${_libname}/source/${_libname}-${pkgver}-src.tar.gz"
        "https://repo.maven.apache.org/maven2/${_libname}/${_libname}/${pkgver}/${_libname}-${pkgver}.pom"
        'avalon-logkit-implement_abstract_methods.patch'
        'avalon-logkit-utf8_encoding.patch')
md5sums=('fee6f5f2db70c320aafbfb4cc32c1c43'
         '830f9ba5ef4f0ceaa2601ca9c87d0fc6'
         '3faff7e6ecc53c2caf26d707f7b223d2'
         'a2310f8d589262001983ceb3780ecf75')

prepare() {
  cd "${srcdir}/${_libname}-${pkgver}"
  patch -Np1 -i ../avalon-logkit-utf8_encoding.patch
  patch -Np1 -i ../avalon-logkit-implement_abstract_methods.patch
}

build() {
  cd "${srcdir}/${_libname}-${pkgver}"

  ant dist -Dnoget=true \
    -Dlibdir=/usr/share/java
}

package() {
  cd "${srcdir}/${_libname}-${pkgver}"

  # Install license file
  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"

  # Install documentation
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r "dist/docs/api" "${pkgdir}/usr/share/doc/${pkgname}"

  # Install Maven artifacts
  export DESTDIR=${pkgdir}
  jh mvn-install ${_libname} ${_libname} ${pkgver} \
    "${srcdir}/${_libname}-${pkgver}.pom" \
    "dist/${_libname}-${pkgver}.jar" \
    "${_libname}-${pkgver}.jar"
  ln -s "/usr/share/java/${_libname}-${pkgver}.jar" \
    "${pkgdir}/usr/share/java/${_libname}.jar"
}
