# Maintainer: Michał Masłowski  <mtjm@mtjm.eu>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=mozilla-devscripts
pkgver=0.32
pkgrel=1
pkgdesc="Development scripts used by Debian Mozilla's addons packages"
arch=("any")
url="http://packages.debian.org/source/unstable/mozilla-devscripts"
license=('GPL' 'custom')
depends=("python2" "zip" "unzip")
_debrepo=http://ftp.debian.org/debian/pool/main/
source=("${_debrepo}/m/${pkgname}/${pkgname}_${pkgver}.dsc"
        "${_debrepo}/m/${pkgname}/${pkgname}_${pkgver}.tar.gz")
md5sums=("386a5854601f29dca4a293f90f6c2a69"
         "230126afa15fa654eb254bb4e61b4a93")

build() {
  cd "$srcdir/$pkgname-$pkgver"
  # Adapt it to Arch's Python naming.
  find . -type f | xargs -L1 sed -i "s:#!/usr/bin/python:#!/usr/bin/python2:"
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  # The Makefile expects the system to have standard Python name, so
  # do this directly here.
  python2 setup.py install --root="$pkgdir/"
  install -Dm644 debian/copyright "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
}

# vim:set ts=2 sw=2 et:
