# $Id: PKGBUILD 189356 2016-09-15 20:21:37Z svenstaro $
# Contributor (Arch): Aaron Griffin <aaron@archlinux.org>
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=vim-colorsamplerpack-libre
pkgname=vim-colorsamplerpack
pkgver=2012.10.28
pkgrel=5
pkgrel+=.par1
_scriptid=18915
pkgdesc="Different colorschemes for vim, without nonfree colorschemes"
arch=('any')
url="http://www.vim.org/scripts/script.php?script_id=625"
license=('GPL2' 'GPL3' 'custom')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('vim')
makedepends=('unzip')
groups=('vim-plugins')
mksource=(ColorSamplerPack.zip::"http://www.vim.org/scripts/download_script.php?src_id=$_scriptid")
source=("https://repo.parabola.nu/other/${_pkgname}/ColorSamplerPack-libre.tar.xz"
        'LICENSE')
mksha256sums=('2d0b07a36fa52728f45850933a35ab6172913262fb3aaa2cb32e597cf75859f3')
sha256sums=('b1f2bbe6ab7ee4fcce66aca812726919f96d013caf8a6c68b242c59b48269d17'
            '6d9e25d62ca66835eb24209c8e7ef973932165f65e96f615639027418ab6742d')

mksource() {
   # Remove nonfree colorschemes
   cd ${srcdir}
   mv colors colors-tmp
   install -d colors
   install -m644 colors-tmp/{calmar256-light,cleanphp,dante,ekvoli,lettuce,marklar,martin_krischik,motus,railscasts,relaxedgreen,synic,tabula,vibrantink,vividchalk,xoria256,zenburn}.vim colors
   rm -rv colors-tmp
}

package() {
    cd ${srcdir}
    installpath="${pkgdir}/usr/share/vim/vimfiles"
    install -Dm 644 colors/* -t "${installpath}/colors"
    install -Dm 644 plugin/color_sample_pack.vim "${installpath}/plugin/themes.vim"
    install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
