# Maintainer (aur): Brian Bidulock <bidulock@openss7.org>
# Contributor: Kalidarn

pkgname=freeradius-client
pkgver=1.1.7
pkgrel=2.1
pkgdesc="FreeRADIUS Client Software"
arch=('x86_64' 'i686' 'armv7h')
url="http://wiki.freeradius.org/Radiusclient"
license=('BSD')
#source=(ftp://ftp.freeradius.org/pub/radius/$pkgname-$pkgver.tar.bz2)
source=($pkgname-$pkgver.tar.gz::https://github.com/FreeRADIUS/freeradius-client/archive/release_${pkgver//./_}.tar.gz)
sha256sums=('5eb20eb0eb0c194ba2efeedbe00aa40fe3e774615bbb4d5814ba085cd1b26557')

build() {
  cd "$srcdir"/freeradius-client-release_${pkgver//./_}
  ./configure --prefix=/usr --sysconfdir=/etc --sbindir=/usr/bin
  make
}

package() {
  cd "$srcdir"/freeradius-client-release_${pkgver//./_}
  make DESTDIR="$pkgdir" install
  install -D -m0644 COPYRIGHT "$pkgdir"/usr/share/licenses/$pkgname/license
  mv "$pkgdir"/etc/radiusclient "$pkgdir"/etc/radiusclient.default
}
