# Contributor (Arch): Martin Wimpress <code@flexion.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=mate-icon-theme-faenza
pkgver=1.20.0
pkgrel=1
pkgrel+=.par1
pkgdesc="Faenza icon theme for MATE"
pkgdesc+=", without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('GPL')
makedepends=('mate-common')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('ca7202b7c880399d3d1ccd409b79fd0de728350dcf3fe1b4a758d06559ca1b00')

prepare() {
    cd ${pkgname}-${pkgver}
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype playonlinux picasa spotify; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd ${pkgname}-${pkgver}
    ./autogen.sh
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd ${pkgname}-${pkgver}
    make DESTDIR="${pkgdir}" install
}
