# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>

pkgname=accountsservice
pkgver=0.6.55
pkgrel=1
pkgrel+=.nonsystemd1
pkgdesc="D-Bus interface for user account query and manipulation"
url="https://gitlab.freedesktop.org/accountsservice/accountsservice"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL3)
depends=(glib2 polkit elogind)
makedepends=(gtk-doc gobject-introspection git meson docbook-xsl xmlto)
provides+=($pkgname-elogind)
conflicts=(${provides[@]})
replaces=(${provides[@]})
_commit=6d6f7d62fd18fe5a4d4c06cb1455887ca3abdd1d  # tags/0.6.55^0
source=("git+https://gitlab.freedesktop.org/accountsservice/accountsservice.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}


prepare() {
  cd $pkgname
  sed -i '/dbus_conf_dir/s/sysconfdir/datadir/g' meson.build
}

build() {
  arch-meson $pkgname build \
    -D admin_group=wheel \
    -D systemd=false \
    -D docbook=true \
    -D gtk_doc=true \
    -D systemdsystemunitdir=no \
    -D elogind=true \
    -D user_heuristics=false
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}

# vim:set ts=2 sw=2 et:
