# Contributor (Arch): maz-1 <loveayawaka[at]gmail[dot]com>
# Maintainer: André Silva <emulatorman@hyperbola.info>

pkgname=b43-tools
pkgver=019
pkgrel=2.1
pkgdesc="Tools for the Broadcom 43xx series WLAN chip"
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/mbuesch/b43-tools"
license=('GPL2' 'GPL3')
depends=('python2')
makedepends=('bison' 'flex' 'python2')
provides=("b43-fwcutter=$pkgver")
conflicts=('b43-fwcutter')
replaces=('b43-fwcutter')
source=("https://github.com/mbuesch/b43-tools/archive/b43-fwcutter-019.tar.gz")
sha256sums=('6fe82827655cf978a649c2c3f8221bc22bded28e4ec2f4ab0a7df487ea1ea4aa')

build() {
  cd "$srcdir/b43-tools-b43-fwcutter-$pkgver"

  sed -i -e 's/\/man\//\/share\/man\//g' fwcutter/Makefile

  make -C assembler
  make -C disassembler
  make -C fwcutter
  make -C ssb_sprom
}

package() {
  cd $srcdir/b43-tools-b43-fwcutter-$pkgver/debug/; python2 install.py install --root "$pkgdir/"; cd ..

  make -C assembler PREFIX="$pkgdir/usr/" install
  make -C disassembler PREFIX="$pkgdir/usr/" install
  make -C fwcutter PREFIX="$pkgdir/usr/" install
  make -C ssb_sprom PREFIX="$pkgdir/usr/" install
} 
