# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=sql
pkgname=(python{,2}-$_pkgname)
pkgver=1.0.0
pkgrel=1
pkgdesc="Library to write SQL queries"
arch=(any)
url="http://python-sql.tryton.org/"
license=('BSD')

makedepends=(python{,2}-setuptools)
source=("https://files.pythonhosted.org/packages/source/p/python-sql/python-sql-$pkgver.tar.gz")
md5sums=('74ddd9c49013eb45ce12be84661b1c6e')

_package() {
  depends=($1)
  cd "$srcdir"/python-$_pkgname-$pkgver
  $1 setup.py install --root="$pkgdir"
}

for _pkg in "${pkgname[@]}"; do
  eval "package_$_pkg () { _package ${_pkg%%-*}; }"
done
