# Maintainer (arch): David Runge <dvzrv@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Asa Marco <marcoasa90[at]gmail[.]com>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Freemor <freemor@freemor.ca>

# parabola changes and rationale:
#  - removed faac recommendation and youtube upload support
#  - neuter google analytics and exception tracking as it all happens over http

pkgname=openshot
pkgver=2.5.1
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="An award-winning free and open-source video editor"
pkgdesc+=", without nonfree faac recommendation and Youtube uploader support"
arch=('any')
url="https://www.openshot.org/"
license=('GPL3')
depends=('ffmpeg' 'mlt' 'python-pyqt5' 'python-requests' 'libopenshot'
'libopenshot-audio' 'python-pyzmq' 'qt5-base' 'qt5-svg' 'qt5-webkit')
makedepends=('python-setuptools')
source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenShot/openshot-qt/archive/v$pkgver.tar.gz")
source+=('nonprism.patch'
         'neuter_tracking.patch')
sha256sums=('4c25eb9a5de42e749de4c6ca2f7a313c60e1283fe52d70c121629dbb8bb2df7b'
            'b7fea3b32dd1666403caab7ff70c59cbdedceee8d3180b7a8878ee239a67623d'
            '138260661ca9cd1b2bb62556a2e718d0f95e3bf02a92451e39cba5e958ef7ef8')

prepare() {
  mv -v "${pkgname}-qt-${pkgver}" "${pkgname}-${pkgver}"

  cd "${pkgname}-${pkgver}"
  patch -Np1 -i $srcdir/nonprism.patch
  patch -Np1 -i $srcdir/neuter_tracking.patch
}

build() {
  cd "${pkgname}-${pkgver}"
  python setup.py build
}

package() {
  cd "${pkgname}-${pkgver}"
  python setup.py install --skip-build \
                          --optimize=1 \
                          --prefix=/usr \
                          --root="${pkgdir}"
  install -vDm 644 {AUTHORS,{CONTRIBUTING,README}.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}
