# $Id: PKGBUILD 114621 2014-07-02 09:40:38Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): Ner0 <darkelfdarkelf666@yahoo.co.uk>
# Contributor (Arch): Sander Deryckere  <sanderd17@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Jorge Araya Navarro <elcorreo@deshackra.com>

pkgname=faience-icon-theme
pkgver=0.5.1
pkgrel=3.parabola2
pkgdesc='An icon theme based on Faenza, without nonfree distros and application icons (Parabola rebranded)'
url='http://tiheum.deviantart.com/art/Faience-icon-theme-255099649'
license=('GPL3')
arch=('any')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=('faenza-icon-theme')
source=("http://ppa.launchpad.net/tiheum/equinox/ubuntu/pool/main/f/${pkgname}/${pkgname}_${pkgver}.tar.gz"
        'start-here-parabola-symbolic.svg')
sha256sums=('da4e6e921c465caeb8904d4fc6a183b173c8000c08abce625b5b6739f5a0867a'
            'ad3a47c9545358046b8ef1695cbc6effc913d7affbf27017744419d33e66aea6')

prepare() {
  cd ${pkgname}-${pkgver%.*}
  rm -rv debian

  # remove nonfree distros and application logos
  for nonfree in archlinux debian fedora frugalware gentoo linux-mint mandriva opensuse redhat slackware ubuntu flash rpmdrake skype; do
   find -name *$nonfree* -delete
  done

  # add the Parabola GNU/Linux-libre logo to the source code
  cp -a "$srcdir/start-here-parabola-symbolic.svg" Faience/places/scalable

  # set the Parabola GNU/Linux-libre start menu logo
  cd Faience/places/scalable
  ln -sf start-here{-parabola-symbolic,-symbolic}.svg
}

package() {
  cd ${pkgname}-${pkgver%.*}

  install -dm 755 "${pkgdir}"/usr/share/icons
  cp -dr --no-preserve=ownership Faience* "${pkgdir}"/usr/share/icons/

# Fix permissions
  find "${pkgdir}" -type d -exec chmod 755 {} +
  find "${pkgdir}" -type f -exec chmod 644 {} +
}

# vim: ts=2 sw=2 et:
