# Maintainer: Andreas Grapentin <oaken-source@parabola.nu>

_pkgname=papis
pkgname=$_pkgname
pkgver=0.9
pkgrel=1
pkgdesc="Powerful and highly extensible command-line based document and bibliography manager."
arch=('any')
url="https://github.com/papis/papis"
license=('GPL3')

_pypi=(click requests filetype pyparsing arxiv2bib yaml chardet
       beautifulsoup4 prompt_toolkit bibtexparser slugify pyparser
       pylibgen habanero isbnlib)
depends=(python "${_pypi[@]/#/python-}")
makedepends=('python-setuptools')
source=("https://files.pythonhosted.org/packages/source/${_pkgname::1}/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('6a1070ea9a8345dde9cb5d9ccda582e2592520f987d0cfefa6f95d714bf5fd42')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
  sed -i '/configparser/d' setup.py
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver
  python setup.py install --root="$pkgdir"
}
