# Maintainer (AUR): Steffen Weber <-boenki-gmx-de->
# Contributor (AUR): Anton Bazhenov <anton.bazhenov at gmail>
# Contributor (AUR): Christopher Rogers <slaxemulator@gmail.com>
# Contributor (AUR): J. W. Birdsong <jwbirdsong AT gmail DOT com> 
# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697

pkgname=wordwarvi
pkgver=1.0.2
pkgrel=2
pkgdesc="Side-scrolling shoot 'em up '80s style arcade game"
arch=('i686' 'x86_64' 'armv7h')
url="http://smcameron.github.io/$pkgname"
license=('GPL2' 'custom')
depends=('gtk2' 'portaudio' 'libvorbis')
source=($pkgname-$pkgver.tar.gz::https://github.com/smcameron/$pkgname/archive/v$pkgver.tar.gz
        $pkgname.desktop)
sha256sums=('361d15af6edbe6db032db24de54e8f489a05b230572a8793b9889e2b8308a7ad'
            'c1a1d0eb26ca614a6baa6cf1ba553c678a4712148511e1db0ba52a1bab08236d')

build() {
  cd $pkgname-$pkgver
  make 
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install

  mv $pkgdir/usr/games $pkgdir/usr/bin

  install -Dm644 sounds/Attribution.txt $pkgdir/usr/share/licenses/$pkgname/COPYING_SOUNDS
  install -Dm644 ../$pkgname.desktop $pkgdir/usr/share/applications/$pkgname.desktop
  install -Dm644 icons/wordwarvi_icon_48x48.png $pkgdir/usr/share/pixmaps/$pkgname.png

  for _width in '16' '22' '32' '48' '64' '128'; do
    install -Dm644 icons/${pkgname}_icon_${_width}x${_width}.png \
      $pkgdir/usr/share/icons/hicolor/${_width}x${_width}/apps/$pkgname.png
  done
}
