# Maintainer (AUR) : tuftedocelot@fastmail.fm
# Maintainer (AUR) : frank604 <frankshin82 at gmail>
# Maintainer (AUR) : youngunix <zagazaw2004 'at' gmail 'dot' com>
# Maintainer (AUR) : Jeremy L <jl AT adminempire DOT com>
# Maintainer (Arch) : Alexander F Rødseth <xyproto@archlinux.org>
# Contributor (Arch) : Laurie Clark-Michalek <bluepeppers@archlinux.us>
# Contributor (Arch) : graysky <graysky AT archlinux DOR us>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Aurélien DESBRIÈRES <aurelien@hackers.camp>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

_pkgname=paraboley
# FIXME: couldn't we skip the -git to simplify provides=() ?
#        we should probably use the one in [community] over AUR
pkgname=${_pkgname}-git
pkgver=9
pkgrel=1
pkgdesc="Python script to display system infomation alongside the Parabola GNU/Linux-libre logo."
arch=('any')
url="https://projects.parabola.nu/paraboley.git"
license=('GPL')
depends=('python')
makedepends=('git' 'python-distribute')
optdepends=(
'python-mpd-git: python libary for mpd interaction',
'python-logbook-git: for logging'
'imagemagick: for default screenshot command'
)
conflicts=('archey3')
provides=('archey3' 'paraboley')
replaces=('archey3')
source=("git://projects.parabola.nu/paraboley.git")
md5sums=('SKIP')

pkgver() {
	cd ${_pkgname}
    git rev-list --count HEAD
}

package() {
	cd "$_pkgname"
	python setup.py install --root=${pkgdir}
	install -D -m644 COPYING ${pkgdir}/usr/share/licenses/paraboley/COPYING
}
