# Maintainer (arch): David Runge <dvzrv@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Asa Marco <marcoasa90[at]gmail[.]com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>


# parabola changes and rationale:
# - remove optdepends 'faac'
# - pin to tightly-coupled dependency versions


pkgname=openshot
pkgver=2.5.1
pkgrel=4
pkgrel+=.parabola1
pkgdesc="An award-winning free and open-source video editor"
pkgdesc+=", without nonfree faac recommendation"
arch=(any)
url="https://www.openshot.org/"
license=(GPL3)
depends=(ffmpeg python-pyqt5 python-requests python-setuptools libopenshot
         libopenshot-audio python-pyzmq qt5-base qt5-svg qt5-webkit)
source=($pkgname-$pkgver.tar.gz::https://github.com/OpenShot/openshot-qt/archive/v$pkgver.tar.gz)
sha512sums=('8254a45254bbe523b6485b9598022de2c46ec30818e606ac4665790d29486693c4efe9f5bc55ee43d6342de6782cf0090e4bc880e831c08e3b1218bca555af14')

build() {
  cd ${pkgname}-qt-${pkgver}
  python setup.py build
}

package() {
  cd ${pkgname}-qt-${pkgver}
  python setup.py install --skip-build \
                          --optimize=1 \
                          --prefix=/usr \
                          --root="${pkgdir}"
  install -vDm 644 {AUTHORS,{CONTRIBUTING,README}.md} \
    -t "${pkgdir}"/usr/share/doc/${pkgname}

  # pin to current 'qt5-base' libs
  local qt5_ver=$(pacman -S --print-format='%v' qt5-base)
# TODO: and/or python-pyqt5 https://labs.parabola.nu/issues/3036
#local qt5_ver=$(pacman -S --print-format='%v' python-pyqt5)
  depends=( ${depends[@]/qt5-base/qt5-base=${qt5_ver}} ) 
}
