# Maintainer: Andreas Grapentin <oaken-source@parabola.nu>

_pkgname=habanero
pkgname=(python{,2}-$_pkgname)
pkgver=0.6.2
pkgrel=2
pkgdesc="Low Level Client for Crossref Search API"
arch=(any)
url="https://pypi.python.org/pypi/$_pkgname"
license=('MIT')

_depends=()
makedepends=(python{,2}-setuptools)
source=("https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
md5sums=('ecb477732b495dabe286b58e792b174d')

_package() {
  depends=("$1" "${_depends[@]/#/$1-}")
  cd "$srcdir"/$_pkgname-$pkgver
  $1 setup.py install --root="$pkgdir"
}

for _pkg in "${pkgname[@]}"; do
  eval "package_$_pkg () { _package ${_pkg%%-*}; }"
done
