# Contributor: Daniel Milewski <niitotantei@riseup.net>

pkgname=vim-autotag
pkgver=r23.b2847e1
_gitcommit=b2847e15cb448e7e3194c500527fdfe042a4378a
pkgrel=1
pkgdesc='Automatically discover and "properly" update ctags files on save'
arch=(any)
url=https://github.com/craigemery/vim-autotag
license=(custom:vim)
groups=(vim-plugins)
makedepends=(git)
depends=(ctags vim)
source=(git+https://github.com/craigemery/$pkgname.git#commit=$_gitcommit)
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir"/$pkgname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

package()
{
  cd "$srcdir/$pkgname"

  install -Dm 644 plugin/autotag.py "$pkgdir/usr/share/vim/vimfiles/plugin/autotag.py"
  install -Dm 644 plugin/autotag.vim "$pkgdir/usr/share/vim/vimfiles/plugin/autotag.vim"

  install -d "$pkgdir/usr/share/licenses/$pkgname"
  ln -s /usr/share/licenses/vim-runtime/license.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
