# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>


pkgname=('python-lazr-config' 'python2-lazr-config')
pkgver=2.1
pkgrel=1
pkgdesc="Is typically used to manage process configuration"
arch=(any)
url=https://launchpad.net/lazr.config
license=('LGPL')
options=(!emptydirs)

makedepends=('python-setuptools' 'python2-setuptools')

_upstream_name='lazr.config'
_release=${_upstream_name}-${pkgver}
source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
sha256sums=('5f380f5defd1f2e0db7483f5b55072e458dcba1d38ea8b2c7867de8127970689')


package_python-lazr-config()
{
  depends=('python' 'python-lazr-delegates' 'python-nose' 'python-setuptools'
           'python-zope-interface')

  cd "${srcdir}/${_release}"

  python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-lazr-config()
{
  depends=('python2' 'python2-lazr-delegates' 'python2-nose' 'python2-setuptools'
           'python2-zope-interface')

  cd "${srcdir}/${_release}"

  python2 setup.py install --root="$pkgdir/" --optimize=1
}
