# Barebox: am335x
# Contributor: Denis Carikli <GNUtoo@cyberdimension.org>

_pkgname=barebox
pkgname=barebox-tools
pkgver=2019.02.0
pkgrel=1
pkgdesc='Barebox bootloader utility tools'
arch=('armv7h' 'i686' 'armv7h')
makedepends=('lzop')
url="http://barebox.org/"
license=('GPL2')
source=("http://barebox.org/download/${_pkgname}-${pkgver}.tar.bz2")
sha512sums=('648827efeec7b2591eaf43daf98368be1902e3f8157c8acd88b9f103078e9989bb158d81eda013e360d6dfdfbb3c7aae0e334fce957663b72ca46f419c33e981')

build() {
  cd "${_pkgname}-${pkgver}"
  unset CFLAGS CXXFLAGS LDFLAGS
  yes '' | make config
  make scripts
}

package() {
  cd "${_pkgname}-${pkgver}"
  install -d "${pkgdir}/usr/bin/"
  install -m755 -t "${pkgdir}/usr/bin/" "scripts/bareboxenv"
  for file in kernel-install mkimage netconsole ; do
      install -m755 "scripts/${file}" "${pkgdir}/usr/bin/barebox-${file}"
  done
}
