# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer (aur): John D Jones III <jnbek1972@gmail.com>

# NB: This package is affected by a makepkg bug (in a non-critical
# way).  I'm choosing to just wait for makepkg to get fixed, rather
# than writing a work-around.  https://bugs.archlinux.org/task/53770

_perlmod=MLDBM
pkgname=perl-${_perlmod,,}
pkgver=2.05
pkgrel=1
pkgdesc="Store multi-level Perl hash structure in single level tied hash"
arch=('any')
license=('GPL' 'PerlArtistic')
depends=('perl')
options=('!emptydirs')
url="http://search.cpan.org/dist/$_perlmod"
source=("http://cpan.perl.org/modules/by-module/${_perlmod%%-*}/$_perlmod-$pkgver.tar.gz")
md5sums=('9b7ec37bfc36b0e83db9323be92beb50')

build() {
  cd "$srcdir/$_perlmod-$pkgver"

  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

check() {
  cd "$srcdir/$_perlmod-$pkgver"
  make test
}

package() {
  cd "$srcdir/$_perlmod-$pkgver"
  make install DESTDIR="$pkgdir"
}

# vim:set ts=2 sw=2 et:
