# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org> 
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=ark
pkgver=21.04.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Archiving Tool'
pkgdesc+=', with unarchiver support'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://apps.kde.org/ark/'
license=(GPL)
depends=(kparts kpty libarchive libzip kitemmodels hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools)
optdepends=('p7zip: 7Z format support' 'unarchiver: RAR format support'
            'lzop: LZO format support' 'lrzip: LRZ format support')
groups=(kde-applications kde-utilities)
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
source+=(libre.patch)
sha256sums=('0e5e0552598038e38f42d813aefb46ebee9a3d00ffb1ea163b526de58ce39e0c'
            'SKIP'
            '624bd7cd221db2a80b21cd5f71c447d86091e52276f2bdb609c8916755c7d602')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i $srcdir/libre.patch
  rm -rv plugins/clirarplugin
}

build() { 
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}

