# U-Boot: Wandboard
# Maintainer: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgname=uboot-wandboard
pkgver=2015.10
pkgrel=1.parabola1
pkgdesc="U-Boot for Wandboard"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
makedepends=('bc')
depends=('linux-libre')
replaces=('uboot-wandboard-solo' 'uboot-wandboard-dual' 'uboot-wandboard-quad' 'uboot-wandboard-linux-libre')
conflicts=('uboot4extlinux-wandboard' 'uboot4grub-wandboard')
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch')
md5sums=('7c203b0fc3390a122d8e8b75f147eac5'
         '87a2643750ab2152c6c91415e3949807')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}
  
  unset LDFLAGS
  
  make distclean
  make wandboard_defconfig
  make
}

package() {
  cd u-boot-${pkgver}

  mkdir -p "${pkgdir}"/boot
  cp SPL u-boot.img "${pkgdir}"/boot
}
