# Contributor: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>

pkgname='ucsniff-ace'
pkgver='1.10'
pkgrel=5
pkgdesc='A simple yet powerful VoIP Corporate Directory enumeration tool that mimics the behavior of an IP Phone in order to download the name and extension entries that a given phone can display on its screen interface.'
url='http://ucsniff.sourceforge.net/ace.html'
license=('GPL')
makedepends=('libtirpc')
depends=('libpcap')
arch=('i686' 'x86_64' 'armv7h')
source=("http://downloads.sourceforge.net/ucsniff/ace-$pkgver.tar.gz")
sha1sums=('747aee37f74e71101317809797cdaed7077dd29e')


prepare() {
  cd "$srcdir/ace-$pkgver"

  # FTBS with GCC10; because '-fno-common' is now the default
  # this software appears to be unmaintained
  export CFLAGS="${CFLAGS} -fcommon -I/usr/include/tirpc"

  sed -i 's#linux/if_tr.h#netinet/if_tr.h#' client.h
  sed -i "s:gcc :gcc $CFLAGS :g" Makefile
}

build() {
  cd "$srcdir/ace-$pkgver"

  make
}

package() {
  cd "$srcdir/ace-$pkgver"

  install -Dm755 ace "$pkgdir/usr/bin/ace"
}
