# Maintainer (Arch): Jaroslav Lichtblau <svetlemodry@archlinux.org>
# Contributor (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=pysolfc-cardsets
pkgver=2.0
pkgrel=6
pkgrel+=.parabola1
pkgdesc="A collection of cardsets adapted for use with PySolFC"
pkgdesc+=", without nonfree cardsets"
arch=('any')
url="http://pysolfc.sourceforge.net/"
license=('GPL3')
source=(https://downloads.sourceforge.net/pysolfc/PySolFC-Cardsets-$pkgver.tar.bz2)
sha256sums=('c388d6360191b3b7e463d84e5a64260c4e3ed36e791a85227d7e8923f3f47ca7')

prepare() {
  cd "${srcdir}"/PySolFC-Cardsets-$pkgver

  # removing nonfree cardsets included in pysolfc
  rm -rv cardset-{greywyvern,jacoby,patience,rangoon-{d,e,r},tksol}
}

package() {
  cd "${srcdir}"/PySolFC-Cardsets-$pkgver

  install -d "${pkgdir}"/usr/share/PySolFC
  cp -r * "${pkgdir}"/usr/share/PySolFC
}
