# $Id: PKGBUILD 212301 2014-05-12 12:04:49Z lcarlier $
# Maintainer: Laurent Carlier <lordheavym@gmail.com>
# Contributor: Fly-away <flyaaway@gmail.com>

_pkgname=libomxil-bellagio
pkgname=lib32-$_pkgname
pkgver=0.9.3
pkgrel=1
pkgdesc="An free implementation of the OpenMAX Integration Layer API"
arch=('x86_64')
url="http://omxil.sourceforge.net"
license=('LGPL')
depends=("$_pkgname" 'lib32-glibc')
source=("http://downloads.sourceforge.net/project/omxil/omxil/Bellagio%200.9.3/${_pkgname}-${pkgver}.tar.gz"
        fedora-fixes.patch)
md5sums=('a1de827fdb75c02c84e55f740ca27cb8'
         'c34f9facf0cf26171c81f2fc3d562ec6')

prepare() {
  cd ${srcdir}/${_pkgname}-$pkgver

  # Fixes from fedora repo
  patch -Np1 -i ../fedora-fixes.patch
  autoreconf -fiv
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd ${srcdir}/${_pkgname}-${pkgver}

  ./configure --prefix=/usr --disable-static --disable-doc --libdir=/usr/lib32
  make
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install

  # remove conflicting and unused files
  rm -vr "${pkgdir}"/usr/{bin,include,share}
}
