# SPDX-License-Identifier: CC0-1.0
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>


# NOTE: This PKGBUILD does not need to be edited manually.
#       The package is normally built automatically by the auto-builder.
#       To generate a new package, simply push changes to blacklist.git.
#       If ${pkgname}-blacklist.txt is modified, the auto-builder will
#       replace $pkgver, $_srcver, and the checksum (updpkgsums),
#       build and publish the package, and commit the changes to abslibre.


pkgname=your-gaming-freedom # TODO: change any references on the wiki
pkgver=20240212
pkgrel=1
_srcver=835dfa36db23f81dee00165d47d2ac1a95f9d71e
pkgdesc="This meta-package conflicts with emulators for which no libre games, OS or applications exist (yet)"
pkgdesc+=", and games with dubious free culture licensing" # TODO: why not right? - either this, or many games should be deleted
arch=(any)
url=https://wiki.parabola.nu/Blacklist
license=(custom:CCPL:zero)
# license=('CCPL:zero') # TODO: NYI

makedepends=(librelib)
install=${pkgname}.install
_srcname=${pkgname}-blacklist-${_srcver}.txt
source=(${_srcname}::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_srcver})

sha256sums=('a4dc17bb0a8654c0bc1118831469f52d48cb33021870a37194e3b39ec8b3b9ad')


package()
{
  # collect blacklisted package names as pacman conflicts
  conflicts=( $( libreblacklist normalize < ${_srcname}     | \
                 cut -d: -f1,2 | sed -n 's/:$//p' | sort -u ) )

  install -Dm644 ${_srcname} "${pkgdir}"/usr/share/doc/${pkgname}/blacklist.txt
}
