# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (aur): Simon Hanna <simon dot hanna AT serve-me DOT info>

pkgname=('python2-django-hyperkitty')
pkgver=1.2.1
pkgrel=1
pkgdesc="A Django app that provides a web user interface to access GNU Mailman archives"
arch=(any)
url=https://gitlab.com/mailman/hyperkitty
license=('GPL')
options=(!emptydirs)

makedepends=('python2-setuptools')
depends=('python2-mailmanclient' 'python2-django-crispy-forms' 'python2-django-rest-framework'
         'python2-social-auth' 'python2-django-gravatar' 'python2-django-paintstore'
         'python2-django-compressor' 'python2-django-browserid' 'python2-django-haystack'
         'python2-pytz' 'python2-dateutil' 'python2-enum34' 'python2-networkx'
         'python2-robot-detection' 'python2-django-extensions' 'sassc')

_upstream_name='hyperkitty'
_release="${_upstream_name}-v${pkgver}"
source=(https://gitlab.com/mailman/${_upstream_name}/-/archive/v${pkgver}/${_release}.tar.gz)
sha256sums=('b5d0064a2af3f36b055f7aa07f6f0828776d3437357ecb2e9b7d5d4e5bbceaf9')


package()
{
  cd "$srcdir/${_release}"

  python2 setup.py install --root="$pkgdir/" --optimize=1
}
