# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Isaac David <isacdaavid@at@isacdaavid.info>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>

# parabola changes and rationale:
#  - removed geoclue2 support
#  - add libmm-glib as dependency (implicit in upstream)

pkgname=gnome-settings-daemon
pkgver=3.34.1+1+ge1fc4599
pkgrel=1
pkgrel+=.nonprism1
pkgdesc="GNOME Settings Daemon, without geoclue2 support"
url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse libnotify systemd-libs
         libwacom pulseaudio pulseaudio-alsa upower librsvg libgweather geocode-glib nss
         libgudev gtk3-print-backends libnm gcr libmm-glib)
makedepends=(xf86-input-wacom libxslt docbook-xsl python git meson)
checkdepends=(python-gobject python-dbusmock)
groups=(gnome)
_commit=e1fc4599764c9b10e086317164267c78f9338883  # gnome-3-34
source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git"
        nonprism.patch)
sha256sums=('SKIP'
            'SKIP'
            '6619205eb1e4d87caeb8e1673d6c80acf4d30f15ae91c5f6cb728a2e5674bf65')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/^GNOME_SETTINGS_DAEMON_//;s/_/./g;s/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.subprojects/gvc.url "$srcdir/libgnome-volume-control"
  git submodule update

  patch -p1 -i $srcdir/nonprism.patch
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}
