# Maintainer (arch): Morten Linderud <foxboron@archlinux.org>
# Maintainer (arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: Pierre Neidhardt <ambrevar@gmail.com>
# Contributor: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
#  - removed qt5-webengine dependency
#  - set webkit backend as default
#  - condensed the excessive webkit rant on the welcome screen


pkgname=qutebrowser
pkgver=2.3.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5"
pkgdesc+=" and QtWebKit"
arch=('armv7h' 'i686' 'x86_64')
url="https://www.qutebrowser.org/"
license=("GPL")
depends=("python-jinja" "python-pyqt5" "python-yaml" "qt5-base" "python-pyqtwebengine")
depends=( ${depends[*]/python-pyqtwebengine/qt5-webkit} )
makedepends=("asciidoc" "python-setuptools")
optdepends=("python-adblock: adblocking backend"
            "python-pygments"
            "gst-libav: media playback with qt5-webkit backend"
            "gst-plugins-base: media playback with qt5-webkit backend"
            "gst-plugins-good: media playback with qt5-webkit backend"
            "gst-plugins-bad: media playback with qt5-webkit backend"
            "gst-plugins-ugly: media playback with qt5-webkit backend"
            "pdfjs: displaying PDF in-browser"
)
options=(!emptydirs)
source=("https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz"
        "https://github.com/qutebrowser/qutebrowser/releases/download/v$pkgver/qutebrowser-$pkgver.tar.gz.asc")
source+=("warning-webkit.html")
validpgpkeys=("E04E560002401B8EF0E76F0A916EB0C8FD55A072") # Florian Bruhin
sha256sums=('10ad01f07b9ce75fc86cb300e69208cba3d219a5d92687efc13a2a0a5a36df25'
            'SKIP')
sha256sums+=('e18216f24387b61a109611958bb59248beaf5afc90da8654e29ea8b0a7ef1610')


_version_constraint() # (dep_pkgname [precision])
{
  local dep_pkgname=$1
  local full_version=$(pacman -S --print-format='%v' ${dep_pkgname} | tail -n 1)
  local n_dots=$(tmp=${full_version%-*} ; tmp=${tmp//[^\.]} ; echo "${#tmp}" ;)
  local def_precision=$(( n_dots + 1 ))
  local precision=$( [[ "$2" =~ ^[1-${def_precision}]$ ]] && echo $2 || echo ${def_precision} )
  local pkgver_rx='[^-\.\ ]+'
  local subver_rx='\.'${pkgver_rx}
  local pkgrel_rx='[^-\ ]+'
  local capture_rx=${pkgver_rx}
  for (( n_dots=1 ; n_dots < precision ; n_dots++ )) ; do capture_rx+=${subver_rx} ; done ;

  if   [[ "${full_version}" =~ ^(${capture_rx})(${subver_rx})*-${pkgrel_rx}$ ]]
  then local version=${BASH_REMATCH[1]}
       local subver_inc=$(( ${version##*.} + 1 ))
       local version_inc=$( [[ "${version}" =~ \. ]] && echo ${version%.*}.${subver_inc} || \
                                                        echo ${subver_inc}                  )
       local constraint_string="${dep_pkgname}>=${version} ${dep_pkgname}<${version_inc}"

       echo "applied version constraint: ${constraint_string}" >&2
       echo -n "${constraint_string}"
  else echo "ERROR: _version_constraint() error parsing: dep_pkgname='${dep_pkgname}' full_version='${full_version}'" >&2
       exit 1
  fi
}

prepare() {
  cd "$pkgname-$pkgver"

  cp "$srcdir"/warning-webkit.html qutebrowser/html/
}

build() {
    cd "$pkgname-$pkgver"

    # make sure webkit is the default backend
    sed -i 's/webengine/webkit/' qutebrowser/config/configdata.yml

    export PYTHONHASHSEED=0
    make -f misc/Makefile all
}

package() {
    cd "$pkgname-$pkgver"

    depends+=( $(_version_constraint python       2) \
               $(_version_constraint python-pyqt5  ) \
               $(_version_constraint qt5-base      ) )

    make -f misc/Makefile DESTDIR="$pkgdir" PREFIX=/usr install
}
