# Maintainer (aur):  Esben Haabendal <esben@haabendal.dk>
# Maintainer: Aurélien Desbrières <aurelien@cwb.io>

# parabola changes and rationale:
#  - added replaces for previous pkgname 'emacs-magit-git' (2018-02-02)

pkgname=emacs-magit
pkgver=2.11.0
pkgrel=1
pkgdesc="It's Magit! A Emacs mode for Git."
arch=('any')
_github_org="magit"
_github_repo="magit"
url="http://github.com/${_github_org}/${_github_repo}"
license=('GPL3')
depends=('emacs' 'git' 'emacs-dash>=2.13.0' 'emacs-with-editor-git>=2.6.0')
provides=('emacs-magit' 'emacs-magit-popup')
conflicts=('emacs-magit-git' 'emacs-magit-popup')
replaces=('emacs-magit-git')
install="${pkgname}.install"
source=("git+https://github.com/${_github_org}/${_github_repo}.git#tag=$pkgver")
md5sums=('SKIP')

build() {
  cd "$srcdir/${_github_repo}"
  make LOAD_PATH="-L /usr/share/emacs/site-lisp -L /usr/share/emacs/site-lisp/dash -L ${srcdir}/magit/lisp" \
       lisp docs
}

package() {
  cd "$srcdir/${_github_repo}"
  make PREFIX="/usr" DESTDIR="${pkgdir}" install
}
