# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=sensors-applet
pkgver=3.0.0+13+g0728426
pkgrel=2
pkgrel+=.parabola1
pkgdesc="Applet for GNOME Panel to display readings from hardware sensors, including CPU temperature, fan speeds and voltage readings"
pkgdesc+=", without nonfree libxnvctrl support"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="http://sensors-applet.sourceforge.net/"
license=('GPL')
depends=('gnome-panel' 'libatasmart' 'lm_sensors')
makedepends=('git' 'gnome-common' 'intltool' 'yelp-tools')
optdepends=('hddtemp: get HDD temperatures')
_commit=07284262768e3a7066da09845370d78526be6bc1  # master
source=("$pkgname::git+https://git.code.sf.net/p/sensors-applet/code#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname

  #https://bugzilla.gnome.org/show_bug.cgi?id=656231
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}
