# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=wbar
pkgver=2.3.4
pkgrel=4
pkgdesc="Minimalist quick-launch tool"
arch=('i686' 'x86_64')
license=('GPL')
url=https://code.google.com/archive/p/wbar/

depends=('imlib2')
makedepends=('intltool' 'libglade')

source=(https://storage.googleapis.com/google-code-archive-downloads/v2/code.google.com/wbar/wbar-2.3.4.tgz
        wbar-dock.png
        remove_static_iterator.patch)
sha256sums=('46a69849e4436529aefb5cfb2c94b520d05a53c237e7773b90207f67f97a93e3'
            '902dbf06f596bf4453e60b5caa5f173cfc2644dd054e27b50b7e028d0968edd0'
            'c43d40965ef191ea41a4ee87ad71b7cc7459470f48424e2b82de0d67a8965b65')

_build_dir=${pkgname}-${pkgver}


prepare()
{
  cd ${srcdir}/${_build_dir}

  sed -i 's|AM_INIT_AUTOMAKE(\[\(.*\)\])|AM_INIT_AUTOMAKE(\[\1subdir-objects \])|' ./configure.ac
  sed -i 's|\$(top_srcdir)/src/||g'                                                ./src/Makefile.am
  sed -i 's|= PACKAGE_NAME" "DEFAULT_ARGV;|= PACKAGE_NAME " " DEFAULT_ARGV;|'      ./src/core/Main.cc
  sed -i 's|= PACKAGE_NAME" "DEFAULT_ARGV;|= PACKAGE_NAME " " DEFAULT_ARGV;|'      ./src/config/Functions.cc
  sed -i 's|("killall "PACKAGE_NAME)|("killall " PACKAGE_NAME)|'                   ./src/config/Run.cc
  sed -i 's| PIXMAPDIR"/"PACKAGE_NAME"| PIXMAPDIR "/" PACKAGE_NAME "|'             ./src/config/Functions.cc

  # FIXME
  # /usr/include/gtk-2.0/gtk/gtkfilechooserbutton.h:65:8: error: unnecessary parentheses in declaration of ‘__gtk_reserved7’ [-Werror=parentheses]
  # /usr/include/gtk-2.0/gtk/gtkstatusicon.h:76:8: error: unnecessary parentheses in declaration of ‘__gtk_reserved1’ [-Werror=parentheses]
  sed -i 's|-Werror \\|-Werror -Wno-error=parentheses \\|' ./src/Makefile.am

  patch -p1 < ${srcdir}/remove_static_iterator.patch
}

build()
{
  cd ${srcdir}/${_build_dir}

  autoreconf -fiv
  ./configure
  make
}

package()
{
  cd ${srcdir}/${_build_dir}

  make DESTDIR=${pkgdir} install

  install -d usr/share/pixmaps/wbar
  install -m 644 ${srcdir}/wbar-dock.png ${pkgdir}/usr/share/pixmaps/wbar/
}
