# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

_perlmod=Mail-SRS
pkgname=perl-${_perlmod,,}
pkgver=0.31
pkgrel=1
pkgdesc="Interface to Sender Rewriting Scheme (SRS)"
arch=('any')
url="http://search.cpan.org/dist/$_perlmod"
license=('GPL' 'PerlArtistic')
depends=('perl' 'perl-digest-hmac' 'perl-mldbm')
source=("http://cpan.perl.org/modules/by-module/${_perlmod%%-*}/$_perlmod-$pkgver.tar.gz")
md5sums=('1440999563a7b25d5fb03204b03e1060')

build() {
  cd "$srcdir/$_perlmod-$pkgver"

  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "$srcdir/$_perlmod-$pkgver"
  make test
}

package() {
  cd "$srcdir/$_perlmod-$pkgver"
  make install DESTDIR="$pkgdir/"
}

# vim:set ts=2 sw=2 et:
