# Maintainer (AUR): parazyd <parazyd AT dyne DOT org>
# Contributor: fauno <fauno@kiwwwi.com.ar>

# parabola changes and rationale:
#  - updated package to 2.2.3 (AUR is 2.0.2)
#  - fixed broken source url
#  - added missing makedepends: python-setuptools-scm python2-sphinx python2-pysocks

pkgname=monkeysign
pkgver=2.2.3
pkgrel=1
pkgdesc="OpenPGP Key Exchange for Humans"
arch=('any')
url="http://web.monkeysphere.info/monkeysign/"
license=('GPL3')
depends=('python2-qrencode' 'gtk2' 'pygtk' 'zbar' 'python2-imaging')
makedepends=('python2-setuptools-scm' 'git' 'python2-sphinx' 'python2-pysocks')
source=("git+https://0xacab.org/monkeysphere/monkeysign.git/#commit=2.2.3")
sha256sums=('SKIP')

build() {
    cd "${pkgname}"
    python2 setup.py build
}

package() {
    cd "${pkgname}"
    python2 setup.py install --root="${pkgdir}" --prefix="/usr" --optimize=1
}
