# Maintainer: David P. <megver83@hyperbola.info>

# parabola changes and rationale:
#  - removed python2 split package because upstream dependencies are gone

pkgbase=python-pypump
pkgname=('python-pypump')
pkgver=0.7
pkgrel=2
arch=('any')
license=('GPL3')
pkgdesc="Python pump.io library"
url="https://github.com/xray7224/PyPump"
makedepends=('python-setuptools')
checkdepends=('python-dateutil' 'python-requests' 'python-requests-oauthlib')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/xray7224/PyPump/archive/v$pkgver.tar.gz")
sha512sums=('3906118f681dd886bd8e3d57a49f66a0bc4236fe526d8137905ea8f7fd9bc9fea61a5646ca6e6617095fab62ab3ce91f2ea7d2c5e150125f399048c2f8831e86')

prepare() {
  mv PyPump-$pkgver pypump-$pkgver
}

build() {
  cd "$srcdir"/pypump-$pkgver
  python setup.py build
}

check() {
  cd "$srcdir"/pypump-$pkgver
  python setup.py test
}

package_python-pypump() {
  depends=('python' 'python-requests' 'python-requests-oauthlib')

  cd pypump-$pkgver
  python setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 COPYING "$pkgdir"/usr/share/licenses/python-pypump/LICENSE
}
