# Maintainer: Parabola Project <dev@lists.parabola.nu>

pkgname=your-freedom
pkgdesc="This package conflicts with every nonfree package known to date to ensure your system is free."
license=('GPL3')
url="https://git.parabola.nu/blacklist.git"
pkgver=20210628
_gitver=50cf92a24fa5e2a6e4d70b90fbabd161dc2554e3
pkgrel=1

arch=('any')
install=${pkgname}.install

makedepends=(librelib)
source=(blacklist-${_gitver}.txt::https://git.parabola.nu/blacklist.git/plain/blacklist.txt?id=${_gitver})
sha512sums=('d5b65d62a6c593bdff03e0a3bb7cb6ba6b32d8efcb671a220d73fc7d67fb4fe2ca76938a0dc68c47084c31421ae681f0b4b09b40a256e56068b1c67e656c0019')


package() {
	cd "$srcdir"

	conflicts=($( \
		< blacklist-${_gitver}.txt \
		libreblacklist normalize | \
		cut -d: -f1,2 | \
		sed -n 's/:$//p' | \
		sort -u \
		))

	install -Dm644 blacklist-${_gitver}.txt "$pkgdir"/usr/share/doc/${pkgname}/blacklist.txt
}
