# Maintainer (Arch:pcre): Sébastien "Seblu" Luttringer
# Contributor (Arch:pcre): Allan McRae <allan@archlinux.org>
# Contributor (Arch:pcre): Eric Belanger <eric@archlinux.org>
# Contributor (Arch:pcre): John Proctor <jproctor@prium.net>
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Contributor: Márcio Silva <coadde@hyperbola.info>

_pkgname=pcre
pkgname=pcre-static
pkgver=8.43
pkgrel=1
pkgrel+=.static1
pkgdesc='A library that implements Perl 5-style regular expressions'
pkgdesc+=' (static libraries)'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='http://www.pcre.org/'
license=('BSD3')
depends=("$_pkgname=$pkgver")
options=('staticlibs')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8') # Philip Hazel
source=("https://ftp.pcre.org/pub/pcre/$_pkgname-$pkgver.tar.bz2"{,.sig})
md5sums=('636222e79e392c3d95dcc545f24f98c4'
         'SKIP')

prepare() {
  cd $_pkgname-$pkgver
  # apply patch from the source array (should be a pacman feature)
  local filename
  for filename in "${source[@]}"; do
    if [[ "$filename" =~ \.patch$ ]]; then
      msg2 "Applying patch ${filename##*/}"
      patch -p1 -N -i "$srcdir/${filename##*/}"
    fi
  done
  :
}

build() {
  cd $_pkgname-$pkgver
  ./configure \
    --prefix=/usr \
    --enable-unicode-properties \
    --enable-pcre16 \
    --enable-pcre32 \
    --enable-jit \
    --enable-pcregrep-libz \
    --enable-pcregrep-libbz2 \
    --enable-pcretest-libreadline
  make
}

check() {
  cd $_pkgname-$pkgver
  if [[ $CARCH == armv7h ]]; then return 0; fi # qemu: Unsupported syscall: 229
  make -j1 check
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

  # remove conflicting files
  rm -vr -- \
     "$pkgdir"/usr/bin/ \
     "$pkgdir"/usr/include/ \
     "$pkgdir"/usr/lib/pkgconfig/ \
     "$pkgdir"/usr/share/doc/ \
     "$pkgdir"/usr/share/man/
  rm -v -- \
     "${pkgdir}"/usr/lib/lib*.so \
     "${pkgdir}"/usr/lib/lib*.so.*
}

# vim:set ts=2 sw=2 et:
