# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=parabola-wiki-docs
pkgdesc="Pages from Parabola Wiki optimized for offline browsing"
pkgver=20160605
_commit=98fa13fd57df6191fdae98065e0c713f3040a0e0
pkgrel=1
arch=('any')
url="https://notabug.org/ovruni/parabola-wiki-docs"
license=('FDL')
options=('!strip')
makedepends=('git' 'python' 'python-simplemediawiki' 'python-lxml' 'python-cssselect')
replaces=('arch-wiki-docs')
conflicts=('arch-wiki-docs')
source=("git+https://notabug.org/ovruni/parabola-wiki-docs.git#commit=${_commit}")
md5sums=('SKIP')

pkgver() {
  date "+%Y%m%d"
}

prepare() {
  cd "$pkgname"
  LANG=en_US.UTF-8 python parabola-wiki-docs.py --output-directory "$srcdir/build_wiki" --clean --safe-filenames
}

package() {
  install -dm755 "$pkgdir/usr/share/doc/parabola-wiki/html"
  cp -r "$srcdir"/build_wiki/* "$pkgdir/usr/share/doc/parabola-wiki/html/"
}