# Maintainer (upstream): Robert Štětka <robert dot stetka at gmail dot com>
# Contributor: fauno <fauno@parabola.nu>
# Contrbutor: bill-auger <bill-auger@programmer.net>


pkgname=perspectives-server
_srcname=Perspectives-Server
pkgver=3.5
pkgrel=1
url='https://perspectives-project.org/'
pkgdesc='Perspectives notary server'
arch=('any')
license=('GPL3')
depends=(openssl python2-m2crypto python2-cherrypy python2-sqlalchemy)
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/danwent/${_srcname}/archive/v${pkgver}.tar.gz
        perspectives-server.{conf,cron,service,install})
install="${pkgname}.install"
optdepends=('python2-psycopg2: for postgresql storage'
            'memcache: for caching'
            'redis: for caching')
sha256sums=('7e967bee534e116bffb0f66df4a8d13f47046612105f633315e127889324d12c'
            '1bf40daec1696be0b99afe436e2a399eecfb4746ad35244e5afc9681198062cf'
            '8406f3e80cd7a12e1cf0e39c3dc81c347168cb75e810ca227f49e082a382059b'
            '4162936154c5dc66a3498966140d040cf8ccca4b9746e11b2c6886e99218b3c5'
            'bf8aec21870fb110864cc0f4e80676d051481c864dc5e518f17d91524b9cedc6')


package()
{
  cd "${srcdir}"/

  install -dm 750 "${pkgdir}"/usr/share/webapps/${pkgname}
  install -dm 750 "${pkgdir}"/etc/webapps/${pkgname}

  install -Dm 640 ${pkgname}.conf    "${pkgdir}"/etc/conf.d/${pkgname}.conf
  install -Dm 755 ${pkgname}.cron    "${pkgdir}"/etc/cron.daily/${pkgname}
  install -Dm 644 ${pkgname}.service "${pkgdir}"/usr/lib/systemd/system/${pkgname}.service
  cp -av ${_srcname}-${pkgver}/*     "${pkgdir}"/usr/share/webapps/${pkgname}/
}
