# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=libretools
pkgver=20181004
pkgrel=6.1
pkgrel+=.nonsystemd2
pkgdesc="Programs for Parabola development"
arch=('any')
url="https://git.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')
backup=(etc/libretools.conf
        etc/libretools.d/chroot.conf
        etc/libretools.d/libredbdiff.conf
        etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools libretools-mips64el)
replaces=(libretools-mips64el)
depends=(
  "librelib=$pkgver"
  "gitget=$pkgver" # `createworkdir`
  'pacman>=5.1.1-1.parabola5' 'pacman<5.3'
  arch-install-scripts # `mkarchroot` uses `pacstrap`
  binutils # `libremakepkg` uses `makepkg` uses `strip`
  expac # `libredbdiff`
  fakeroot # `libremakepkg` uses `makepkg` uses `fakeroot`
  make # `librefetch`
  openssh # `librerelease`
  rsync # `librerelease` and `makechrootpkg.sh`
  chroot-nspawn # chroot-nspawn
  tokyocabinet # `toru`
  #namcap # Namcap is currently dissabled in libremakepkg :-(
  subversion # `diff-unfree`
  wget # `aur`, optdepend for librelib:`blacklist`
)
optdepends=('qemu-user-static-binfmt: To build ARM packages from x86')
makedepends=(ruby-ronn)
checkdepends=(
  bash-bats git
  'pacman>=5.1.1-1.parabola5' 'pacman<5.3'
  expac
  openssh
  rsync
  tokyocabinet
)
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
        nonsystemd.patch
        0002-libremakepkg-pacman_5_2.patch)
sha256sums=('2bdefd1803ba3e6cbd1eb955fad3de9ce8a4abfd23a0bd96a60772762df7b53b'
            'SKIP'
            '511de3404afcb3fe2ed002a94be00bc0b83d6abeb1cf3ab0456bf916c8f1114e'
            '8986adf14a81b979b2ff4c4e3e76483115c146782e4ba30640649299f98355df')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

prepare() {
  cd "$srcdir/$pkgbase-$pkgver"

  # non-systemd patch changes:
  # * uses chroot-nspawn instead of systemd-nspawn
  # * replaces systemd-machine-id-setup with dbus-uuidgen
  patch -p1 -i ../nonsystemd.patch

  # don't apply 0001-libremakepkg-rw-startdir.patch like libre/libretools because
  # by using chroot-nspawn we don't have that issue
  patch -N -p1 -i $srcdir/0002-libremakepkg-pacman_5_2.patch
}

build() {
  cd "$srcdir/$pkgbase-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgbase-$pkgver"
  make install-libretools DESTDIR="$pkgdir"
}
