# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (aur): Fazlul Shahriar <fshahriar@gmail.com>

pkgname=9mount
pkgver=1.3
pkgdesc="A set of SUID tools for mounting 9p filesystems via v9fs."
url="http://sqweek.net/code/9mount/"
license=('custom:ISC')
source=("http://sqweek.net/9p/$pkgname-$pkgver.tar.gz" fix-checks.patch)

pkgrel=3
arch=('i686' 'x86_64')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  patch -i "$srcdir/fix-checks.patch"
  make
}

check() {
  cd "$srcdir/$pkgname-$pkgver"
  PATH=.:$PATH sh ./test.sh
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make prefix="$pkgdir/usr" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  ln -s 9mount.1 "$pkgdir/usr/share/man/man1/9umount.1"
  ln -s 9mount.1 "$pkgdir/usr/share/man/man1/9bind.1"
}

md5sums=('711a0a6f4d076c8275596171b0a315d0'
         '7961acda05c55f91f8cd6fb0d51b5c7d')
sha256sums=('820d80b9b478d05ecb022ad658477b37cfc2414a8669c3af17d192a522064c17'
            '69cd1be08cc13cdecf2851dd6f78efd734afa8b0b099484cd777edb0b1d36f79')
