# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor (AUR): willemw <willemw12@gmail.com>
# Contributor (AUR): gnomeye <gnomeye at gmail dot com>

_name=ts

pkgname=task-spooler
pkgver=1.0
pkgrel=2

arch=('i686' 'x86_64' 'armv7h')
license=('GPL')

url="http://vicerveza.homeunix.net/~viric/soft/ts/"
pkgdesc="Queue up tasks from the shell for batch execution"

source=(http://vicerveza.homeunix.net/~viric/soft/$_name/$_name-$pkgver.tar.gz
        task-spooler-increase-queue-limit.patch)
sha256sums=('4f53e34fff0bb24caaa44cdf7598fd02f3e5fa7cacaea43fa0d081d03ffbb395'
            '858e0de406abb366f0d3c0fe91398e43344cbf1a461746d232a5ac53db5e0913')

prepare() {
  cd $_name-$pkgver

  patch -Np1 -i "$srcdir"/task-spooler-increase-queue-limit.patch
}

build() {
  cd $_name-$pkgver

  make
}

package() {
  cd $_name-$pkgver

  #make PREFIX="$pkgdir/" install
  install -Dm755 ts "$pkgdir/usr/bin/tsp"
  install -Dm644 ts.1 "$pkgdir/usr/share/man/man1/tsp.1"
}

