# Contributor: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697
# Maintainer: Freemor <freemor@freemor.ca>

pkgname=cmix
pkgver=18
pkgrel=1
pkgdesc="cmix is a lossless data compression program aimed at optimizing compression ratio at the cost of high CPU/memory usage. (Warning: At least 32GB of RAM is recommended to run cmix.)"
arch=('i686' 'x86_64' 'armv7h')
makedepends=('clang') 
url="http://www.byronknoll.com/cmix.html"
license=('GPL3')
source=("http://www.byronknoll.com/$pkgname-v$pkgver.zip")
sha512sums=('b3748e1355e6fd522cf35106bf1f204fde987c49f34cfe3091b61749949e0d321485cd6a039464d31528af24c4a41ea478d2f1dee13b53e167cb541df25c34ab')

build() {
  cd $pkgname
	# Remove -mnative for arm as it's not supported
	if [[ "$CARCH" == "armv7h" ]]; then 
	  sed -i 's/-march=native//g' makefile
	fi
	make
}

package() {
  cd $pkgname
  install -Dm755 "$srcdir/$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 "$srcdir/$pkgname/COPYING" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
