# Maintainer: bill-auger <bill-auger@programmer.net>
# Maintainer (AUR): Simon Hanna <simon dot hanna AT serve-me DOT info>


pkgname=('python-flufl-lock' 'python2-flufl-lock')
pkgver=2.4.1
pkgrel=1
pkgdesc="NFS-safe file locking with timeouts for POSIX systems"
arch=(any)
url=https://launchpad.net/flufl.lock
license=('LGPL')
options=(!emptydirs)

makedepends=('python-setuptools' 'python2-setuptools')

_upstream_name='flufl.lock'
_release=${_upstream_name}-${pkgver}
source=(https://pypi.python.org/packages/source/${_upstream_name:0:1}/${_upstream_name}/${_release}.tar.gz)
sha256sums=('72639aca3ef0379aef125c7346b042691c3452152843f301801b3c2ddcac1032')


package_python-flufl-lock()
{
  depends=('python')

  cd "${srcdir}/${_release}"

  python setup.py install --root="$pkgdir/" --optimize=1
}

package_python2-flufl-lock()
{
  depends=('python2')

  cd "${srcdir}/${_release}"

  python2 setup.py install --root="$pkgdir/" --optimize=1
}
