# Maintainer (arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (arch): Charles Mauch <cmauch@gmail.com>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=perl-algorithm-diff
pkgver=1.1903
pkgrel=5
pkgrel+=.parabola1
pkgdesc="Perl/CPAN Module Algorithm::Diff : Diff also Longest Common Subsequence"
pkgdesc+=", without unlicensed files"
arch=("any")
url="https://search.cpan.org/dist/Algorithm-Diff"
license=("GPL" "PerlArtistic")
depends=(perl)
source=("https://search.cpan.org/CPAN/authors/id/T/TY/TYEMQ/Algorithm-Diff-${pkgver}.tar.gz")
sha256sums=('30e84ac4b31d40b66293f7b1221331c5a50561a39d580d85004d9c1fff991751')

prepare() {
  rm -rv "Algorithm-Diff-${pkgver}"/{htmldiff.pl,lib/Algorithm/DiffOld.pm,t}
}

build() {
  cd "$srcdir"/Algorithm-Diff-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd "$srcdir"/Algorithm-Diff-$pkgver
  make pure_install doc_install DESTDIR="$pkgdir"
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name '*.pod' -delete
}
