# Maintainer (arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Johan Rehnberg <cleanrock@gmail.com>
# This package is in Parabola only for architectures that don't have xonotic in
# their feed. Here is the status of xonotic in the various upstream
# GNU/Linux distributions Parabola is based on:
# +--------------+----------------+---------------+
# | Architecture | Upstream       | Upstream repo |
# +--------------+----------------+---------------+
# | armv7h       | Arch Linux ARM | None          |
# | i686         | Arch Linux 32  | community     |
# | x86_64       | Arch Linux     | community     |
# +--------------+----------------+---------------+

pkgname=naev
pkgver=0.7.0
pkgrel=2
pkgdesc='2D action/rpg space game'
arch=('armv7h')
url="http://sourceforge.net/projects/naev/"
license=('GPL3')
depends=('glu' 'openal' 'libvorbis' 'sdl2' 'sdl2_image' 'sdl2_mixer' 'libgl' 'libxml2' 'freetype2' 'libpng' 'libzip' 'luajit')
makedepends=('freeglut' 'zip')
source=("https://github.com/naev/naev/archive/naev-${pkgver}.tar.gz")
md5sums=('c07e24c2e87d08fdb73e666fb4e59981')

build() {
  cd "$srcdir/$pkgname-$pkgname-$pkgver"

  ./autogen.sh
  ./configure --prefix=/usr --disable-debug --disable-shave --with-ndata-path=/usr/share/naev/ndata
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
}
