# $Id$
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

# parabola changes and rationale:
#  - remove libkvkontakte support for kipi-plugins

pkgbase=digikam
pkgname=(kipi-plugins)
_pkgver=5.9.0
pkgver=${_pkgver//-/_} # for beta versions
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="An advanced digital photo management application"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
url="http://www.digikam.org/"
makedepends=(extra-cmake-modules libkipi libksane liblqr opencv doxygen lensfun eigen boost kdoctools marble-common
             kfilemetadata akonadi-contacts qtav threadweaver kcalcore knotifyconfig libmediawiki libkvkontakte glu)
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${_pkgver}.tar.xz")
source+=("libre.patch" "nonprism.patch")
sha256sums=('660d32eedcfd6fe1a75170a651fab068ae62f7f092ae710771a2f32a1c550d1b'
            '80fbe434d326551f3dc029c5db3ad1b50e87870b03185467aa25a5c03764cc89'
            'e3d8ec4fd041a5545b7efef167d3b2ae6efc1f510832dabc7430ddfeb6b3c4ac')

prepare() {
  mkdir -p build

# fix freedom issues
  cd $pkgbase-$_pkgver
  patch -Np1 -i "$srcdir"/libre.patch
  patch -Np1 -i "$srcdir"/nonprism.patch
}

build() {
  cd build

  cmake ../$pkgbase-${_pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF \
    -DENABLE_KFILEMETADATASUPPORT=ON \
    -DENABLE_MEDIAPLAYER=ON \
    -DENABLE_AKONADICONTACTSUPPORT=ON \
    -DENABLE_MYSQLSUPPORT=ON \
    -DENABLE_OPENCV3=ON \
    -DENABLE_APPSTYLES=ON \
    -DENABLE_LEGACY=ON \
    -DDIGIKAMSC_COMPILE_LIBKVKONTAKTE=OFF
  make
}

package_kipi-plugins() {
  pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam"
  pkgdesc+=", without nonfree suggestions and support for unsafe and dangerous for privacy protocols"
  depends=(kio libkipi)
  optdepends=('libmediawiki: MediaWiki Export plugin')

  cd build/extra
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/po
  make DESTDIR="$pkgdir" install

# Provided by digikam
  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
}
