# Maintainer: Freemor <freemor@freemor.ca>
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@parabola.nu>

# Notes:
# - Does *NOT* provide a specific version of systemd; if a package
#   depends on a specific version, it probably is a "real" dependency,
#   not an erroneous one, and satisfying it would be harmful.
# - Does not conflicts=('systemd'); to make adding/removing notsystemd
#   easy.
# - Does not provide libsystemd-shared-XXX.so, nor depend on
#   (not)systemd-common, which provide it.  That is not a public API
#   or ABI, and no package outside of pkgbase=systemd cares about it.
#   It's absolutely silly that Artix Linux's systemd-dummy package
#   includes that file.
# - Does not do anything with libsystemd.so  We have more finely split
#   packages than Arch (systemd-libsystemd).
# - Sets epoch=1 to allow upgrading from Artix systemd-dummy, which
#   sets pkgver=$systemd_version

pkgbase=systemd-dummy
pkgname=(systemd-dummy systemd-libs-dummy)
pkgdesc='An empty package that provides '"'pkgname'"' to satisfy packages that erronously depend on it'
url='https://parabola.nu/'
license=('custom:Public Domain')
epoch=1
pkgver=1
pkgrel=1
arch=(any)

package_systemd-dummy() {
  pkgdesc="${pkgdesc/pkgname/${pkgname%-dummy}}"
  provides=(${pkgname%-dummy})
}

package_systemd-libs-dummy() {
  pkgdesc="${pkgdesc/pkgname/${pkgname%-dummy}}"
  depends=(libsystemd.so)
  provides=(libsystemd ${pkgname%-dummy})
  conflicts=(libsystemd-dummy)
  replaces=(${conflicts[@]})
}
