# Maintainer (aur): Bill Sun <cap.sensitive at gmail dot com>
# Contributer (AUR): Jamie Nguyen <jamie at tomoyolinux dot co dot uk>
# Maintainer: Aurélien DESBRIERES <aurelien@hackers.camp>

# parabola changes and rationale:
#  no changes.

pkgname=bashmount
pkgver=3.2.0
pkgrel=2

pkgdesc="A menu-driven bash script for the management of removable media with udisks."
arch=('any')
url='https://github.com/jamielinux/bashmount'
license=('GPL2')

optdepends=('udisks2')
backup=(etc/bashmount.conf)
source=("https://github.com/jamielinux/${pkgname}/archive/${pkgver}.tar.gz")

package()
{
    cd "${srcdir}/${pkgname}-${pkgver}"

    # Install script
    install -D -m755 bashmount "${pkgdir}/usr/bin/bashmount"

    # Install config file
    install -D -m644 bashmount.conf "${pkgdir}/etc/bashmount.conf"

    # install man page
    gzip -c -9 bashmount.1 > bashmount.1.gz
    install -D -m644 bashmount.1.gz "${pkgdir}/usr/share/man/man1/bashmount.1.gz"

    # Install documentation
    install -d -m755 "${pkgdir}/usr/share/doc/bashmount"
    # Currently the source code doesn't have an 'AUTHORS' file
    #install -m644 AUTHORS "${pkgdir}/usr/share/doc/bashmount/AUTHORS"
    install -m644 COPYING "${pkgdir}/usr/share/doc/bashmount/COPYING"
    install -m644 NEWS "${pkgdir}/usr/share/doc/bashmount/NEWS"
}

sha256sums=('32f328e1921f60b429e2ab389ecc314f5bd7545ac4385c7c7918d08ebe9ecc22')
