# $Id: PKGBUILD 186214 2016-08-09 14:33:03Z arojas $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): josephgbr <rafael.f.f1@gmail.com>
# Contributor (Arch): vEX <vex@niechift.com>
# Maintainer (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

# NOTE: This package is not in ArchLinux32, maybe
# the i686 support could be dropped. Ohterwise,
# when building for 32-bits then upload it to [pcr],
# not [libre], the x86_64 version is the only one
# that goes to [libre-multilib]

pkgname=pcsx2
pkgver=1.4.0
pkgrel=8.parabola1
pkgdesc='A Sony PlayStation 2 emulator, without nonfree nvidia-cg-toolkit support'
arch=('i686' 'x86_64')
url='http://www.pcsx2.net'
license=('GPL2' 'GPL3' 'LGPL2.1' 'LGPL3')
depends_i686=('glew' 'libaio' 'libcanberra' 'libjpeg-turbo' 'libpulse'
              'portaudio' 'sdl2' 'soundtouch' 'wxgtk2')
depends_x86_64=('lib32-glew' 'lib32-libaio' 'lib32-libcanberra'
                'lib32-libjpeg-turbo' 'lib32-libpulse'
                'lib32-portaudio' 'lib32-sdl2' 'lib32-soundtouch'
                'lib32-wxgtk2')
makedepends=('cmake' 'png++')
makedepends_x86_64=('gcc-multilib')
conflicts=("${pkgname}-libre")
replaces=("${pkgname}-libre")
options=('!emptydirs')
source=("pcsx2-${pkgver}.tar.gz::https://github.com/PCSX2/${pkgname}/archive/v${pkgver}.tar.gz"
        pcsx2-gcc6.patch)
sha256sums=('2c8a986e2b6514d7018f6cfd39c4f2a72229b9b4ab06ca6b1d3466dfd9c33005'
            'd78c63808a609a249ec7e8330eeabee306a55ee08d2c9ce9c383b46b334bf7d0')

prepare() {
  cd ${pkgname}-${pkgver}

  patch -Np1 -i ../pcsx2-gcc6.patch
  # Remove zzogl and zerogs plugins (depends nonfree nvidia-cg-toolkit)
  rm -vr plugins/{zerogs,zzogl-pg}
  sed -i '\|zz_res  =|,+4 d' linux_various/glsl2h.pl
}

build() {
  cd ${pkgname}-${pkgver}

  if [[ -d build ]]; then
    rm -rf build
  fi
  mkdir build && cd build

  if [[ $CARCH == i686 ]]; then
    cmake .. \
      -DCMAKE_BUILD_TYPE='Release' \
      -DCMAKE_INSTALL_PREFIX='/usr' \
      -DCMAKE_LIBRARY_PATH='/usr/lib' \
      -DPLUGIN_DIR='/usr/lib/pcsx2' \
      -DGAMEINDEX_DIR='/usr/share/pcsx2' \
      -DDISABLE_ADVANCE_SIMD='TRUE' \
      -DEXTRA_PLUGINS='TRUE' \
      -DREBUILD_SHADER='TRUE' \
      -DGLSL_API='TRUE' \
      -DPACKAGE_MODE='TRUE' \
      -DXDG_STD='TRUE'
  elif [[ $CARCH == x86_64 ]]; then
    # TODO: Drop wxWidgets_CONFIG_EXECUTABLE once the upstream fix is released
    # https://github.com/PCSX2/pcsx2/issues/1933
    cmake .. \
      -DCMAKE_BUILD_TYPE='Release' \
      -DwxWidgets_CONFIG_EXECUTABLE='/usr/bin/wx-config32' \
      -DCMAKE_TOOLCHAIN_FILE='cmake/linux-compiler-i386-multilib.cmake' \
      -DCMAKE_INSTALL_PREFIX='/usr' \
      -DCMAKE_LIBRARY_PATH='/usr/lib32' \
      -DPLUGIN_DIR='/usr/lib32/pcsx2' \
      -DGAMEINDEX_DIR='/usr/share/pcsx2' \
      -DDISABLE_ADVANCE_SIMD='TRUE' \
      -DEXTRA_PLUGINS='TRUE' \
      -DREBUILD_SHADER='TRUE' \
      -DGLSL_API='TRUE' \
      -DPACKAGE_MODE='TRUE' \
      -DXDG_STD='TRUE'
  fi

  make
}

package() {
  cd ${pkgname}-${pkgver}/build

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et:
