# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgname=debootstrap
pkgver=1.0.116
pkgrel=1
pkgrel+=.parabola2
_pureospkgver=1.0.108
_pureospkgrel=pureos2
pkgdesc="Bootstrap a basic gNewSense and Trisquel system, without Debian support"
arch=(any)
license=(GPL)
url="https://tracker.debian.org/pkg/debootstrap"
depends=(wget binutils)
source=("$pkgname-$pkgver.tar.gz::https://github.com/felixonmars/debootstrap/archive/$pkgver.tar.gz"
        "https://repo.puri.sm/pureos/pool/main/d/debootstrap/debootstrap_$_pureospkgver$_pureospkgrel.tar.gz"
        arch-detect.patch
        debootstrap.8
        gnewsense
        trisquel)
optdepends=('gnupg: check release signatures'
            'pureos-archive-keyring: check PureOS release signatures'
            'trisquel-keyring: check Trisquel release signatures')
sha512sums=('4b81bc56c6ac6e210aaceb06013882ba3cfe777d4173fd89d38a279fe57425302b86b2fb00ea2e19df2abfb7058909e1eb628f74f241612d865044b32e3481a4'
            '16888223cb3f4688ac468204bf4351080ac801456b990481602580f78666a034530b48d8bf6e989a53a393ab5edf6fdc80f5815be82fbfab3f9b845850da5d0b'
            '56e25f48027f99f7e720859a9e14fe769b1cbd6227c7a7e27e14c2fea88520109342d6e5b127dc34ce8cc40f46941a0c5157ad35cf8ef9b3e4323877a4b32d97'
            '0b3507756b8f29d19146df3201143ccbd71cfd1f7ef865d184079180612b90c046cabab59fe42d246bfe476ae8fd5c43e81ee2fc3ee06bbc1fc3e75d9f1382ca'
            '968ef005bf1f399b3400080b2ba65f1b32c067c49faadc1caa7ee524a85980f0a6625c7b06838e01bbd8b99a496492da77a38f0e17f0a81fc029ee611fe639b6'
            '06a352906de6f321f0bbd30667046eec3d9363774ba468d7dbe7c2d2cde92cca480ab4d595a84d594cd3f93ea0def1c67dc8f5bb1be6d669a29035ec289da668')

prepare() {
  cd debootstrap-$pkgver

  sed -i 's/sbin/bin/g' Makefile

  # gNewSense/Trisquel defaults
  sed -i 's|export PATH|export PATH="/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin"|' debootstrap

  # Detect Architecture
  patch -p1 -i ../arch-detect.patch

  # Remove Debian files
  rm -v debootstrap.8

  # Add rebranded man
  install -m644 ../debootstrap.8 .

  # Remove (non-FSDG compliant) distributions's scripts
  for SCRIPT in scripts/* ; do
    case $SCRIPT in
    scripts/debian-common)
      ;;
    *)
      rm -v $SCRIPT
      ;;
    esac
  done

  # Add gNewSense script
  install -m644 $srcdir/gnewsense scripts

  # Add PureOS script
  install -m644 $srcdir/debootstrap/scripts/amber scripts/pureos

  # Add Trisquel script
  install -m644 $srcdir/trisquel scripts

  # Enter to scripts dir
  cd scripts

  # Create gNewSense symlinks
  ln -s gnewsense ucclia
  ln -s gnewsense parkes

  # Create PureOS symlinks
  ln -s pureos amber
  ln -s pureos green
  ln -s pureos landing
  ln -s pureos purple

  # Create Trisquel symlinks
  ln -s trisquel awen
  ln -s trisquel belenos
  ln -s trisquel brigantia
  ln -s trisquel dagda
  ln -s trisquel dwyn
  ln -s trisquel etiona
  ln -s trisquel flidas
  ln -s trisquel robur
  ln -s trisquel slaine
  ln -s trisquel taranis
  ln -s trisquel toutatis
}

package() {
  cd debootstrap-$pkgver
  make DESTDIR="$pkgdir" install

  install -Dm644 debootstrap.8 "$pkgdir"/usr/share/man/man8/debootstrap.8
}
