# Maintainer (Arch):  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>

pkgname=libusb
pkgver=1.0.23
pkgrel=2
pkgrel+=.nonsystemd1
pkgdesc='Library that provides generic access to USB devices'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://libusb.info/'
license=(LGPL)
depends=(glibc libudev)
makedepends=(udev)
replaces=(libusb1 libusbx)
provides=("libusbx=$pkgver" libusb-1.0.so)
conflicts=(libusbx)
source=(https://github.com/libusb/libusb/releases/download/v$pkgver/libusb-$pkgver.tar.bz2)
sha256sums=('db11c06e958a82dac52cf3c65cb4dd2c3f339c8a988665110e0d24d19312ad8d')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr
  make
}

check() {
  make -C $pkgname-$pkgver check
}

package () {
  make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
}
