# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=calamares
pkgver=3.2.20
pkgrel=parabola2
pkgdesc="Distribution-independent installer framework - Parabola edition"
arch=(i686 x86_64)
url=https://calamares.io/
license=(GPL)

depends=(boost-libs ckbcomp dmidecode gptfdisk hwinfo icu kconfig kcoreaddons ki18n
         kparts kpmcore libpwquality polkit-qt5 python solid qt5-base qt5ct qt5-svg yaml-cpp)
makedepends=(boost extra-cmake-modules git kservice kwindowsystem qt5-tools)
depends+=(os-prober) # FIXME: qemu+calamares+os-prober was buggy last build - try again
# conflicts=(os-prober) # FIXME: qemu+calamares+os-prober is still buggy

source=(git+https://git.parabola.nu/${pkgname}.git#tag=v${pkgver}-${pkgrel%%.*})
sha256sums=('SKIP')


_version_constraint() # (dep_pkgname)
{
  local dep_pkgname=$1
  local version=$(pacman -S --print-format='%v' ${dep_pkgname} | tail -n 1)
  version=${version%-*}
  local version_inc=${version%.*}.$(( ${version##*.} + 1 ))

  echo -n "${dep_pkgname}>=${version}" "${dep_pkgname}<${version_inc}"
}

prepare()
{
  sed -i "s|_BUILD_DATE_|$(date +%Y.%m)|" ${srcdir}/${pkgname}/src/branding/parabola/branding.desc
}

build()
{
  mkdir -p "${srcdir}"/${pkgname}/build
  cd       "${srcdir}"/${pkgname}/build

  cmake -DCMAKE_BUILD_TYPE=Release                                                     \
        -DCMAKE_INSTALL_PREFIX=/usr                                                    \
        -DCMAKE_INSTALL_LIBDIR=lib                                                     \
        -DSKIP_MODULES="contextualprocess dracut dracutlukscfg dummycpp dummyprocess   \
                        dummypython dummypythonqt fsresizer hostinfo initramfs         \
                        initramfscfg interactiveterminal license netinstall networkcfg \
                        notesqml oemid openrcdmcryptcfg packages plasmalnf plymouthcfg \
                        preservefiles rawfs removeuser shellprocess tracking unpackfs  \
                        webview"                                                       ..
  make
}

package()
{
  depends+=( $(_version_constraint 'boost-libs') \
             $(_version_constraint 'icu'       ) \
             $(_version_constraint 'kpmcore'   ) \
             $(_version_constraint 'qt5-base'  ) )

  cd "${srcdir}"/${pkgname}/build

  make DESTDIR=${pkgdir} install
}
