# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): 3V0LU710N <db_eee-at-hotmail-dot-com>
# Maintainer: David P. <megver83@parabola.nu>

pkgname=lib32-libusb
pkgver=1.0.22
pkgrel=1
pkgrel+=.nonsystemd1
pkgdesc="A cross-platform user library to access USB devices (32-bit)"
arch=('x86_64')
url="http://libusb.info/"
license=('LGPL')
depends=('lib32-glibc' 'libusb' 'lib32-eudev')
replaces=('lib32-libusb1' 'lib32-libusbx')
provides=("lib32-libusbx=$pkgver")
source=(https://github.com/libusb/libusb/releases/download/v$pkgver/libusb-$pkgver.tar.bz2)
md5sums=('466267889daead47674df933cea9cacb')

build() {
  export CC="gcc -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  cd "libusb-${pkgver}"
  ./configure --prefix=/usr --libdir=/usr/lib32 --disable-static
  make -j1
}

package () {
  cd "${srcdir}/libusb-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/include
}
