# Maintainer (arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Andreas Grapentin <oaken-source@parabola.nu>
# Contributor: grizzlyuser <grizzlyuser@protonmail.com>
# Contributor: Iván Ávalos <avalos@disroot.org>
# Contributor: bill-auger <bill-auger@programmer.net>


# parabola changes and rationale:
# - remove qt5-webengine support


pkgname=libksysguard
pkgver=5.22.3
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Library to retrieve information on the current status of computer hardware'
pkgdesc+=' (without nonfree qt5-webengine)'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://kde.org/plasma-desktop/'
license=(LGPL)
depends=(libxres kdeclarative knewstuff)
depends+=(qt5-webchannel)
makedepends=(extra-cmake-modules kdoctools qt5-tools)
conflicts=('ksysguard<5.21.90')
groups=(plasma)
source=(https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz{,.sig})
install=libksysguard.install
sha256sums=('50b6f881483f3c66843a8506f66cd5bec190b7b980cf9d2ed84c774edea8596a'
            'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}
