# Contributor: Georg Bremer <pkgbuild@dschoordsch.de>
# Maintainer: Aurélien Desbrières <aurelien@hackers.camp>

_pkgname=vcstools
pkgname=(python{,2}-$_pkgname)
pkgver=0.1.40
pkgrel=1
pkgdesc='API for interacting with different version control systems (VCS/SCMs)'
arch=(any)
url="http://ros.org/"
license=('BSD3')

makedepends=(python{,2}-setuptools)
source=("https://files.pythonhosted.org/packages/source/v/vcstools/$_pkgname-$pkgver.tar.gz")
sha256sums=('95586ab5a8dc02cd52074d88c4c8ecd20dfbaacaf4078b4c7ac1cf706ed4cad5')

_package() {
  depends=($1 $1-yaml)
  cd "$srcdir"/$_pkgname-$pkgver
  $1 setup.py install --root="$pkgdir"
}

for _pkg in "${pkgname[@]}"; do
  eval "package_$_pkg () { _package ${_pkg%%-*}; }"
done
