# Contributor: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Figue <ffigue at gmail>
# Contributor: Figue <ffigue at gmail>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: vando <facundo@esdebian.org>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com>

pkgname=mozilla-searchplugins
pkgver=2
pkgrel=4
pkgdesc="System-wide OpenSearch plugins common for Mozilla based browsers."
arch=('any')
license=('MPL' 'GPL' 'LGPL')
url="https://www.parabola.nu/"
source=(
  searx.json searx.ico
  duckduckgo-html.json duckduckgo-html.ico
  duckduckgo-lite.json duckduckgo-lite.ico
  internet-archive.json internet-archive.ico
  parabola-packages.json parabola-packages.ico
  parabola-wiki.json parabola-wiki.ico
  yacy.json yacy.ico)

package() {
  for d in searx duckduckgo-{html,lite} internet-archive parabola-{packages,wiki} yacy; do
    install -m755 -d                 "$pkgdir/usr/share/mozilla/searchplugins/$d"
    install -m644 "$srcdir/$d.json"  "$pkgdir/usr/share/mozilla/searchplugins/$d/manifest.json"
    install -m644 "$srcdir/$d.ico"   "$pkgdir/usr/share/mozilla/searchplugins/$d/favicon.ico"
  done
}

sha256sums=('2c1323676dd6633a3a813e3d29f899a234df385990e8e31a224c184f0171caad'
            '57940b86f10b3c2e341fbaf5ddd7707e2b5ae418ccd17f9976f02f321895a1cd'
            'b8078c5c61df0851aad5ae9e418a1ff2cf8e359bf86e648078d39413b09ce46c'
            '3ec69a44bd0df1b1e6da6a2a7ec8a5aa53cfc6a3149841c52aeefeb61f5ba923'
            '94cb076c272e34b5772e6df4f5df1ff8f4cc5f13d556b5d9cf73d0d981b66782'
            '3ec69a44bd0df1b1e6da6a2a7ec8a5aa53cfc6a3149841c52aeefeb61f5ba923'
            '0d42fbe6dc41ed00b7b7295539f530412954633ad3d50b3744d0e91fd684b1c1'
            'abac83a6e6813515818512cbe6b8714820e43471ac10dd997023dab93cd6aeca'
            'd549273e31e51399e32b4f39b46e7c019384c9cab214c49c1f290f51c5d1e56b'
            '96a64ce3e91e88a6b890edf752df08246a51284e6250d53276fa3e0bbab2f667'
            '5b4e493fb0a80e7e414bda1b37b7d3a1d14cf59b72ce1aa4984812f39184dc2d'
            '735b8ef017b33b8017af0ee3253fe78f523ccf3144b1f1deaee17a4f6cb0bde4'
            '519864cf9e828e97400ab4ccc165c1115f12c567865dc1b008d857af73a1cfa4'
            '6236c83242b32ff1f9ad38eaab32617216228474818419413d3535b4dfaa4729')
