# Maintainer bill-auger <bill-auger@programmer.net>


pkgname=qtau
pkgver=0.5.5
pkgrel=1
pkgdesc="Qt based UTAU clone (also supports FESTIVAL and MBROLA voices)"
arch=(armv7h i686 x86_64)
license=(GPL3 CCPL custom:CC0) # the CCPL is CC-BY-3.0
url=https://www.qtau.de/
depends=(espeak-ng fftw gsl hts_engine_api-git jack2 libsmf qt5-base sekai sinsy)
makedepends=(boost)
source=(${pkgname}-${pkgver}.tar.gz::https://notabug.org/isengaara/${pkgname}/archive/upstream/${pkgver}.tar.gz)
sha256sums=('ebc491e39fa76c9a7f1c92faaac193cc7153d0dc092ade54fc3e54b85511189f')


prepare()
{
  mv "${srcdir}"/${pkgname}{,-${pkgver}}
}

build()
{
  mkdir "${srcdir}"/${pkgname}-${pkgver}/build
  cd    "${srcdir}"/${pkgname}-${pkgver}/build

  qmake PREFIX=/usr ..
  make
}

package()
{
  cd "${srcdir}"/${pkgname}-${pkgver}/build

  make INSTALL_ROOT="${pkgdir}" install

  install -Dm644 ../LICENSES/CC0-1.0.txt "${pkgdir}"/usr/share/licenses/${pkgname}/CC0-1.0.txt
}
