# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Christoph Zeiler <rabyteNOSPAM _at_ gmx.d0t.net>
# Contributor: Nathan Owe <ndowens04+AUR at gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=base91
pkgver=0.6.0
pkgrel=6
pkgdesc='An advanced method for encoding binary data to ASCII text'
arch=('i686' 'x86_64')
url='http://base91.sourceforge.net/'
license=('BSD')
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz")
sha512sums=('0785178bcf556c02c03dfb467eb936fa84d92f070827f05d356bca4e8558a2f73462228f157dc8242e31305d8a61bfbabf92706974fc3bbec21c4076adc0e37e')

build() {
	cd ${srcdir}/${pkgname}-${pkgver}

	sed -i '/^\(C\|LD\)FLAGS/s/=/+=/' Makefile
	make
}

package() {
	cd ${srcdir}/${pkgname}-${pkgver}

	make prefix='/usr' DESTDIR="${pkgdir}" install
	install -D -m0644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}