# Maintainer (arch): Mike Swanson <mikeonthecomputer@gmail.com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=deutex
pkgver=5.1.1
pkgrel=1
pkgdesc="Composer and decomposer for Doom, Heretic, Hexen, Strife WAD files"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/Doom-Utils/deutex"
license=('custom')
depends=('libpng')
makedepends=('asciidoc')
conflicts=('deutex-devel-git')
source=($url/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz{,.sig})
sha512sums=('a6af2b16d9f3ad4da0bee2ede4cbc71902b935af7055aec9f198d5af6de371adb1a401a8f12309eac4fdd80fd9dc36873ef45e12db95c9b18908c8aed3a5adc6'
            'SKIP')
validpgpkeys=('99459CE2770037FF5566EB4B8649B37607A08042')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
  install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
