# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Contributor (Arch): Gerardo Exequiel Pozzi <djgera@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgbase=parabolaiso-git
_pkgbase=parabolaiso
pkgname=(parabolaiso-git mkinitcpio-parabolaiso-git)
pkgver=v51.r1.c43fdf45
pkgrel=1
pkgdesc='Tools for creating Parabola GNU/Linux-libre live and install iso images'
arch=('any')
license=('GPL3')
url='https://git.parabola.nu/parabolaiso.git/'
makedepends=('git')
_commit=c43fdf4
source=("git+https://git.parabola.nu/packages/parabolaiso.git#commit=${_commit}?signed")
sha256sums=('SKIP')
validpgpkeys=(6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78) # David P.

pkgver() {
  cd "${_pkgbase}"
  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

package_parabolaiso-git() {
  depends=('arch-install-scripts' 'bash' 'dosfstools' 'e2fsprogs' 'libisoburn'
  'mtools' 'squashfs-tools')
  optdepends=('edk2-ovmf: for emulating UEFI with run_parabolaiso'
              'qemu: for run_parabolaiso')
  provides=("archiso-git=$pkgver" 'parabolaiso')
  conflicts=('archiso-git' 'parabolaiso')
  replaces=('archiso-git')
  cd "${_pkgbase}"
  make DESTDIR="${pkgdir}" install
}

package_mkinitcpio-parabolaiso-git() {
  pkgdesc='Mkinitcpio hooks and scripts for parabolaiso'
  depends=('mkinitcpio')
  provides=("mkinitcpio-archiso-git=$pkgver" 'mkinitcpio-parabolaiso')
  conflicts=('mkinitcpio-archiso-git' 'mkinitcpio-parabolaiso')
  replaces=('mkinitcpio-archiso-git')
  cd "${_pkgbase}"
  make DESTDIR="${pkgdir}" install-initcpio
}
