# Maintainer (Arch): Brian Bidulock <bidulock@openss7.org>
# Contributo (Arch): Jianhui Z <jianhui@outlook.com>
# Contributo (Arch): Tau Tsao <realturner at gmail.com>
# Contributor (Arch): Tomasz Zok <tomasz.zok [at] gmail.com>
# Contributor (Arch): techryda <techryda at silentdome dot com>
# Contributor (Arch): Mathias R. <pu154r@overlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=xrdp
pkgver=0.9.1
pkgrel=5
pkgdesc="An open source remote desktop protocol (RDP) server"
url="https://github.com/neutrinolabs/xrdp"
arch=('i686' 'x86_64' 'armv7h')
license=('Apache')
makedepends=('nasm')
depends=('tigervnc' 'libxrandr' 'lame' 'opus' 'fuse')
backup=('etc/xrdp/sesman.ini' 'etc/xrdp/xrdp.ini')
install="${pkgname}.install"
source=("https://github.com/neutrinolabs/xrdp/releases/download/v${pkgver}/xrdp-${pkgver}.tar.gz"
	"arch-config.diff")
md5sums=('111a3a3b7ea01eb62b08c698ab8f8bff'
         'b41c3d596a582d00e83cd55c756e9ee4')

prepare() {
  cd "${pkgname}-${pkgver}"
  patch -Np2 -b -z .orig <../arch-config.diff
  ./bootstrap
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
              --sysconfdir=/etc \
              --localstatedir=/var \
              --sbindir=/usr/bin \
              --with-systemdsystemunitdir=/usr/lib/systemd/system \
              --enable-jpeg \
              --enable-tjpeg \
              --enable-fuse \
	      --enable-opus \
	      --enable-rfxcodec \
	      --enable-mp3lame \
	      --enable-pixman
  make V=0
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
  rm -f "$pkgdir"/etc/xrdp/rsakeys.ini
  install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
}
