# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-initfreedom
pkgdesc="This package conflicts with every package known to work only for/with systemd."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20200617
_gitver=bfeb700f416853a64851d013245e2964f907b626
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver})
sha512sums=('706ba7a132346926b57db9def597fd2e06fab6e1916de85ff049ed5708f95e2032d30d1586853358647763c5cb399c15518ab2005ed90cd57f29918ecc798c4e')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}
