# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (aur): Xiao-Long Chen <chenxiaolong@cxl.epac.to>
# Rationale: Build dependency of apache-ant

pkgname=jakarta-oro
pkgver=2.0.8
pkgrel=1.2
pkgdesc="Java regular expression and text-processing library"
arch=('any')
url="https://jakarta.apache.org/oro"
license=('Apache')
makedepends=('apache-ant')
source=("http://archive.apache.org/dist/jakarta/oro/${pkgname}-${pkgver}.tar.gz")
sha512sums=('a7f6eb6a088765f273df18ccc823f918737f18ec8772275054839a87f8370f1848e795d481f226c712651104d7598ab86c7d90a991fb039df6581f42f1447920')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  find . \( -name '*.jar' -o -name '*.class' \) -delete
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ant jar
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  install -Dm644 ${pkgname}-${pkgver}.jar \
    "${pkgdir}/usr/share/java/${pkgname}.jar"
}
