# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer (aur): Mark Foxwell <fastfret79@archlinux.org.uk>
# Contributor: Nicolas Martyanoff <khaelin@gmail.com>
# Contributor: Rick Chen <stuffcorpse@archlinux.us>


# parabola changes and rationale:
# * no significant changes
# * this is in [libre] because it is a dependency of 'libretools'


pkgname=tokyocabinet
pkgver=1.4.48
pkgrel=5
pkgdesc="a modern implementation of DBM"
arch=('i686' 'x86_64' 'armv7h')
url="http://fallabs.com/tokyocabinet/"
license=('LGPL')
depends=('zlib' 'bzip2')
source=("http://fallabs.com/tokyocabinet/${pkgname}-${pkgver}.tar.gz")
sha256sums=('a003f47c39a91e22d76bc4fe68b9b3de0f38851b160bbb1ca07a4f6441de1f90')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  [ "$CARCH" == "armv7h" ] && sed -i "s/-minline-all-stringops//g" configure
  ./configure --prefix=/usr --enable-off64 --enable-fastest
  make
}

check() {
  cd "$srcdir/$pkgname-$pkgver"
  make check
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
}
