# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor (Arch): Michael Düll <mail@akurei.me> PGP-Key: AAAEE882
# Contributor (Arch): TDY <tdy@gmx.com>
# Contributor (Arch): Sergio Rubio <rubiojr.ml@gmail.com>
# Contributor (Arch): Hannes Rist <cowider@gmail.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
 
pkgname=unp
pkgver=2.0~pre7+nmu1
pkgrel=3
pkgrel+=.parabola1
pkgdesc='A script for unpacking a wide variety of archive formats'
pkgdesc+=', without nonfree unace, unarj and unrar recommendation'
arch=(any)
url='https://packages.qa.debian.org/u/unp.html'
license=(GPL)
depends=(perl)
optdepends=(
  'unzip: zip support'
  'bzip2: bzip2 support'
  'p7zip: p7zip support'
  'cpio: cpio support'
  'sharutils: sharutils'
  'cabextract: cab support'
  'rpmextract: rpm support'
)
source=(http://ftp.debian.org/debian/pool/main/u/unp/unp_$pkgver.tar.bz2
        libre.patch)
sha1sums=('b91f4cbc4720b3aace147652ac2043cf74668244'
          '202375dd1c013c798d0d61ab5c273be8ebe1c546')

prepare() {
  cd unp-$pkgver
  patch -Np1 -i "$srcdir"/libre.patch
}

build() {
  cd unp-$pkgver/po
  make
}
 
package() {
  cd unp-$pkgver
  install -Dm755 unp "$pkgdir"/usr/bin/unp
  install -Dm755 ucat "$pkgdir"/usr/bin/ucat
  install -Dm644 debian/unp.1 "$pkgdir"/usr/share/man/man1/unp.1
  install -Dm755 bash_completion.d/unp "$pkgdir"/usr/share/bash-completion/completions/unp

  cd po
  make DESTDIR="$pkgdir" install
}
