# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_libname=jline
pkgname=java-${_libname}
pkgver=1.0
pkgrel=3.parabola1
pkgdesc="Java library for handling console input"
arch=('any')
url="http://jline.sourceforge.net/"
license=('BSD')
depends=('java-runtime-headless')
makedepends=('apache-ant' 'jh' 'junit')
source=("http://downloads.sourceforge.net/project/${_libname}/${_libname}/${pkgver}/${_libname}-${pkgver}.zip"
        "http://repo.maven.apache.org/maven2/${_libname}/${_libname}/${pkgver}/${_libname}-${pkgver}.pom"
        "build.xml")
md5sums=('811dc1c8a351a2e928524bd79eb9e798'
         'b45424a0b2557589f2f3eddae5fc4944'
         '6d198263612535fe617c6d166200c08d')

prepare() {
  cd "${srcdir}/${_libname}-${pkgver}"
  rm -v "${_libname}-${pkgver}.jar"
  mv "${srcdir}/build.xml" .
}

build() {
  cd "${srcdir}/${_libname}-${pkgver}"

  ant clean jar javadoc
}

package() {
  cd "${srcdir}/${_libname}-${pkgver}"

  # Install license file
  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"

  # Install documentation
  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r "api" "${pkgdir}/usr/share/doc/${pkgname}"

  # Install Maven artifacts
  export DESTDIR=${pkgdir}
  jh mvn-install ${_libname} ${_libname} ${pkgver} \
    "${srcdir}/${_libname}-${pkgver}.pom" \
    "${_libname}.jar" \
    "${_libname}.jar"

  ln -s "/usr/share/java/${_libname}.jar" \
    "${pkgdir}/usr/share/java/${_libname}-${pkgver}.jar"
}
