# U-Boot: PandaBoard and PandaBoard ES
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgname=uboot4extlinux-omap4_panda
pkgver=2017.01
pkgrel=1.1
pkgdesc="U-Boot with Extlinux support for PandaBoard and PandaBoard ES"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
conflicts=('uboot-omap4_panda' 'uboot4grub-omap4_panda')
makedepends=('bc')
license=('GPL')
install=${pkgname}.install
backup=('boot/extlinux/extlinux.conf' 'boot/uEnv.txt')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'extlinux.conf'
        'uEnv.txt')
sha256sums=('6c425175f93a4bcf2ec9faf5658ef279633dbd7856a293d95bd1ff516528ecf2'
            'dbdfef11ac6ef81add6a7d5983e715538583738561409e35de393a0bc2185772'
            'bb489334db2d44562caa18ed6297068cf7df3afdf1bb8b1b1f27bce0d2b8e987'
            '79c60872095fb4a421a532ce918ffb0927398a83df028578aebf46f54a4d6ed6')

prepare() {
  cd u-boot-${pkgver}

  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS

  make distclean
  make omap4_panda_config
  make
}

package() {
  cd u-boot-${pkgver}

  mkdir -p "${pkgdir}"/boot/extlinux
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}
