# Maintainer (Arch): Vesa Kaihlavirta <vegai@iki.fi>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

# parabola changes and rationale:
#  - removed recommendation for non-free openttd-opensfx
#  - depends on individual icu libraries to prevent upgrade breakages and
#    enable Parabola to provide older icu libraries in a separate package to
#    make transition easier for Parabola contributors. See the comments in
#    the icu-*-compat PKGBUILDs for more details.

pkgname=openttd
pkgver=1.9.3
pkgrel=2
pkgrel+=.parabola7
pkgdesc='An engine for running Transport Tycoon Deluxe.'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://www.openttd.org'
license=('GPL')
depends=('libpng' 'sdl' 'fontconfig' 'lzo' 'hicolor-icon-theme' 'desktop-file-utils' 'xz' 'fluidsynth')
depends+=('libicui18n.so' 'libicuuc.so')
optdepends=('openttd-opengfx: free graphics')
source=("https://proxy.binaries.openttd.org/openttd-releases/${pkgver}/${pkgname}-${pkgver}-source.tar.xz")
sha256sums=('1988e17f5b6f4b8f423c849ef1c579c21f678722ae4440f87b27a5fea6385846')

build() {
  cd ${pkgname}-${pkgver} 

  # http://site.icu-project.org/download/61#TOC-Migration-Issues
  CXXFLAGS+=' -DU_USING_ICU_NAMESPACE=1'

 ./configure \
    --prefix-dir=/usr \
    --binary-name=${pkgname} \
    --binary-dir=bin \
    --data-dir=share/${pkgname} \
    --install-dir="${pkgdir}" \
    --doc-dir=share/doc/${pkgname} \
    --with-fluidsynth \
    --menu-name="OpenTTD"

  make
}

package() {
  cd ${pkgname}-${pkgver} 

  make install
}
