# Maintainer: bill-auger <bill-auger@programmer.net>


# NOTE: there is not much point in diffing this against the AUR package
#       the AUR package is very convoluted, uses vendored libs, and builds from VCS;
#       so i re-wrote it from scratch according to the upstream guide
#       this recipe is nice and simple


pkgname=quaternion
pkgver=0.0.96
pkgrel=1
pkgdesc="Qt5 Matrix client, with IRC/hexchat-like GUI"
arch=(aarch64 armv7h i686 x86_64)
url=https://matrix.org/docs/projects/client/quaternion.html
license=(GPL3)

depends=(libquotient qt5-multimedia qt5-quickcontrols2 qt5-tools)
makedepends=(cmake)
optdepends=(qtkeychain-qt5)

source=(${pkgname}-${pkgver}.tar.gz::https://github.com/quotient-im/${pkgname^}/archive/refs/tags/${pkgver}.tar.gz)
sha256sums=(39868fbae40c36ebcd1a955cb65e953c4a1b9b74e9c1b9e2c838a0ce77ce5ac0)


build()
{
  cd "${srcdir}"/${pkgname^}-${pkgver} ; mkdir build ; cd build ;

  cmake ..                          \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DCMAKE_INSTALL_PREFIX=/usr     \
    -DCMAKE_BUILD_TYPE=Release      \
    -DBUILD_SHARED_LIBS=ON          \
    -DUSE_INTREE_LIBQMC=OFF         \
    -DBUILD_WITH_QT6=OFF
  cmake --build . --target all
}

package()
{
  cd "${srcdir}"/${pkgname^}-${pkgver}

  DESTDIR="$pkgdir" cmake --install build
}
