# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: bill-auger <bill-auger@programmer.net>


pkgname=parabola-vmbootstrap
pkgver=20200401
pkgrel=1
arch=('any')
pkgdesc="helper scripts to build and boot parabola virtual machine images"
license=('GPL3')
url="https://git.parabola.nu/parabola-vmbootstrap.git/"

depends=(arch-install-scripts bash binutils librelib parted qemu
         qemu-arch-extra qemu-user-static-binfmt sudo wget)
makedepends=(git)

source=(git+https://git.parabola.nu/${pkgname}.git#tag=v${pkgver})
sha256sums=('SKIP')


package()
{
  cd "$srcdir"/$pkgname

  local _bin_dir="$pkgdir"/usr/bin
  local _lib_dir="$pkgdir"/usr/lib/$pkgname
  local _lic_dir="$pkgdir"/usr/share/licenses/$pkgname
  local _hook_script

  install -Dm755 src/pvmbootstrap.sh   "$_bin_dir"/pvmbootstrap
  install -Dm755 src/pvmboot.sh        "$_bin_dir"/pvmboot
  install -Dm755 src/pvm2tarball.sh    "$_bin_dir"/pvm2tarball

  install -Dm755 src/pvm-common.sh.inc "$_lib_dir"/pvm-common.sh.inc
  for _hook_script in src/hooks/*
  do  install -Dm644 $_hook_script     "$_lib_dir"/$(basename $_hook_script)
  done

  install -Dm644 COPYING               "$_lic_dir"/LICENSE
}
