# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-freedom_emu
pkgdesc="This package removes free software emulators for which no free software games, OS or applications exist (yet)."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20210421
_gitver=095aa1e09cfc51d31b3bb04cb83b29a418346b72
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/${pkgname}-blacklist.txt?id=${_gitver})
sha512sums=('736b2e8bc9f766b72787851a7f2bc9914ef1e1234040e954098568b62c561b09de753206e24439df796f7f9117b1e5fe748d5a4c7f691818c61d415be75c3488')

package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}
