# Copyright 2023 bill-auger <bill-auger@programmer.net>
# SPDX-License-Identifier: CC0-1.0
# Maintainer: bill-auger <bill-auger@programmer.net>


# build order: (gnustep-base) <- gnustep-gui <- gnustep-back <- gnustep-netclasses


pkgname=gnustep-netclasses
_upstream_name=netclasses
pkgrel=1
pkgver=1.1.0
pkgdesc="Networking framework for GNUstep"
arch=(armv7h i686 x86_64)
url=http://gap.nongnu.org/talksoup/index.html
license=(GPL2)
depends=(gnustep-back)
makedepends=(gcc-objc gnustep-make)
source=(http://savannah.nongnu.org/download/gap/${_upstream_name}-${pkgver}.tar.gz)
sha256sums=(d7d783c5b85abb289ef2fbb4bbf709eacb631e6ddf5a78e26fa45b94fb717f40)


build()
{
  cd ${_upstream_name}-${pkgver}

  export GNUSTEP_MAKEFILES=$(gnustep-config --variable=GNUSTEP_MAKEFILES)

  ./configure
  make
}

package()
{
  cd ${_upstream_name}-${pkgver}

  make DESTDIR="${pkgdir}" install
}
