# Contributor: Limao Luo <luolimao+AUR@gmail.com>
# Maintainer: Aurélien Desbrières <aurelien@cwb.io>

# parabola changes and rationale:
#  - upstream pkgbuild is gone but we keep maintaining this.

pkgname=emacs-tuareg-mode
pkgver=2.1.0
pkgrel=1
pkgdesc="Emacs tuareg mode for ocaml"
arch=(any)
url=https://github.com/ocaml/tuareg
license=(GPL)
depends=(emacs)
install=$pkgname.install
source=($pkgname-$pkgver.tar.gz::https://github.com/ocaml/tuareg/archive/$pkgver.tar.gz)
sha512sums=('ef554c45ff03bf9a4a4f96c91cdd26e8ec020c19b47dbc73722f6cfe5b25983e784cb132d8959190ee56cf3ebc61e0554d687f53ce081380202d896a4be845b7')

build() {
    cd "$srcdir"/tuareg-$pkgver/
    make elc
}

package() {
    cd "$srcdir"/tuareg-$pkgver/
    for i in *.el{,c}; do
        install -Dm644 $i "$pkgdir"/usr/share/emacs/site-lisp/tuareg/$i
    done
    install -Dm644 README.md "$pkgdir"/usr/share/doc/tuareg/README.md
}
