# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>

# parabola changes and rationale:
#  - rebranded to parabola
#  - switched default searchengine to duckduckgo
#  - removed useless dependency on icu because it's not
#    used at runtime according to readelf -d

pkgname=epiphany
pkgver=40.2
pkgrel=2
pkgrel+=.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine"
pkgdesc+=", with DuckDuckGo-HTML search"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(webkit2gtk gcr icu libdazzle libhandy libportal libarchive)
depends=( $( sed 's| icu | |' <<<${depends[@]} ) )
depends+=(libhogweed.so)
makedepends=(docbook-xml startup-notification lsb-release gobject-introspection
             yelp-tools git meson)
checkdepends=(xorg-server-xvfb aspell hspell hunspell nuspell libvoikko)
groups=(gnome)
_commit=95552d19b3fc8c7e1c014db301390a0a517dc3e6  # tags/40.2^0
source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit")
source+=(libre.patch)
sha256sums=('SKIP'
            '2ef991ade98fbe9a3a6cd80220d3348e69007abff5141bea42bbdf1c72836689')

# check() requires networking
_run_check=1

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../libre.patch
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  (( _run_check )) || ! echo "skipping check()" || return 0

  dbus-run-session xvfb-run \
    -s '-screen 0 1920x1080x24 -nolisten local' \
    meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}
