# SPDX-License-Identifier: CC0-1.0
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>


# NOTE: This PKGBUILD does not need to be edited manually.
#       The package is normally built automatically by the auto-builder.
#       To generate a new package, simply push changes to blacklist.git.
#       If ${pkgname}-blacklist.txt is modified, the auto-builder will
#       replace $pkgver, $_srcver, and the checksum (updpkgsums),
#       build and publish the package, and commit the changes to abslibre.


pkgname=your-init-freedom
pkgver=20221021
pkgrel=1
_srcver=249a8e38967abf9243252f03a4b33100cd636dbb
pkgdesc="This meta-package conflicts with every package which strictly requires systemd"
arch=(any)
url=https://wiki.parabola.nu/Blacklist
license=(custom:CCPL:zero)
# license=('CCPL:zero') # TODO: NYI

replaces=(your-initfreedom)

makedepends=(librelib)
install=${pkgname}.install
_srcname=${pkgname}-blacklist-${_srcver}.txt
source=(${_srcname}::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_srcver})

sha256sums=('6dbe07d8f0fe38d90a1b6811ecfd2543f4638a94a36954256d3b6d1432768891')


package()
{
  # collect blacklisted package names as pacman conflicts
  conflicts=( $( libreblacklist normalize < ${_srcname}     | \
                 cut -d: -f1,2 | sed -n 's/:$//p' | sort -u ) )

  install -Dm644 ${_srcname} "${pkgdir}"/usr/share/doc/${pkgname}/blacklist.txt
}
