# Contributor: Daniel Milewski <niitotantei@riseup.net>

pkgname=smartypants
pkgver=1.5.1
pkgrel=2
pkgdesc='Smart punctuation for web sites'
arch=(any)
url=http://daringfireball.net/projects/smartypants/
license=(BSD3)
depends=(perl)
makedepends=(unzip)
source=(http://daringfireball.net/projects/downloads/SmartyPants_$pkgver.zip)
sha256sums=(2813a12d8dd23f091399195edd7965e130103e439e2a14f298b75b253616d531)

build() {
  cd "$srcdir/SmartyPants_$pkgver"

  pod2man SmartyPants.pl > smartypants.1
  sed -n '/^Copyright (c)/,/damage\./p' 'SmartyPants Readme.txt' > LICENSE
}

package() {
  cd "$srcdir/SmartyPants_$pkgver"

  install -Dm 755 SmartyPants.pl "$pkgdir/usr/bin/smartypants"
  install -Dm 644 smartypants.1 "$pkgdir/usr/share/man/man1/smartypants.1"
  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
