# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (aur): Simon Hanna <simon dot hanna AT serve-me DOT info>
# Contributor: Jakob Gahde <j5lx@fmail.co.uk>

pkgbase='django-allauth'
pkgname=('python-django-allauth' 'python2-django-allauth')
pkgver=0.37.0
pkgrel=1
pkgdesc="Integrated set of Django applications addressing authentication, registration, account management as well as 3rd party (social) account authentication."
arch=('any')
license=('MIT')
url=http://www.intenct.nl/projects/django-allauth/

makedepends=('python-setuptools' 'python2-setuptools')

source=(https://github.com/pennersr/${pkgbase}/archive/${pkgver}.tar.gz)
sha256sums=('3d526573d0f3463506c605224a9bb444cdf0ad2e7118206a8e8cf9af6489efc3')


package_python-django-allauth()
{
  depends=('python' 'python-django>=1.11' 'python2-openid' 'python-requests-oauthlib>=0.3.0'
           'python-requests')

  cd "${srcdir}/${pkgbase}-${pkgver}"

  python setup.py install --root="${pkgdir}" -O1

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

package_python2-django-allauth()
{
  depends=('python2' 'python2-django>=1.10' 'python2-openid'
           'python2-requests-oauthlib' 'python2-requests')

  cd "${srcdir}/${pkgbase}-${pkgver}"

  python2 setup.py install --root="${pkgdir}" -O1

  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
