# Maintainer (arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: Iván Ávalos <avalos at disroot.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>


# parabola changes and rationale:
#  - rebranded to parabola
#  - switched default searchengine to duckduckgo
#  - removed useless dependency on icu because it's not
#    used at runtime according to readelf -d
#  - pin to sodeps
#  - disabled tests by default (require networking)


pkgname=epiphany
pkgver=43.1
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(
  gcr
  icu
  libarchive
  libdazzle
  libhandy
  libportal-gtk3
  libsoup3
  webkit2gtk-4.1
)
depends=( ${depends[*]/icu/} )
depends+=(libhogweed.so)
makedepends=(
  docbook-xml
  git
  gobject-introspection
  lsb-release
  meson
  startup-notification
  yelp-tools
)
checkdepends=(
  aspell
  hspell
  hunspell
  libvoikko
  nuspell
  xorg-server-xvfb
)
groups=(gnome)
_commit=e21c2e68f34fcf23ca560088479e13c9929a4c36  # tags/43.1^0
source=(
  "git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit"
  fix-test.diff
)
source+=(libre.patch)
b2sums=('SKIP'
        '05121ff5f759ec637a718c9b39406f9a384227a312d69f6dc74e73fde8351689d588a30dddea3cfe0a6edb094fdcf5382eb5ff725bb2adfccdff87ab3cf4c953')
b2sums+=('203dcf6e532aa4778662aab6ec7e4628d5ed05d4e22a3be5cf80ec9bc17610b650a4b8c2bed66337213aa2bf6a3ee7966f972aa2422571d75caf2f4ba792c6c8')


_DISABLE_TESTS=1 # check() requires networking


pkgver() {
  cd epiphany
  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}

prepare() {
  cd epiphany

  # Fix encoding test; perhaps caused by different glibc or locale env
  # https://gitlab.gnome.org/GNOME/epiphany/-/issues/1842
  git apply -3 ../fix-test.diff

  echo "applying libre.patch"
  patch -Np1 -i ../libre.patch
}

build() {
  arch-meson epiphany build
  meson compile -C build
}

check() {
  (( ! _DISABLE_TESTS )) || ! echo "skipping check()" || return 0

  dbus-run-session xvfb-run -s '-nolisten local' \
    meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}
