# Maintainer (AUR): Stefan Majewsky <majewsky@gmx.net>
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

pkgname='art'
pkgver=2.0
pkgrel=1
pkgdesc='Arch Repository building Tool'
arch=('i686' 'x86_64' 'armv7h')
url='https://github.com/majewsky/art'
license=('GPL3')
depends=('pacman>=5.1')
optdepends=(
    'holo-build: to build packages from *.pkg.toml files'
)
makedepends=('go' 'git')
validpgpkeys=('BB41E373DB0390916D232BFFD6019A3E17CA2D96') # Signing Key for Holo releases and packages <holo-packaging@posteo.de>
                                                          # This key signs Git commits and tags by <majewsky@gmx.net>
source=("git+https://github.com/majewsky/${pkgname}.git?signed#tag=v${pkgver}")
sha256sums=('SKIP')

options=('!strip') # binaries are already stripped inside the Makefile

build() {
    cd "${srcdir}/${pkgname}"
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make install DESTDIR="${pkgdir}"
}
