# Maintainer: Luke Shumaker <lukeshu@lukeshu.com>
# Maintainer (Arch:python2-memcached): Alexander Rødseth <rodseth@gmail.com>
# Contributor (Arch:python2-memcached): Angel Velasquez <angvp@archlinux.org>
# Contributor (Arch:python2-memcached): Geoffroy Carrier <geoffroy.carrier@aur.archlinux.org>
# Contributor (Arch:python2-memcached): Nathan Jones <nathanj@insightbb.com>

# Rational for inclusion in [libre]:
#  - Used by libre/parabolaweb-utils

pkgname=python2-memcached
pkgname+=1.54
pkgdesc='Python interface to memcached'
pkgver=1.54
pkgrel=2
pkgrel+=.1
url='https://github.com/linsomniac/python-memcached'
arch=('any')
license=('PSF')
depends=('python2-six')
makedepends=('python2-setuptools' 'git' 'python2-six')
source=("git://github.com/linsomniac/python-memcached#tag=release-$pkgver")
md5sums=('SKIP')

prepare() {
  cd 'python-memcached'

  sed -i 's:/env python:/python2:' memcache.py
}

package() {
  cd 'python-memcached'
  provides=("python2-memcached=$pkgver")
  conflicts=('python2-memcached')

  python2 setup.py install --root=$pkgdir --optimize=1
}

check() {
  cd 'python-memcached'

  python2 setup.py check
}

# getver: -u 2 github.com/linsomniac/python-memcached/blob/master/ChangeLog
# vim:set ts=2 sw=2 et:
