# Maintainer (arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Aaron Schaefer <aaron@elasticdog.com>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale:
#  - removing recommendations for python2-boto python2-dropbox and python2-gdata

pkgname=duplicity
pkgver=0.7.15
pkgrel=1.nonprism1
pkgdesc='A utility for encrypted, bandwidth-efficient backups using the rsync algorithm, without python2-boto, python2-dropbox and python2-gdata recommendation'
arch=('x86_64' 'i686' 'armv7h')
url='http://www.nongnu.org/duplicity/'
license=('GPL')
depends=('gnupg' 'librsync' 'ncftp' 'python2-paramiko' 'python2-fasteners')
makedepends=('python2-setuptools')
optdepends=('lftp: FTPS backend'
            'python2-gobject: GIO backend'
            'gvfs: GIO backend'
            'rsync: rsync backend')
source=("https://launchpad.net/$pkgname/0.7-series/${pkgver}/+download/$pkgname-$pkgver.tar.gz"{,.sig})
md5sums=('d106f93627973026707fdcaf37a578bd'
         'SKIP')
validpgpkeys=('9D95920CED4A8D5F8B086A9F8B6F8FF4E654E600')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # python2 fix
  for file in $(find . -name '*.py' -print); do
    sed -i 's_^#!.*/usr/bin/python$_#!/usr/bin/python2_' $file
    sed -i 's_^#!.*/usr/bin/env.*python$_#!/usr/bin/env python2_' $file
  done
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  python2 setup.py install --root="$pkgdir" --optimize=1

  # fix broken documentation permissions until upstream does (FS#27301)
  chmod 644 "$pkgdir/usr/share/man/man1/$pkgname.1"
  chmod 644 "$pkgdir/usr/share/man/man1/rdiffdir.1"
  chmod 644 "$pkgdir/usr/share/doc/$pkgname-$pkgver"/*
}
