# Maintainer: Parabola automatic package builder <autobuilder@parabola.nu>

pkgname=parabola-keyring
pkgver=20191127
_gitver=89066299c593bd574bda1c97f2a5c9be3bb833cf
pkgrel=1
pkgdesc='Parabola GNU/Linux-libre PGP keyring'
arch=('any')
url='https://git.parabola.nu/hackers.git/'
license=('GPL')
install=$pkgname.install
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig})
sha512sums=('7955ba2afc61f2918025816494859faf2ed27ebdc609d492aae23f3b51744b29a2e4056823f1d4d6ae04837793a3cf24c431f0025b5ca719aa6b7ee64d4638ad'
            'SKIP')
validpgpkeys=('D3EAD7F9D076EB9AF650149DA170D6A0B669E21A') # Parabola automatic package builder <dev@lists.parabolagnulinux.org>

mkdepends=('parabola-hackers')
mksource=("hackers-${_gitver}::git://git.parabola.nu/hackers.git#commit=${_gitver}")
mkmd5sums=('SKIP')

mksource() {
	cd "$srcdir"
	mv {,.}hackers-$_gitver
	mkdir .cachedir
	/usr/lib/parabola-hackers/pacman-make-keyring \
		V="$pkgver" \
		PARABOLA_HACKERS_YAMLDIR="$PWD/.hackers-$_gitver/users" \
		cachedir="$PWD/.cachedir"
	bsdtar xf "$pkgname-$pkgver.tar.gz"
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make PREFIX=/usr DESTDIR="${pkgdir}" install
}
