# Maintainer (AUR): Doug Newgard <scimmia at archlinux dot info>
# Mantainer (AUR): Lorenzo Ferrillo <lorenzofersteam at live dot it>
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

# parabola changes and rationale:
#  - created split package for both python2 and python3
#  - fixed license array (does not contain any GPL3 licensed code)
#  - added missing makedepends: mesa libdrm

pkgbase=python-efl
pkgname=(python-efl python2-efl)
pkgver=1.20.0
pkgrel=2
arch=('i686' 'x86_64' 'armv7h')
url="http://www.enlightenment.org"
license=('LGPL3')
makedepends=("efl>=$pkgver" python-dbus python2-dbus mesa libdrm)
source=("http://download.enlightenment.org/rel/bindings/python/$pkgbase-$pkgver.tar.xz")
sha256sums=('70de0ee3fabe1e91da5aa0ca09dd908b62dbbeb5fce86ec194b8793967c30ea3')
#sha256sums=('SKIP')

package_python-efl() {
  pkgdesc="Python bindings for the Enlightenment Foundation Libraries"
  depends=("efl>=$pkgver" "python-dbus")
  cd "$srcdir/$pkgbase-$pkgver"
  rm -rf build
  python setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" AUTHORS README ChangeLog
}

package_python2-efl() {
  pkgdesc="Python2 bindings for the Enlightenment Foundation Libraries"
  depends=("efl>=$pkgver" "python2-dbus")
  cd "$srcdir/$pkgbase-$pkgver"
  rm -rf build
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" AUTHORS README ChangeLog
}
