# Maintainer (Arch): Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>

# parabola changes and rationale:
#  - removed unace and unrar recommendation

pkgname=file-roller
pkgver=3.40.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Create and modify archives"
pkgdesc+=", without nonfree unace and unrar recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(yelp-tools git libnautilus-extension meson appstream-glib)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
            'lrzip: lrzip archive support'
            'squashfs-tools: squashfs image support')
groups=(gnome)
_commit=d5cfba5a4e86b2e8118113be410f39fc854b1df7  # tags/3.40.0^0
source=("git+https://gitlab.gnome.org/GNOME/file-roller.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
}

build() {
  arch-meson $pkgname build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}
