# $id$
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
pkgname=libxtrx
pkgver=r49.g2443a10
pkgrel=3
pkgdesc="High level XTRX API"
url="https://github.com/xtrx-sdr/libxtrx"
arch=('armv7h' 'i686' 'x86_64')
license=('LGPL')
depends=('liblms7002m' 'libxtrxdsp' 'libxtrxll')
makedepends=('git' 'cmake' 'liblms7002m' 'libxtrxdsp' 'libxtrxll')
commit=2443a10621039049c3ced7c295d4959e74a1dcef
source=("git://github.com/xtrx-sdr/libxtrx#commit=$commit")
sha512sums=('SKIP')

pkgver() {
    cd $pkgname
    echo r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)
}

prepare() {
    cd $pkgname
    sed 's/^#include "..\/liblms7002m\/liblms7002m.h"/#include <liblms7002m.h>/' \
        -i xtrx_fe_nlms7.c
}

build() {
    case "$CARCH" in
	i686) ARCH=i386;;
	x86_64) ARCH=x86_64;;
	arhmv7h) ARCH=armhf;;
    esac

    cd "$srcdir/$pkgname"
    mkdir -p build
    cd build

    cmake \
	-DENABLE_SOAPY=NO \
	-DPYTHON_EXECUTABLE=/usr/bin/python2 \
	-DCMAKE_INSTALL_PREFIX=/usr \
	-DFORCE_ARCH=$ARCH \
	../
    make
}

package() {
    cd "$srcdir/$pkgname/build/"
    make DESTDIR="${pkgdir}" install
}
