# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Artix): Artoo <artoo@artixlinux.org>
# Contributor (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Eli Schwartz <eschwartz@archlinux.org>

# NOTE: Since Artix has multiple inits, they install ALPM hooks for
#       auto-detecting and setting the correct /usr/bin/init binary.
#       I've plans to add these to [nonsystemd] in the future.
#       Meanwhile, this package will set the default init to openrc-init.

#_v=1.1
#_url=https://gitea.artixlinux.org/artix/alpm-hooks

pkgname=base
pkgver=3
pkgrel=1.parabola1.nonsystemd1
pkgdesc='Minimal package set to define a basic Parabola GNU/Linux-libre installation'
url='https://www.parabola.nu'
arch=('x86_64' 'i686' 'armv7h')
license=('GPL')
optdepends=('linux-libre: bare metal support')
#source=("alpm-hooks-$_v.tar.gz::$_url/archive/$_v.tar.gz")
#sha256sums=('6d08e6853a7b66f5bcfb5df9c37428f410981ed8ca52f65e2923f8f74276f327')

package() {
    depends=(
      # very very base
      'filesystem' 'gcc-libs' 'glibc' 'bash'

      # POSIX tools
      'coreutils' 'file' 'findutils' 'gawk' 'grep' 'procps-ng' 'sed' 'tar'

      # standard linux toolset
      'gettext' 'pciutils' 'psmisc' 'shadow' 'util-linux' 'bzip2' 'gzip' 'xz'

      # distro defined requirements
      'licenses' 'pacman' 'parabola-keyring' 'init-logind' 'esysusers' 'etmpfiles'
      'your-freedom' 'your-init-freedom'

      # networking, ping, etc
      'iputils' 'iproute2'
    )
    depends_x86_64=('archlinux-keyring')
    depends_i686=('archlinux32-keyring')
    depends_armv7h=('archlinuxarm-keyring')

    # pacman hooks
    #make -C alpm-hooks DESTDIR="${pkgdir}" install_base

    # provide default symlink for PM file tracking
    install -d "${pkgdir}"/usr/bin
    ln -svf openrc-init "${pkgdir}"/usr/bin/init
}

# vim: ts=2 sw=2 et:
