# Maintainer (arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor: SolveFinder <kwopleq@proton.me>


# parabola changes and rationale:
# - disable DRM


pkgname=okular
pkgver=24.02.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Document Viewer'
pkgdesc+=', with copy-protection anti-feature disabled, without nonfree recommendations'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://apps.kde.org/okular/'
# license=(GPL-2.0-or-later LGPL-2.0-or-later) # TODO:
license=(GPL LGPL)
depends=(discount
         djvulibre
         freetype2
         gcc-libs
         glibc
         plasma-activities
         karchive
         kbookmarks
         kcolorscheme
         kcompletion
         kconfig
         kconfigwidgets
         kcoreaddons
         kcrash
         ki18n
         kio
         kitemviews
         kparts
         kpty
         ktextwidgets
         kwallet
         kwidgetsaddons
         kwindowsystem
         kxmlgui
         libjpeg-turbo
         libkexiv2
         libspectre
         libtiff
         phonon-qt6
         poppler-qt6
         purpose
         qt6-base
         qt6-declarative
         qt6-speech
         qt6-svg
         threadweaver
         zlib)
makedepends=(ebook-tools
             extra-cmake-modules
             kdegraphics-mobipocket
             kdoctools)
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support'
            'unarchiver: Comic Book Archive support')
groups=(kde-applications
        kde-graphics)
source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
source+=(disable-drm.patch)
sha256sums=('fc265548f859562c54cd40587ff3c6a1c2d0f7926617951b06e6145d1f42938c'
            'SKIP')
sha256sums+=('83cf760b3ae6e03d49e02369375dae3ecc05a6800d512dd9ffeaac1648c19457')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
options=(!zipman)

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver

  echo "applying disable-drm.patch"
  patch -Np1 -i "$srcdir"/disable-drm.patch
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
