# $id$
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>

pkgname=liblms7002m
pkgver=r8.g91b5107
pkgrel=2
pkgdesc="Compact LMS7002 library suitable for MCU"
url="https://github.com/xtrx-sdr/liblms7002m"
arch=('armv7h' 'i686' 'x86_64')
license=('LGPL')
depends=('python2-cheetah')
makedepends=('git' 'cmake')
commit=91b5107a11eb5335bbaf02ac0c744ea58d2a0b74
source=("git://github.com/xtrx-sdr/liblms7002m#commit=$commit")
sha512sums=('SKIP')

pkgver() {
    cd $pkgname
    echo r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)
}

build() {
    case "$CARCH" in
	i686) ARCH=i386;;
	x86_64) ARCH=x86_64;;
	arhmv7h) ARCH=armhf;;
    esac

    cd "$srcdir/$pkgname"
    mkdir -p build
    cd build

    cmake \
	-DFORCE_ARCH=$ARCH \
	-DPYTHON_EXECUTABLE=/usr/bin/python2 \
	-DCMAKE_INSTALL_PREFIX=/usr \
	../
    make
}

package() {
    cd "$srcdir/$pkgname/build/"
    make DESTDIR="${pkgdir}" install
}
