# U-Boot: Beaglebone and Beaglebone Black
# Maintainer (ArchArm): Kevin Mihelich <kevin@archlinuxarm.org>
# Maintainer: Andreas Grapentin <oaken-source@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>

buildarch=4

pkgname=uboot-am335x_bone
pkgver=2017.07
pkgrel=1
pkgdesc="U-Boot for Beaglebone and Beaglebone Black"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
makedepends=('bc' 'git')
conflicts=(uboot4{extlinux,grub}-am335x_bone)
license=('GPL')
install=${pkgname}.install
backup=('boot/boot.txt' 'boot/boot.scr')
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'boot.txt'
        'mkscr')
md5sums=('b74741e7a9ad1cf9a5bfa87302b80f2b'
         '89c046a7858da6ea55404c3b8314c41d'
         'e35840bf487af832b84b41b931e16aa1'
         '021623a04afd29ac3f368977140cfbfd')

prepare() {
  cd u-boot-${pkgver/rc/-rc}
  git apply ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver/rc/-rc}

  unset CFLAGS CXXFLAGS LDFLAGS

  make distclean 
  make am335x_boneblack_defconfig
  echo 'CONFIG_IDENT_STRING=" Parabola GNU/Linux-libre"' >> .config
  make EXTRAVERSION=-${pkgrel}
}

package() {
  cd u-boot-${pkgver/rc/-rc}
  mkdir -p "${pkgdir}"/boot
  cp MLO u-boot.img "${pkgdir}"/boot

  tools/mkimage -A arm -O linux -T script -C none -n "U-Boot boot script" -d ../boot.txt "${pkgdir}"/boot/boot.scr
  cp ../{boot.txt,mkscr} "${pkgdir}"/boot
}
