# $Id: PKGBUILD 188496 2013-06-15 04:38:11Z bisson $
# Maintainer (AUR): Gaetan Bisson <bisson@archlinux.org>
# Contributor (AUR): Pierre Schmitz <pierre@archlinux.de>
# Contributor (AUR): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale:
#  - removed flash recommendation
#  - removed nonfree search engines
#  - changed to a new upstream url

pkgname=arora
pkgver=0.11.0
pkgrel=4.parabola3
pkgdesc='Lightweight cross-platform Web browser, without nonfree flash recommendation and nonfree search engines'
url='http://code.google.com/p/arora/'
license=('GPL')
arch=('i686' 'x86_64' 'armv7h')
depends=('qtwebkit' 'desktop-file-utils')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Arora/${pkgname}/archive/${pkgver}.tar.gz"
        'searchengines.qrc'
        'libre.patch'
        'duckduckgo-html.xml'
        'seeks-search.xml'
        'wikipedia-en.xml'
        'yacy.xml')
sha1sums=('ed54f052bf3212ce612cd81b965148b4c54f4e90'
          'd64bdfe9022f8b4b0745a0d9cc1094ee80bbc897'
          '3982032d669077644d485f4d04d4ae4891bdb0e3'
          'e96f2d92b24daad0cfa28d02a003b92042651de0'
          '07bc208fbc3bf3d08192b2c07e550525953fc0b2'
          '3eea200350f7436bb2d744f8b6af1b5bbb758e51'
          '2d515947a8cbeea831490727e88c89ebee17c313')

install=install

prepare() {
        cd "${srcdir}/${pkgname}-${pkgver}"
        # remove nonfree search engines
        rm -r src/data/searchengines/*
        install -m644 $srcdir/searchengines.qrc src/data/searchengines
        install -m644 "$srcdir/"{duckduckgo-html,seeks-search,wikipedia-en,yacy}.xml src/data/searchengines    
        # remove nonfree flash recommendation
        patch -Np1 -i $srcdir/libre.patch
        sed -i '\|Flash|d' src/settings.cpp
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	qmake-qt4 PREFIX='/usr' 'CONFIG-=debug' -r
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make INSTALL_ROOT="${pkgdir}" install
}
