# Maintainer: André Silva <emulatorman@hyperbola.info>
# Maintainer: Márcio Silva <coadde@hyperbola.info>

# Based on pcsx2 (parabola) package

_pkgname=pcsx2
pkgname=pcsx2-git
pkgver=r9498.a18d624bc
pkgrel=1.parabola1
pkgdesc='A Sony PlayStation 2 emulator, without nonfree nvidia-cg-toolkit support'
arch=('i686' 'x86_64')
url='http://www.pcsx2.net'
license=('GPL2' 'GPL3' 'LGPL2.1' 'LGPL3')
depends_i686=('glew' 'libaio' 'libcanberra' 'libjpeg-turbo'
              'portaudio' 'sdl2' 'soundtouch' 'wxgtk' 'opengl-driver')
depends_x86_64=('lib32-glew' 'lib32-libaio' 'lib32-libcanberra'
                'lib32-libjpeg-turbo'
                'lib32-portaudio' 'lib32-sdl2' 'lib32-soundtouch'
                'lib32-wxgtk')
makedepends=('cmake' 'png++' 'git')
makedepends_x86_64=('gcc-multilib')
optdepends_x86_64=('lib32-gtk-engines: GTK2 engines support'
                   'lib32-gtk-engine-unico: Unico GTK2 engine support')
provides=("${_pkgname}")
conflicts=("${_pkgname}" "${_pkgname}-libre")
replaces=("${_pkgname}-libre")
options=('!emptydirs')
source=(${_pkgname}-${pkgver}::git+https://github.com/PCSX2/${_pkgname}.git)
sha256sums=('SKIP')

pkgver() {
  cd ${_pkgname}-${pkgver}
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd ${_pkgname}-${pkgver}
  # Remove zzogl and zerogs plugins (depends nonfree nvidia-cg-toolkit)
  rm -vr plugins/{zerogs,zzogl-pg}
  sed -i '\|zz_res  =|,+4 d' linux_various/glsl2h.pl
}

build() {
  cd ${_pkgname}-${pkgver}

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build && cd build

  if [[ $CARCH == i686 ]]; then
    cmake .. \
      -DCMAKE_BUILD_TYPE='Release' \
      -DCMAKE_INSTALL_PREFIX='/usr' \
      -DCMAKE_LIBRARY_PATH='/usr/lib' \
      -DPLUGIN_DIR='/usr/lib/pcsx2' \
      -DGAMEINDEX_DIR='/usr/share/pcsx2' \
      -DDISABLE_ADVANCE_SIMD='TRUE' \
      -DEXTRA_PLUGINS='TRUE' \
      -DREBUILD_SHADER='TRUE' \
      -DGLSL_API='TRUE' \
      -DPACKAGE_MODE='TRUE' \
      -DXDG_STD='TRUE'
  elif [[ $CARCH == x86_64 ]]; then
    cmake .. \
      -DCMAKE_BUILD_TYPE='Release' \
      -DCMAKE_TOOLCHAIN_FILE='cmake/linux-compiler-i386-multilib.cmake' \
      -DCMAKE_INSTALL_PREFIX='/usr' \
      -DCMAKE_LIBRARY_PATH='/usr/lib32' \
      -DPLUGIN_DIR='/usr/lib32/pcsx2' \
      -DGAMEINDEX_DIR='/usr/share/pcsx2' \
      -DDISABLE_ADVANCE_SIMD='TRUE' \
      -DEXTRA_PLUGINS='TRUE' \
      -DREBUILD_SHADER='TRUE' \
      -DGLSL_API='TRUE' \
      -DPACKAGE_MODE='TRUE' \
      -DXDG_STD='TRUE'
  fi

  make
}

package() {
  cd ${_pkgname}-${pkgver}/build

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et:
