# U-Boot: BeagleBoard and BeagleBoard-xM
# Maintainer: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgname=uboot-omap3_beagle
pkgver=2016.01
pkgrel=1
pkgdesc="U-Boot for BeagleBoard and BeagleBoard-xM"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
replaces=('uboot-beagleboard-linux-libre' 'uboot-beagleboard-linux-libre-lts'
          'uboot-beagleboard-linux-libre-grsec' 'uboot-beagleboard-linux-libre-pck'
          'uboot-beagleboard')
conflicts=('uboot4extlinux-omap3_beagle' 'uboot4grub-omap3_beagle')
makedepends=('bc')
depends=('linux-libre')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'uEnv.txt')
md5sums=('7d4f65fd43d4d706f5c5650e020d899d'
         '7922da50052c9ca5feb6f0356415d7eb'
         'd41d8cd98f00b204e9800998ecf8427e')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS CFLAGS CXXFLAGS

  make distclean
  make omap3_beagle_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}"/boot
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
}
