# Maintainer: André Silva <emulatorman@hyperbola.info>
# Maintainer: Márcio Silva <coadde@hyperbola.info>

_pkgname=uzebox
pkgname=uzem
pkgver=3.3
pkgrel=3
pkgdesc="A ${_pkgname^} 8-bit game console emulator"
url="http://belogic.com/$_pkgname"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('sdl')
options=(!debug)
source=("https://github.com/${_pkgname^}/$_pkgname/archive/$_pkgname-$pkgver.tar.gz"
        "uzem-c++14.patch")
sha256sums=('d6f5d302df3d58eb536d706e6a830618ac72157bfe15c9c2b2025e4f3091bc38'
            '5ed1b4f9faa347b8ac6001dc664db98798c77a6fb02ac845df25a7a89770b962')

prepare() {
  cd "$srcdir"/$_pkgname-$_pkgname-$pkgver
  patch -Np1 -i "$srcdir"/uzem-c++14.patch
}

build() {
  cd "$srcdir"/$_pkgname-$_pkgname-$pkgver/tools/$pkgname
  make
}

package() {
  cd "$srcdir"/$_pkgname-$_pkgname-$pkgver
  install -d "$pkgdir/usr/bin"
  install -Dm755 "$srcdir"/$_pkgname-$_pkgname-$pkgver/tools/$pkgname/${pkgname}    "$pkgdir"/usr/bin
  install -Dm755 "$srcdir"/$_pkgname-$_pkgname-$pkgver/tools/$pkgname/${pkgname}dbg "$pkgdir"/usr/bin
  # license
  install -Dm644 gpl-3.0.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}
