# Maintainer (AUR): Sebastian Bøe <sebastianbooe@gmail.com>
# parabola changes and rationale:
# - Added armv7h and i686 architectures support
# - Modified to use a fixed git revision
pkgname=icestorm-git
pkgver=r776.0dfc713
_commit=0dfc7130bbce6a62a4ffd1c7671c0c1f7a80ee89
pkgrel=1
pkgdesc="Lattice iCE40 FPGAs Bitstream Documentation (Reverse Engineered)"
arch=('armv7h' 'i686' 'x86_64')
url="http://www.clifford.at/icestorm/"
license=('custom:ISC')
depends=('python' 'libftdi-compat')
makedepends=('git')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/cliffordwolf/icestorm.git#commit=${_commit}")
md5sums=('SKIP')
_prefix="/usr"

pkgver() {
	cd "$srcdir/${pkgname%-git}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/${pkgname%-git}"

    # Icestorm defaults to clang. We prefer to use gcc because it is
    # more widespread on Arch (gcc is in base-devel).
    CXX=gcc

    make \
        CXX=$CXX \
        PREFIX=$_prefix
}

package() {
	cd "$srcdir/${pkgname%-git}"

	# Move the license file into place
	install -dm 755        "$pkgdir/usr/share/licenses/$pkgname"
	install -m  644 README "$pkgdir/usr/share/licenses/$pkgname"

	# Install the package
	make \
      DESTDIR="$pkgdir" \
      PREFIX=$_prefix \
      install
}
