# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

_pkgname=django-jinja
pkgname=(python-$_pkgname python2-$_pkgname)
pkgver=1.3.3
pkgdesc="Simple and nonobstructive jinja2 integration with Django"
url="https://niwibe.github.io/django-jinja/"
license=('custom:BSD3')

pkgrel=2
arch=(any)
makedepends=(python{,2}-{django,jinja,setuptools})
source=(https://files.pythonhosted.org/packages/76/c0/a38626bbf66ed2f2cadbb40c6436986110647dc410df27abdfd0decb99a8/django-jinja-1.3.3.tar.gz)
sha256sums=('df0d5c2deabc33375f288c7ab5462e06c6ecd824ecfa27bfa8bcd5e4ccfb372a')

package_python-django-jinja() {
  depends=(python-{django,jinja})

  cd "$srcdir/$_pkgname-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_python2-django-jinja() {
  depends=(python2-{django,jinja})

  cd "$srcdir/$_pkgname-$pkgver"
  python2 setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
