# Maintainer (Arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>


_basekernel=5.10.39

pkgname=tp_smapi-lts
_pkgname=tp-smapi
pkgver=0.43
pkgrel=156
pkgrel+=.parabola1.basekernel${_basekernel}
pkgdesc="Modules for ThinkPad's SMAPI functionality"
pkgdesc+=" (for linux-libre-lts)"
arch=('x86_64')
arch+=('i686')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
makedepends=(linux-libre-lts-headers=${_basekernel} 'git' libelf)
_commit=a63729ab30d85430048f65c37f29188ab484cd52  # tags/tp-smapi/0.43
source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd ${pkgname/-lts/}
  git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
}

build() {
  cd ${pkgname/-lts/}

  # https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
  # Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules

  make HDAPS=1 KVER="$(</usr/src/linux-libre-lts/version)" EXTRA_CFLAGS=
}

package() {
  depends=(linux-libre-lts=${_basekernel})

  local extradir=/usr/lib/modules/$(</usr/src/linux-libre-lts/version)/extramodules
  cd tp_smapi

  # install kernel modules
  find . -name "*.ko" -exec install -Dt "$pkgdir$extradir" {} +

  # compress kernel modules
  find "$pkgdir" -name "*.ko" -exec xz {} +

  # load module on startup
  echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
}
