# Maintainer: bill-auger <bill-auger@programmer.net>
# Contributor (AUR): Wesley Moore <wes@wezm.net>

# parabola changes and rationale:
#   - replace images that are not clearly licensed


pkgname=tootle
pkgver=0.2.0
pkgrel=2
pkgdesc="GTK3 client for Mastodon federated services"
arch=('armv7h' 'x86_64' 'i686')
url=https://github.com/bleakgrey/tootle
license=('GPL3')

depends=('glib2' 'gtk3' 'hicolor-icon-theme' 'libsoup' 'granite' 'json-glib')
optdepends=('noto-fonts-emoji: color emoji')
makedepends=('git' 'desktop-file-utils' 'hicolor-icon-theme' 'intltool' 'yelp-tools' 'gnome-common' 'gobject-introspection' 'meson' 'ninja' 'vala')
options=('!libtool')
source=(https://github.com/bleakgrey/${pkgname}/archive/${pkgver}.tar.gz
        fix-build-on-vala-46.patch
        handle-unknown-message-types.patch
        tootle-horn-16.png tootle-horn-24.png tootle-horn-32.png tootle-horn-48.png
        tootle-horn-64.png tootle-horn-128.png tootle-horn-grey-128.png)
sha256sums=('e83c4a0539bf7b4b9d2b81d036ee0e8a69564b11c70f77ded5091955a89d2737'
            '5158d1e2019eaf6f4fa043b8483f8dfa049335d572a2563a0d4f71f799cae2b0'
            '6f28fe4169d5f596e3574fa717cc07c709659c653f6fee56fdfe370aa02d55c5'
            'd0f5575de5c73afc5b0db9c91c45762f4eb948b36b756bf45f5116cde91b42a8'
            '6c3533b2e795d478047d3df477109c85aaa8aa1389db42341ec770823d595502'
            '516b0358b6e9806c812331a8819567519cf54131566ca1450c251eced401eb11'
            '2414fd5bf4dd435420f863dcfbe59a9184b2d1325fd4638b2db1180076440e23'
            '9d8876aa02c3e4bdeb0c96f477aacd5f6eb7b9ddf5de0df62697e4b48a7b08d4'
            'bbd99b1209fd52b16a39ee94dca5538032f4eca8f66da18bed8acbfc74a7e1dc'
            'bc9a827d3d27e4ba394cd39c9e32b9a313a85254e47e54a71e8632b0c8ab2e5f')

prepare()
{
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -p1 < ../fix-build-on-vala-46.patch
  # FIXME: the program will crash if it gets any message of an unknown type
  #        there is a fix for this on the upstream master branch
  #          but it can not be back-ported onto release 0.2.0
  #        this patch is adapted from a rejected merge request:
  #          https://github.com/bleakgrey/tootle/pull/143
  patch -p1 < ../handle-unknown-message-types.patch

  sed -i "s|'\.svg'|'\.png'|" data/meson.build
  for dims in 16 24 32 48 64 128
  do  cp ${srcdir}/tootle-horn-${dims}.png data/icons/${dims}/com.github.bleakgrey.tootle.png
      rm                                   data/icons/${dims}/com.github.bleakgrey.tootle.svg
  done
  cp ${srcdir}/tootle-horn-grey-128.png    data/empty_state.png
  cp ${srcdir}/tootle-horn-128.png         data/logo128.png
  rm                                       data/screenshot*.png
}

build()
{
  cd "${srcdir}/${pkgname}-${pkgver}"

  arch-meson -Db_pie=false build
  ninja -C build
}

package()
{
  cd "${srcdir}/${pkgname}-${pkgver}"

  DESTDIR="${pkgdir}/" ninja -C build install

  ln -s /usr/bin/com.github.bleakgrey.tootle ${pkgdir}/usr/bin/tootle
}
