# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
# Contributor (Arch): speps <speps at aur dot archlinux dot org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: fauno <fauno@parabola.nu>

pkgname=minitube
pkgver=3.6.1
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A YouTube desktop application"
pkgdesc+=", without nonfree recommendations"
arch=('x86_64')
arch+=('i686')
url="https://flavio.tordini.org/minitube"
license=('GPL3')
depends=('gcc-libs' 'glibc' 'qt5-base' 'qt5-declarative' 'qt5-x11extras')
makedepends=('mpv' 'qt5-tools')
source=("https://github.com/flaviotordini/${pkgname}/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.bz2"
        'remove_unfree_recommendations.patch')
sha512sums=('034baa51934564f492049c6a2a4c2eaabf335f1168593aa27664a5f268b0dc4136217c8da4d1a80e777879d7ad3d109d4ba7089cf387dc76f97af52c7c6d3609'
            '1e030cec9469f4823c32fa015c22d1b4743258bd922543eaab1aa5bb868bc77298dce691175a4068305f3f7ccba3cfaeba09054f00bde9a47cbbe97a3a132de3')

prepare() {
  cd "${pkgname}-${pkgver}"
  patch -p1 -i ../remove_unfree_recommendations.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  qmake
}

package() {
  depends+=('libmpv.so')
  cd "${pkgname}-${pkgver}"
  make install INSTALL_ROOT="${pkgdir}/"
  install -vDm 644 {AUTHORS,CHANGES,README.md,TODO} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}
