# Maintainer (AUR): Doug Newgard <scimmia22 at outlook dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

# parabola changes and rationale:
#  - fixed source url
#  - added makedepends: mesa (FIXME: this appears to be missing in depends of efl-1.20: https://bugs.archlinux.org/task/57351)

pkgname=econnman
pkgver=1.1
pkgrel=1.2
pkgdesc="Enlightenment ConnMan user interface"
arch=('any')
url="https://phab.enlightenment.org/w/projects/econnman/"
license=('LGPL3')
depends=('python-efl' 'connman')
makedepends=('mesa')
source=("http://download.enlightenment.org/rel/apps/$pkgname/$pkgname-$pkgver.tar.xz")
sha256sums=('0cce87681fae7ca70f1e63cfe0ae65fdf17bc334727054317e25e3897619ed85')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr

  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

# install text files
  install -d "$pkgdir/usr/share/doc/$pkgname/"
  install -m644 -t "$pkgdir/usr/share/doc/$pkgname/" AUTHORS ChangeLog NEWS README
}
