# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-privacy
pkgdesc="This package will remove support for protocols and services known to endanger privacy."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20210421
_gitver=6aacba7a7bba283f6feb38fe79bcae576ca6ae14
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver})
sha512sums=('5a09e43046a7447bf6f2219f5bfb0b84bf1a2506b58c65193e7dd2ef625729540e001e5c75a8979e43a7991d055a30f1dff7fcce70b4ff99cbcf3ad6c5a4e096')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}
